source: to-imperative/trunk/compiler/rfp_asail.rf @ 750

// $Source$
// $Revision: 750 $
// $Date: 2003-05-22 09:41:13 +0000 (Thu, 22 May 2003) $

$use Apply Box Class Compare Convert StdIO Table;
$use "rfpc";
$use "rfp_helper";
$use "rfp_list";
$use "rfp_mangle";

$box Module-Name;

$box Current-Namespace;

$box Entry;

$box Entry-Name;

$func ASAIL-To-CPP e.body = e.cpp-code;

$func Namespace-Control e.qualifiers = e.namespace-control;

$func Expr-To-CPP (e.ASAIL-Expr-init ) e.ASAIL-Expr-rest = e.ASAIL-Expr;

$func Expr-Ref-To-CPP e.ASAIL-Expr-Ref = e.CPP-Expr-Ref;

$func Expr-Int-To-CPP e.ASAIL-Expr-Int = e.CPP-Expr-Int;

$func Step-To-CPP e.step-operators = e.cpp-step-operators;

$func Const-Expr-To-CPP e.ASAIL-const-expr = e.CPP-const-expr;

$func Args-To-CPP (e.prefix) s.Arg-Res-Tag e.ASAIL-Args = e.CPP-Args;

$func Symbol-To-CPP s.RFP-Symbol = e.CPP-String;

$func Name-To-CPP t.name = e.CPP-Name;

$func Cond-To-CPP e.cond = e.CPP-Cond;

$func Infix-To-CPP s.func-for-converting-args-to-cpp s.op e.args = e.cpp-expr;

$func Op-Arg-To-CPP s.op = s.func-for-converting-args-to-cpp;

RFP-ASAIL-To-CPP (e.ModuleName) e.asail =
  <Store &Module-Name e.ModuleName>,
  <Store &Current-Namespace /*empty*/>,
  <Store &Entry (e.ModuleName Main)>,
  <Store &Entry-Name /*empty*/>,
  {
    <ASAIL-To-CPP e.asail> : v.cpp,
      {
        <? &Current-Namespace> : v = ('}');;  // close last namespace
      } :: e.close-namespace,
      <Store &Current-Namespace /*empty*/>,
      {
        <? &Entry-Name> : v.name = ('rfrt::Entry rf_entry (' v.name ');');;
      } :: e.entry,
      ('namespace refal\n{')
      ('using namespace rfrt;')
      v.cpp e.close-namespace e.entry
      ('}');;
  };

ASAIL-To-CPP e.asail, {
  e.asail : t.item e.rest, t.item : {
    (FUNC t.name (e.args) (e.ress) e.body) =
      { <? &Entry> : t.name = <Store &Entry-Name <Rfp2Cpp t.name>>;; },
      <RFP-Extract-Qualifiers t.name> :: (e.qualifiers) e.name,
      <Namespace-Control e.qualifiers>
      ('RF_FUNC (' <Rfp2Cpp e.name> ', '
        '(' <Args-To-CPP ('RF_ARG ') Vars e.args> '), '
        '(' <Args-To-CPP ('RF_RES ') Vars e.ress> '))'
          (<ASAIL-To-CPP e.body>)
       'RF_END');
    (IF (e.cond) e.body) =
      ('if (' <Cond-To-CPP e.cond> ')')
      ('{' (<ASAIL-To-CPP e.body>) '}');
    (FOR (e.label) (e.cond) (e.step) e.body) =
      {
        e.label : t = (LABEL <Rfp2Cpp (LABEL e.label)> ': {}');;
      } :: e.label,
      ('for ( ; ' <Cond-To-CPP e.cond> '; ' <Step-To-CPP e.step> ')')
      ('{' ('{' (<ASAIL-To-CPP e.body>) '}') e.label '}');
    (LABEL (e.label) e.body) =
      {
        e.label : /*empty*/ =
          ('{' (<ASAIL-To-CPP e.body>) '}' );
        ('{' (<ASAIL-To-CPP e.body>) '}')
        (LABEL <Rfp2Cpp (LABEL e.label)> ': {}');
      };
    (TRY e.body) =
      ('trap {' (<ASAIL-To-CPP e.body>) '}');
    (CATCH-ERROR e.body) =
      ('with {' (<ASAIL-To-CPP e.body>) '}');
    RETURN = ('return true;');
    RETFAIL = ('retfail;');
    FATAL = ('error ("Unexpected fail");');
    (LSPLIT e.expr (e.min) t.var1 t.var2) =
      ('lsplit (' <Expr-Ref-To-CPP e.expr> ', ' <Expr-Int-To-CPP e.min> ', '
      <Rfp2Cpp t.var1> ', ' <Rfp2Cpp t.var2> ');');
    (RSPLIT e.expr (e.min) t.var1 t.var2) =
      ('rsplit (' <Expr-Ref-To-CPP e.expr> ', ' <Expr-Int-To-CPP e.min> ', '
      <Rfp2Cpp t.var1> ', ' <Rfp2Cpp t.var2 > ');');
    (ASSIGN t.var e.expr) =
      (<Rfp2Cpp t.var> ' = ' <Expr-To-CPP () e.expr> ';');
    (DECL s.type t.var) =
      (s.type ' ' <Rfp2Cpp t.var> ';');
    (INT  t.var e.expr) =
      ('uintptr_t ' <Rfp2Cpp t.var> ' = ' <Expr-Int-To-CPP e.expr> ';');
    (EXPR t.var e.expr) =
      ('Expr ' <Rfp2Cpp t.var> ' (' <Expr-Ref-To-CPP e.expr> ');');
    (DEREF t.var e.expr (e.pos)) =
      ('Expr ' <Rfp2Cpp t.var> ' (' <Expr-Ref-To-CPP e.expr> ', '
      <Expr-Int-To-CPP e.pos> ');');
    (SUBEXPR t.var e.expr (e.pos) (e.len)) =
      ('Expr ' <Rfp2Cpp t.var> ' ('
      <Expr-Ref-To-CPP e.expr> ', ' <Expr-Int-To-CPP e.pos> ', ' 
      <Expr-Int-To-CPP e.len> ');');
    (DROP t.var) =
      (<Rfp2Cpp t.var> '.drop ();');
    (CONTINUE t.label) =
      ('goto ' <Rfp2Cpp (LABEL t.label)> ';');
    (BREAK t.label) =
      ('goto ' <Rfp2Cpp (LABEL t.label)> ';');
    (ERROR e.expr) =
      ('error (' <Expr-Ref-To-CPP e.expr> ');');
    (CONSTEXPR s.linkage t.name (e.comment) e.expr) =
      { s.linkage : LOCAL = 'static ';; } :: e.linkage,
      {
        t.name : (STATIC e) = (<? &Module-Name>) t.name;
        <RFP-Extract-Qualifiers t.name>;
      } :: (e.qualifiers) e.name,
      <Namespace-Control e.qualifiers>
      (e.linkage 'const Expr ' <Rfp2Cpp e.name> ' = '
        <Const-Expr-To-CPP e.expr> ';');
    (DECL-OBJ s.linkage s.tag t.name) =
      { s.linkage : LOCAL = 'static ';; } :: e.linkage,
      <To-Chars s.tag> : s1 e2,
      <RFP-Extract-Qualifiers t.name> :: (e.qualifiers) e.name,
      <Namespace-Control e.qualifiers>
      (e.linkage 'const Expr ' <Rfp2Cpp e.name>
        ' = new rftype::' s1 <To-Lower e2> ' ();');
    (DECL-FUNC s.linkage t.name) =
      <RFP-Extract-Qualifiers t.name> :: (e.qualifiers) e.name,
      <Namespace-Control e.qualifiers>
      ('RF_DECL (' <Rfp2Cpp e.name> ');');
    /*
     * s.call can be CALL or TAILCALL
     */
    (s.call t.name (e.exprs) (e.ress)) =
      ('RF_' s.call ' (' <Name-To-CPP t.name> ', '
      '(' <Args-To-CPP () Exprs e.exprs> '), (' <Args-To-CPP () Vars e.ress> '));');
  } :: e.cpp-item,
    e.cpp-item <ASAIL-To-CPP e.rest>;
  /*empty*/;
};

/*
 * Determine type of e.expr - int or Refal.
 */
Expr-To-CPP  (e.init) e.expr-all, e.expr-all : {
  /*empty*/ = <Expr-Ref-To-CPP e.init>;
//  s.ObjectSymbol e.rest, {
//    <Int? s.ObjectSymbol> = <Expr-Int-To-CPP e.init e.expr-all>;
//    <Expr-Ref-To-CPP e.expr-all>;
//  };   
  (PAREN e.expr) e.rest = <Expr-Ref-To-CPP e.init e.expr-all>;
  (EXPR e.expr) e.rest = <Expr-Ref-To-CPP e.init e.expr-all>;
  (DEREF e.expr) e.rest = <Expr-Ref-To-CPP e.init e.expr-all>;
  (SUBEXPR e.expr) e.rest = <Expr-Ref-To-CPP e.init e.expr-all>;
  (LENGTH e.expr) e.rest = <Expr-Int-To-CPP e.init e.expr-all> ;
  (MAX e.args) e.rest = <Expr-Int-To-CPP e.init e.expr-all>;         
  (MIN e.args) e.rest = <Expr-Int-To-CPP e.init e.expr-all>;
  (INFIX s.op e.args) e.rest = <Expr-Int-To-CPP e.init e.expr-all>;
  (s.var-tag (e.QualifiedName)) e.rest =
    <Expr-To-CPP (e.init (s.var-tag (e.QualifiedName))) e.rest>;
};


$func Term-Ref-To-CPP e = e;

Expr-Ref-To-CPP {
  /*empty*/ = 'empty';
  term = <Term-Ref-To-CPP term>;
  expr = '(' <Infix-To-CPP &Term-Ref-To-CPP "+" <Paren expr>> ')';
};

Term-Ref-To-CPP {
  (PAREN e.expr) =
    <Expr-Ref-To-CPP e.expr> ' ()';
  (EXPR e.expr) =
    'Expr (' <Expr-Ref-To-CPP e.expr> ')';
  (DEREF e.expr (e.pos)) =
    'Expr (' <Expr-Ref-To-CPP e.expr> ', ' <Expr-Int-To-CPP e.pos> ')';
  (SUBEXPR e.expr (e.pos) (e.len)) =
    'Expr (' <Expr-Ref-To-CPP e.expr> ', '
        <Expr-Int-To-CPP e.pos>   ', ' <Expr-Int-To-CPP e.len> ')';
  (REF t.name) = <Name-To-CPP t.name>;
  (s.var-tag t.name) = <Rfp2Cpp (s.var-tag t.name)>;
};

Expr-Int-To-CPP {
  /*empty*/ = /*empty*/;
  s.ObjectSymbol = 
    {
      <Int? s.ObjectSymbol> = s.ObjectSymbol;
      $error ("Illegal type int-symbol: " s.ObjectSymbol);
    };
  (LENGTH e.expr) =
    <Expr-Ref-To-CPP e.expr> '.get_len ()';
  (MAX e.args) =
    'pxx_max (' <Args-To-CPP () Ints e.args> ')';
  (MIN e.args) =
    'pxx_min (' <Args-To-CPP () Ints e.args> ')';
  (INFIX s.op e.args) =
    '(' <Infix-To-CPP &Expr-Int-To-CPP s.op e.args> ')';
  (REF t.name) = <Name-To-CPP t.name>;
  (s.var-tag t.name) = <Rfp2Cpp (s.var-tag t.name)>;
  expr = '(' <Infix-To-CPP &Expr-Int-To-CPP "+" <Paren expr>> ')';
};

Cond-To-CPP {
  /*empty*/ = /*empty*/;
  (CALL t.name (e.exprs) (e.ress)) = 
    'RF_CALL (' <Name-To-CPP t.name> ', '
    '(' <Args-To-CPP () Exprs e.exprs> '), '
    '(' <Args-To-CPP () Vars e.ress> '))';
  (SYMBOL? e.expr (e.pos)) =
    <Expr-Ref-To-CPP e.expr> '.symbol_at (' <Expr-Int-To-CPP e.pos> ')';
  (FLAT-SUBEXPR? e.expr (e.pos) (e.len)) =
    <Expr-Ref-To-CPP e.expr> '.flat_at ('
      <Expr-Int-To-CPP e.pos> ', ' <Expr-Int-To-CPP e.len> ')';
  /*
   * EQ -> to function eq() with 6 arg.
   */
  (EQ (e.expr1) (e.pos1) (e.len1) (e.expr2) (e.pos2) (e.len2)) =
    'Expr::eq ('<Expr-Ref-To-CPP e.expr1> ', '
          <Expr-Int-To-CPP e.pos1>  ', ' <Expr-Int-To-CPP e.len1> ', ' 
          <Expr-Ref-To-CPP e.expr2> ', '
          <Expr-Int-To-CPP e.pos2>  ', ' <Expr-Int-To-CPP e.len2> ')'; 
  /*
   * FLAT-EQ -> to function flat_eq() with 5 arg.
   */
  (FLAT-EQ (e.expr1) (e.pos1) (e.expr2) (e.pos2) (e.len)) =
    'Expr::flat_eq ('<Expr-Ref-To-CPP e.expr1> ', ' <Expr-Int-To-CPP e.pos1>
          ', ' <Expr-Ref-To-CPP e.expr2> ', ' <Expr-Int-To-CPP e.pos2>
          ', ' <Expr-Int-To-CPP e.len> ')'; 
  (NOT e.cond) =
    '!' <Cond-To-CPP e.cond>;
  (INFIX s.op e.args) =
    '(' <Infix-To-CPP <Op-Arg-To-CPP s.op> s.op e.args> ')';
  expr = '(' <Infix-To-CPP &Cond-To-CPP "&&" <Paren expr>> ')';
}; 

Infix-To-CPP s.arg2cpp s.op e.args, {
  e.args : (e.arg) e.rest =
    <Apply s.arg2cpp e.arg> :: e.arg,
    <Infix-To-CPP s.arg2cpp s.op e.rest> :: e.rest,
    {
      e.arg : v, e.rest : v = e.arg ' ' s.op ' ' e.rest;
      e.arg e.rest;
    };;
};

Op-Arg-To-CPP s.op, {
  s.op : \{ "&&"; "||"; } =
    &Cond-To-CPP;
  s.op : \{ "<"; ">"; "<="; ">="; "=="; "!="; "+"; "-"; "%"; "*"; "/"; } =
    &Expr-Int-To-CPP;
};
 
Step-To-CPP {
  /*empty*/ = /*empty*/;
  (INC-ITER t.var) = 'iter(' <Rfp2Cpp t.var> ')++';
};



$func Const-Expr-Aux e.expr = e.cpp-expr;

Const-Expr-To-CPP {
  /*empty*/ = 'empty';
  (SUBEXPR t.name s.pos s.len) = 'Expr (' <Rfp2Cpp t.name> ', ' s.pos ', ' s.len ')';
                  //FIXME: надо проверять, что s.pos и s.len
                  //       не превышают допустимых величин.
                  //       Задавать эти величины опциями.
  e.expr =
    <Const-Expr-Aux () e.expr> : {
      ' + ' e.cpp-expr = e.cpp-expr;
      e.cpp-expr = e.cpp-expr;
    };
};

Const-Expr-Aux (e.accum) e.expr, {
  e.expr : s.sym e.rest, <Char? s.sym> =
    <Const-Expr-Aux (e.accum <Symbol-To-CPP s.sym>) e.rest>;
  e.accum : v =
    ' + Char::create_expr ("' e.accum '")' <Const-Expr-Aux () e.expr>;
  e.expr : t.item e.rest, t.item : {
    (PAREN e.paren-expr) =
      ' + (' <Const-Expr-To-CPP e.paren-expr> ') ()';
    (REF t.name) =
      ' + ' <Name-To-CPP t.name>;
    (STATIC e) =
      ' + ' <Rfp2Cpp t.item>;
    s.sym, {
      <Int? s.sym>, {
        <"<" (<Abs s.sym>) (2147483648)> =              //FIXME: значение должно
                            //       задаваться опцией.
          ' + ShortInt::create_expr (' s.sym ')';
        ' + Int::create_expr (' s.sym ')';
      };
      <Word? s.sym> =
        ' + Word::create_expr ("' <Symbol-To-CPP s.sym> '")';
    };
  } :: e.cpp-item =
    e.cpp-item <Const-Expr-Aux () e.rest>;
  = /*empty*/;
};

Symbol-To-CPP s.ObjectSymbol, {
  <To-Chars s.ObjectSymbol> () $iter {
    e.symbol : s.char e.rest, s.char : {
      '\\' = '\\\\';
      '\n' = '\\n';
      '\t' = '\\t';
//        '\v' = '\\v';
//        '\b' = '\\b';
      '\r' = '\\r';
//        '\f' = '\\f';
      '\"' = '\\"';
      '\'' = '\\\'';
      s = s.char;
    } :: e.cpp-char,
    e.rest (e.cpp-symbol e.cpp-char);
  } :: e.symbol (e.cpp-symbol),
    e.symbol : /*empty*/ =
    e.cpp-symbol;
};



Args-To-CPP {
  (e.prefix) Vars /*empty*/ = /*empty*/;
  (e.prefix) s.tag e.args =
    e.args () $iter {
      e.args : (e.arg) e.rest =
        {
          e.rest : v = ', ';
          /*empty*/;
        } :: e.comma,
        s.tag : {
          Vars = e.rest (e.cpp-args <Rfp2Cpp (e.arg)> e.comma);
          Exprs = e.rest (e.cpp-args <Expr-Ref-To-CPP e.arg> e.comma);
          Ints = e.rest (e.cpp-args <Expr-Int-To-CPP e.arg> e.comma);
        };
    } :: e.args (e.cpp-args),
    e.args : /*empty*/,
    e.prefix e.cpp-args;
};

Name-To-CPP t.obj-name =
  <RFP-Extract-Qualifiers t.obj-name> :: (e.qualifiers) e.name,
  <? &Current-Namespace> :: e.namespace,
  {
    e.qualifiers : e.namespace e.cont = <Rfp2Cpp e.cont e.name>;
    <Rfp2Cpp t.obj-name>;
  };

Namespace-Control e.qualifiers, {
  <? &Current-Namespace> : e.qualifiers;
  {
    <? &Current-Namespace> : v = ('}');;
  } :: e.close-namespace,
    <Store &Current-Namespace e.qualifiers>,
    e.close-namespace ('namespace ' <Rfp2Cpp e.qualifiers> '\n{');
};