source: to-imperative/trunk/compiler/rfp_asail2asail.rf @ 2488

// $Id: rfp_asail2asail.rf 2488 2007-02-27 18:34:33Z orlov $

$use Apply Arithm Box Class Compare List StdIO Table;

$func Simplify-Infix t.asail-term = t.asail-term;
$func Simplify-Arithm e = e;

$func? Simplify-Cmp s.op (expr1) (expr2) = e;

$func Simplify e.asail = e.asail;

$func Remove-Unreachable e.asail = e.asail;

$func Remove-Dupl-Decl (e.decls) (e.subst) e.asail = e.asail;

$func Process-Var (e.decls) (e.subst) s.type t.var = e.maybe-decl (e.decls) (e.subst);

$func Free-Idx = s.idx;

$box Idx;


Simplify-ASAIL (MODULE t.ModuleName e.asail) =
  <Store &Idx>,
  (MODULE t.ModuleName <Remove-Dupl-Decl () () <Remove-Unreachable <Simplify e.asail>>>);

Simplify {
  t.first e.rest, t.first : {
    (IF-INT-CMP s.op (e.arg1) (e.arg2) e.body) = {
      <Simplify-Cmp s.op (<Simplify-Arithm (e.arg1)>) (<Simplify-Arithm (e.arg2)>)> : {
        (e1) (e2) = (IF-INT-CMP s.op (e1) (e2) <Simplify e.body>);
        /*empty*/ = <Simplify e.body>;
      };;
    };
    (IF t.cond e.body) = (IF t.cond <Simplify e.body>);
    (ASSIGN (INT t.var) e.expr) = (ASSIGN (INT t.var) <Simplify-Arithm (e.expr)>);
    (e1) = (<Simplify e1>);
    s1   = s1;
  } :: e.first =
    e.first <Simplify e.rest>;;
};

$box Blocks;
$table Breaks;
$box Last-Breaks;

$func? GetR s.box = t.right-term;
GetR s.box =
  <? s.box> : e1 t2,
  <Store s.box e1>,
  t2;

Remove-Unreachable {
  t1 e2, t1 : \{
    (FUNC t.name t.in t.out e.body) =
      <Put &Blocks (FUNC t.name t.in t.out)>,
      <Clear-Table &Breaks>,
      e.body;
    (FUNC? t.name t.in t.out e.body) =
      <Put &Blocks (FUNC? t.name t.in t.out)>,
      <Clear-Table &Breaks>,
      e.body;
    (FOR (e.cont) (e.break) (e.cond) (e.step) e.body) =
      <Put &Blocks (FOR (e.cont) (e.break) (e.cond) (e.step))>, e.body;
    (LABEL (t.label) e.body) =
      <Put &Blocks (LABEL (t.label))>, e.body;
    (IF t.cond e.body) =
      <Put &Blocks (IF t.cond)>, e.body;
    (IF-INT-CMP s.op t.arg1 t.arg2 e.body) =
      <Put &Blocks (IF-INT-CMP s.op t.arg1 t.arg2)>, e.body;
    (TRY e.body) =
      <Put &Blocks (TRY)>, e.body;
    (CATCH-ERROR e.body) =
      <Put &Blocks (CATCH-ERROR)>, e.body;
  } :: e.body =
    <Put &Last-Breaks ()>,
    <Remove-Unreachable e.body> :: e.body,
    <GetR &Blocks> : {
      (LABEL (t.label)) = {
        <In-Table? &Breaks t.label> = (LABEL (t.label) e.body) (e2);
        {
          <? &Blocks> : e (LABEL (t.other-label)),
            <Lookup &Breaks t.other-label> : /*empty*/ =
            <Unbind &Breaks t.other-label>;;
        } =
          /*empty*/ (e.body e2);
      };
      (FOR (e.cont) (e.break) (/*empty-cond*/) (e.step)) = {
        <In-Table? &Breaks e.break> =
          (FOR (e.cont) (e.break) (/*empty-cond*/) (e.step) e.body) (e2);
        (FOR (e.cont) (e.break) (/*empty-cond*/) (e.step) e.body) ();
      };
      (TRY) = {
        <? &Last-Breaks> : e (e Normal-Exit) =
          (TRY e.body) (e2);
        e2 : (CATCH-ERROR e.catch-body) e3,
          (TRY e.body) ((CATCH-ERROR e.catch-body e3));
      };
      (e.item) = (e.item e.body) (e2);
    } :: e.t1 (e2),
    <GetR &Last-Breaks> :: t.breaks,
    {
      e.t1 : v,
        t.breaks : (e t.l e),
        <Bind &Breaks (t.l) (Persistent)>,
        $fail;;
    },
    e.t1 <Remove-Unreachable e2>;
  t1 e2, t1 : \{
    (BREAK t.label) =
      <GetR &Last-Breaks> : (e.breaks),
      <Put &Last-Breaks (e.breaks t.label)>,
      {
        <? &Blocks> : e (LABEL (t.label));
        <Bind &Breaks (t.label) ()>, t1;
      };
    (CONTINUE t.label) = {
      <? &Blocks> : e (FOR (t.label) (e.break) (e.cond) (e.step));
      t1;
    };
    RETFAIL = t1;
    (ERROR e) = t1;
    FATAL = t1;
  };
  t1 e2 = t1 <Remove-Unreachable e2>;
  /*empty*/ =
    {
      <GetR &Last-Breaks> : (e.breaks),
        <Put &Last-Breaks (e.breaks Normal-Exit)>;;
    };
};


Remove-Dupl-Decl (e.decls) (e.subst) e.items, e.items : {
  t1 e.rest = {
    t1 : (DECL s.type t.var) =
      <Process-Var (e.decls) (e.subst) s.type t.var> :: e.d (e.decls) (e.subst),
      e.d <Remove-Dupl-Decl (e.decls) (e.subst) e.rest>;
    t1 : (s.split expr (e.len) t.var1 t.var2), s.split : \{ LSPLIT; RSPLIT; } =
      <Remove-Dupl-Decl (e.decls) (e.subst) expr (e.len)> :: expr,
      <Process-Var (e.decls) (e.subst) Split t.var1> :: e.decl1 (e.decls) (e.subst),
      {
        e.decl1 : (DECL s.type t.new-var) = t.new-var;
        t.var1;
      } :: t.var1,
      <Process-Var (e.decls) (e.subst) Split t.var2> :: e.decl2 (e.decls) (e.subst),
      {
        e.decl2 : (DECL s.type t.new-var) = t.new-var;
        t.var2;
      } :: t.var2,
      (s.split expr t.var1 t.var2) <Remove-Dupl-Decl (e.decls) (e.subst) e.rest>;
    e.subst : e (t1 t.new-var) e =
      <Remove-Dupl-Decl (e.decls) (e.subst) t.new-var e.rest>;
    t1 : (e2) =
      (<Remove-Dupl-Decl (e.decls) (e.subst) e2>) <Remove-Dupl-Decl (e.decls) (e.subst) e.rest>;
    t1 <Remove-Dupl-Decl (e.decls) (e.subst) e.rest>;
  };
  /*empty*/ = /*empty*/;
};

Process-Var (e.decls) (e.subst) s.type t.var, {
  e.decls : $r e (DECL s.type-old t.var) e = {
    s.type : s.type-old = /*empty*/ (e.decls) (e.subst);
    t.var : (s.tag e (e.name)),
      (s.tag 'dd' (e.name <Free-Idx>)) :: t.new-var,
      (DECL s.type t.new-var) :: t.decl,
      t.decl (e.decls t.decl) (e.subst (t.var t.new-var));
  };
  (DECL s.type t.var) (e.decls (DECL s.type t.var)) (e.subst);
};


$func "Eval *" e = e;
$func "Eval /" e = e;
$func "Eval %" e = e;
$func "Eval +" e = e;
$func "Eval -" e = e;

Simplify-Infix /*txxx = <WriteLN SSS txxx>, txxx :*/ {
  (INFIX s.op e.args), s.op : {
    "*" = <Foldr1 &"Eval *" (<Map &Simplify-Arithm (e.args)>)>;
    "/" = <Foldr1 &"Eval /" (<Map &Simplify-Arithm (e.args)>)>;
    "%" = <Foldr1 &"Eval %" (<Map &Simplify-Arithm (e.args)>)>;
    "+" = <Foldr1 &"Eval +" (<Map &Simplify-Arithm (e.args)>)>;
    "-" = <Foldr1 &"Eval -" (<Map &Simplify-Arithm (e.args)>)>;
    s   = <Map &Simplify-Arithm (e.args)>;
  } : {
    t1 = t1;
    e1   = (INFIX s.op <Paren e1>);
  };
  (e1) = (<Map &Simplify-Infix (e1)>);
  s1   = s1;
};

Simplify-Arithm (e.args) =
  <Foldr1 &"Eval +" (<Map &Simplify-Infix (e.args)>)> : {
    t1 = t1;
    e1 = (INFIX "+" <Paren e1>);
  };

"Eval *" {
  0  e     = 0;
  e  0     = 0;
  1  e2    = e2;
  e1 1     = e1;
  s1 e2 s3 = e2 <"*" s1 s3>;
  s1 e2    = e2 s1;
  e2       = e2;
};

"Eval +" {
  0  e2    = e2;
  e1 0     = e1;
  s1 e2 s3 = e2 <"+" s1 s3>;
  s1 e2    = e2 s1;
  e2       = e2;
};

"Eval /" {
  e1 1 = e1;
  e1   = e1;
};

"Eval %" {
  e1 1 = 0;
  e1   = e1;
};

"Eval -" {
  e1 0 = e1;
  e1   = e1;
};

$func? Cmp s.fn (expr1) (expr2) = e;

Simplify-Cmp s.op (expr1) (expr2) =
  s.op : { "!=" = &"/="; ">" = &">"; "<" = &"<"; } :: s.op,
  <Cmp s.op (expr1) (expr2)>;

Cmp {
  s.fn (e11 tx e12) (e21 tx e22) =
    <Cmp s.fn (e11 e12) (e21 e22)>;
  s.fn (e1) (e2), <All &Int? (e1)>, <All &Int? (e2)> =
    <Apply s.fn (<Foldr1 &"+" (e1)>) (<Foldr1 &"+" (e2)>)>;
  s.fn (e1) (e2) = (e1) (e2);
};
  

Free-Idx =
  {
    <? &Idx> : s1 = <"+" s1 1>;
    1;
  } :: s1,
  <Store &Idx s1>,
  s1;