source: to-imperative/trunk/compiler/rfp_compile.rf @ 1201

// $Source$
// $Revision: 1201 $
// $Date: 2003-08-13 22:59:18 +0000 (Wed, 13 Aug 2003) $

$use "rfpc";
$use "rfp_list";
$use "rfp_helper";
$use "rfp_check";
$use "rfp_as2as";
$use "rfp_format";
$use "rfp_vars";
$use "rfp_const";
$use "rfp_clashes";

$use StdIO;
$use Table;
$use Box;
$use Arithm;
$use Access;
$use Compare;
$use Convert;
$use Class;
$use Apply;
$use Dos;


/*
 * Table for storing object names.
 */
$table Objects;

/*
 * Table for storing parameters of referenced functions.
 */
$table Stub-Funcs;

/*
 * Box for storing function out format
 */
$box Out-Format;

/*
 * Box for storing names for function result variables
 */
$box Res-Vars;

/*
 * Following table is used by Gener-Label function for obtaining unical (for
 * certain function) label name.
 * e.Key ::= e.QualifiedName      (parameter given to Gener-Label)
 * e.Val ::= [Int]          (last index used with such e.QualifiedName)
 */
$table Labels;

/*
 * Table for storing variables used in place of preprocessor-generated ones.
 */
$table Prep-Vars;


$func Compile (e.targets) (e.headers) e.Items = e.Compiled-Items (INTERFACE e.headers);

$func Comp-Func-Stubs = e.asail-funcs;

$func Comp-Func s.tag t.name e.params-and-body = e.compiled-func;

$func Set-Drops (e.declared-exprs) e.comp-func = (e.declared-exprs) e.result-func;

$func Comp-Sentence e.Sentence = e.asail-sentence;

$func Save-Snt-State = ;

$func Recall-Snt-State = ;

$func Pop-Snt-State = ;

$func Extract-Calls e.Re = (e.last-Re) e.calls;

$func Get-Clash-Sequence (e.last-Re) e.Snt = (e.clashes) e.rest-of-the-Sentence;

$func? Without-Calls? e.Re = ;

$func Comp-Clashes (e.clashes) s.tail? (v.fails) e.Sentence = e.asail-sentence;

$func Gener-Label e.QualifiedName = t.label;

$func Add-To-Label t.label e.name = t.label;

$func Comp-Calls e.Re = e.calls;

$func Prepare-Vars e.vars = e.vars;

$func Prepare-Res e.Reult-exprs = e.Result-exprs;

$func Comp-Assigns e.assignments = e.asail-assignments;

$func Comp-Format (e.last-Re) e.He = e.assignments;



************ Get AS-Items and targets, and pass it to Compile ************

/*
 * Ящик для объявлений статических функций, констант и объектов.  Все они
 * выписываются в самом начале тела модуля.
 */
$box Declarations;

RFP-Compile e.Items =
  { <Lookup &RFP-Options ITEMS>;; } :: e.targets,
  <RFP-Clear-Table &Stub-Funcs>,
  <Store &Declarations /*empty*/>,
  <Init-Consts>,
  <Compile (e.targets) () e.Items> :: e.Items t.Interface,
  <Comp-Func-Stubs> :: e.stub-funcs,
  t.Interface (MODULE <? &Declarations> <Comp-Consts> e.Items e.stub-funcs);



****************** Choose needed items and compile them ******************

Compile (e.targets) (e.headers) e.Items, {
  e.Items : e t.item e.rest,
    {
      e.targets : v =
        e.targets : e t.name e,
        t.item : (t t t t.name e);;
    },
    t.item : {
      (IMPORT e) = () /*empty*/;
      (s.link s.tag t.pragma t.name (e.in) (e.out) e.body), FUNC FUNC? : e s.tag e =
        { 
          s.link : EXPORT = (DECL-FUNC EXPORT t.name);
          <Put &Declarations (DECL-FUNC LOCAL t.name)> = /*empty*/;
        } :: e.decl,
        {
          e.body : (BRANCH t.p e.branch) =
            <Comp-Func s.tag t.name <Del-Pragmas (e.in) (e.out) e.branch>>;;
        } :: e.comp-func,
        (e.decl) e.comp-func;
      (s.link CONST t.pragma t.name e.expr) =
        (CONSTEXPR s.link t.name (e.expr) e.expr) :: t.const,
        {
          s.link : EXPORT = (t.const) /*empty*/;
          <Put &Declarations t.const> = () /*empty*/;
        };
      (EXPORT s.tag t.pragma t.name) = ((DECL-OBJ EXPORT s.tag t.name)) /*empty*/;
      (LOCAL  s.tag t.pragma t.name) =
        <Put &Declarations (DECL-OBJ LOCAL s.tag t.name)>,
        () /*empty*/;
    } :: (e.decl) e.item =
    e.item <Compile (e.targets) (e.headers e.decl) e.rest>;
  /*<Comp-Func-Stubs>*/ (INTERFACE e.headers);
};



$func Gener-Stub e = e;

/*
 * For each referenced function generate a stub one with format e = e.
 */
Comp-Func-Stubs = <Map &Gener-Stub (<Domain &Stub-Funcs>)>;

Gener-Stub (t.name) =
  <Lookup &Stub-Funcs t.name> : t.stub-name s.tag (e.Fin) (e.Fout),
  <Put &Declarations (DECL-FUNC LOCAL t.stub-name)>,
  <Gener-Vars (e.Fin) "stub"> :: e.He,
  <Comp-Func s.tag t.stub-name ((EVAR ("arg" 1))) ((EVAR))
    (LEFT e.He) (RESULT (CALL t.name e.He))>;



Comp-Func s.tag t.name (e.in) (e.out) e.Sentence =
  <RFP-Clear-Table &Labels>,
  <RFP-Clear-Table &Prep-Vars>,
  <Init-Vars>,
  <Vars <Gener-Vars (e.out) "res">> :: e.res-vars,
  <Vars-Decl e.res-vars> : e,
  <Store &Res-Vars e.res-vars>,
  <Store &Out-Format <Format-Exp e.out>>,
  <Prepare-Res (e.in)> : (e.arg),
  <Vars e.arg> :: e.arg-vars,
  <Map &Set-Var- (Instantiated? True) (e.arg-vars)> : e,
  s.tag : {
    FUNC = FATAL;
    FUNC? = RETFAIL;
  } :: t.retfail,
  (FUNC t.name (<Vars-Print e.arg-vars>) (<Vars-Print e.res-vars>)
    <Comp-Sentence Tail ((t.retfail)) (e.arg) e.Sentence>
  ) :: e.comp-func,
*       <Set-Drops () <Gener-Var-Names e.comp-func>> :: t e.comp-func,
  <Gener-Var-Names e.comp-func> :: e.comp-func,
//!     <Post-Comp (e.res-vars) e.comp-func> :: t e.result,
//!     e.result;
  e.comp-func;
//  :: (e.func-decl) e.func-body,
//  () <Domain &Declarations> $iter {
//    e.vars : (t.var) e.rest-vars,
//      (e.var-decls (DECL t.var)) e.rest-vars;
//  } :: (e.var-decls) e.vars,
//  e.vars : /*empty*/,
//  (e.func-decl e.var-decls e.func-body);

Set-Drops (e.declared) e.comp-func =
  e.comp-func () (e.declared) $iter {
    e.comp-func : t.first e.rest, {
      t.first : \{
        (EXPR t.var e) = (DROP t.var) (t.first) t.var Init;
        (DEREF t.var e) = (DROP t.var) (t.first) t.var Init;
        (SUBEXPR t.var e) = (DROP t.var) (t.first) t.var Init;
        (DECL Expr t.var) = (DROP t.var) () t.var Decl;
        (DECL "int" t.var) = /*empty*/ () t.var Decl;
      } :: e.drop (e.constr) t.var s.init,
        {
          e.declared : e1 t.var s.old-init e2, s.old-init : {
            Init, {
              t.var : (VAR ("const" e)) =
                e.rest (e.result-func) (e.declared);
              e.rest (e.result-func e.drop e.constr) (e.declared);
            };
            Decl, s.init : {
              Decl =
                e.rest (e.result-func) (e.declared);
              Init =
                t.first : (s.method t.var e.args),
                e.rest (e.result-func (ASSIGN t.var (s.method e.args)))
                (e1 e2 t.var s.init);
                /*
                 * FIXME: if s.method is EXPR, it shouldn't be written.
                 */
            };
          };
          e.rest (e.result-func t.first) (e.declared t.var s.init);
        };
      t.first : (LABEL (t.label) e.expr) =
        <Set-Drops (e.declared) e.expr> :: (e.declared) e.expr,
        e.rest (e.result-func (LABEL (t.label) e.expr)) (e.declared);
      t.first : (e.expr) =
        <Set-Drops (e.declared) e.expr> :: t e.expr,
        e.rest (e.result-func (e.expr)) (e.declared);
      t.first : s.symbol =
        e.rest (e.result-func s.symbol) (e.declared);
    };
  } :: e.comp-func (e.result-func) (e.declared),
  e.comp-func : /*empty*/ =
  (e.declared) e.result-func;


Comp-Sentence s.tail? (v.fails) (e.last-Re) e.Sentence, e.Sentence : {

  /*empty*/ = /*empty*/;

  /*
   * In case of Re look if we should do a tailcall.  If not, then compile
   * function calls from the Re and assign results to the out parameters or
   * use them in compilation of the rest of the sentence.
   */
  (RESULT e.Re) e.Snt =
    {
      /*
       * If the Re is the last action in the sentence then we can do
       * tailcall if one of the following is true:
       *  - Re is a call of non-failable function;
       *  - Re is a call of a failable function, current function is
       *  failable, and the failures stack is empty.
       * In both cases out format of the called function should coincide
       * with those of compiled one.
       * FIXME: really we can do tailcall if all the parameters of
       * compiled function that won't get their values from the call can
       * be assigned from other sources.  Some support from runtime is
       * needed though.
       */
      e.Snt : /*empty*/, s.tail? : Tail, e.Re : (CALL t.name e.arg),
        { <In-Table? &Fun? t.name> = v.fails : (RETFAIL);; },
        <Lookup-Func t.name> :: s.linkage s.tag t.pragma (e.Fin) (e.Fout),
        <Subformat? (e.Fout) (<? &Out-Format>)> =
        <Extract-Calls e.arg> :: (e.last-Re) e.calls,
        <Prepare-Res <Split-Re (e.Fin) e.last-Re>> :: e.splited-Re,
        <Comp-Calls <R 0 v.fails> e.calls>
        (TAILCALL t.name (e.splited-Re) (<? &Res-Vars>));

      <Extract-Calls e.Re> :: (e.last-Re) e.calls,
        <Comp-Calls <R 0 v.fails> e.calls> :: e.comp-calls,
        {
          e.Snt : /*empty*/, s.tail? : Tail =
            <Split-Re (<? &Out-Format>) e.last-Re> :: e.splited-Re,
            <Prepare-Res e.splited-Re> :: e.splited-Re,
            e.comp-calls <Comp-Assigns <Zip (<? &Res-Vars>) (e.splited-Re)>>;

          e.comp-calls <Comp-Sentence s.tail? (v.fails) (e.last-Re) e.Snt>;
        };
    };

  /*
   * In case of He compile assignments from last Re and then (with new state
   * of variables) proceed with the rest of the sentence.
   */
  (FORMAT e.He) e.Snt =
    <Comp-Format (e.last-Re) e.He>
    <Comp-Sentence s.tail? (v.fails) () e.Snt>;

  /*
   * In case of Pe get from the begining of the sentence a maximum possible
   * sequence of clashes and compile it.  New values of variables from the
   * clashes use in the compilation of the rest of the sentence.
   */
  (s.dir e.Pattern) e.Snt, s.dir : \{ LEFT; RIGHT; } =
    <Get-Clash-Sequence (e.last-Re) e.Sentence> :: (e.clashes) e.Sentence,
    <Comp-Clashes (e.clashes) s.tail? (v.fails) e.Sentence>;

  (s.block) e, BLOCK BLOCK? : e s.block e = <WriteLN! &StdErr "Empty block?">, $fail;

  /*
   * In case of a block first see if its results are needed for something
   * after the block and determine whether the block is a source.  Then
   * compile each branch in turn.
   */
  (s.block e.branches) e.Snt,
    s.block : \{
      BLOCK = (FATAL);
      BLOCK?;
    } :: e.fatal? =
    /*
     * If the block initializes an $iter then extract from the $iter the He
     * for placing it in the end of each branch.
     * Then look if the block is used by a pattern or format expression.
     * If so, we should declare variables from that expression before
     * entering any branch -- those should be visible after the block.
     * Pattern or format expression is placed in the end of each branch.
     * But if a branch computes to $error, the expression shouldn't be
     * used, so protect it with (Comp If-not-error).
     * If next after the block is (Comp Error) then block results should be
     * used as values for $error, so place (Comp Error) in the end of each
     * branch.
     * If next after the block is (Comp If-not-error) then our block is in
     * the end of a branch of an outer block and has next pattern or format
     * inherited from there.  In that case we should place all the sentence
     * rest in the end of each branch because the block can be inside the
     * $error already.
     */
    {
      e.Snt : (ITER t.body t.format t.cond) e.rest =
        t.format (Comp Iter t.body t.format t.cond) e.rest;
      e.Snt;
    } :: e.Snt,
    e.Snt : {
      t.first e.rest, t.first : \{
        (LEFT e.pattern) = e.pattern;
        (RIGHT e.pattern) = e.pattern;
        (FORMAT e.format) = e.format;
      } :: e.expr =
        <Prepare-Vars <Vars e.expr>> :: e.vars,
        (e.vars) ((Comp If-not-error) t.first)
        ((Comp Source)) e.rest;
      (Comp Error) e.rest =
        () ((Comp Error)) () /*empty*/;
      (Comp If-not-error) e.rest =
        () (e.Snt) () /*empty*/;
      e = () () () e.Snt;
    } :: (e.out-vars) (e.next-terms) (e.source?) e.Snt,
    /*
     * The block is a source if after it goes pattern or format expression
     * (in that case e.source? isn't empty) or e.Snt isn't empty.
     * Branches in the block are tail sentences if the current sentence is
     * tail and the block isn't a source.
     */
    {
      \{ e.source? : v; e.Snt : v; } = ((Comp Source) <R 0 v.fails>) Notail;
      s.tail? : Tail = () Tail;
      () Notail;
    } :: (e.source?) s.tail-branch?,
    /*
     * In case our block is a source we should mark the position in the
     * failures stack, so that we can jump to it after CUTALL.  And if our
     * block isn't failable we should add (FATAL) to the end of the stack.
     */
    v.fails e.source? e.fatal? :: v.branch-fails,
    /*
     * Before compile the branches mark all out-vars as declared.
     */
    <Vars-Decl e.out-vars> :: e.decls,
    /*
     * We put all compiled branches in a block, so positive return from a
     * branch is a break from that block.
     * Each branch in its turn is placed in its own block, so for a $fail
     * to the next branch we should just break from that inner block.
     * Each branch is compiled with the current sentence state and the
     * state is recalled after that.  When all branches are compiled the
     * state is popped out from the stack.
     * If last branch fails then the whole block fails, and return from the
     * last branch is return from the block.  So the last branch isn't
     * placed in a block and is processed with the failures stack that was
     * before entering the block.  Note: this trick helps us find more
     * tailcalls.  If the call of a failable function is on the last branch
     * of the block and the failures stack is empty we can do tailcall.
     * When the last branch is compiled with the block's stack, all we
     * should do is to check it.
     */
    <Gener-Label "block"> :: t.label,
    <Save-Snt-State>,
    (e.branches) /*e.comp-branches*/ $iter {
      e.branches : (BRANCH e.branch) e.rest-br =
        <Add-To-Label t.label "branch"> :: t.br-label,
        <Comp-Sentence
          s.tail-branch?
          (v.branch-fails ((BREAK t.br-label)))
          (e.last-Re)
          e.branch e.next-terms
        > :: e.comp-br,
        <Recall-Snt-State>,
        (e.rest-br) e.comp-branches (LABEL (t.br-label) e.comp-br (BREAK t.label));
    } :: (e.branches) e.comp-branches,
    e.branches : (BRANCH e.branch) =
    <Comp-Sentence
      s.tail-branch? (v.branch-fails) (e.last-Re) e.branch e.next-terms
    > :: e.last-branch,
    <Pop-Snt-State>,
    <Map &Set-Var- (Instantiated? True) (e.out-vars)> : e,
    e.decls (LABEL (t.label) e.comp-branches e.last-branch)
    <Comp-Sentence s.tail? (v.fails) () e.Snt>;

  /*
   * In case of $iter first of all compile initial assignment to the hard
   * expression.
   */
  (ITER t.body t.format t.cond) e.Snt =
    <Comp-Sentence s.tail? (v.fails) (e.last-Re)
      t.format (Comp Iter t.body t.format t.cond) e.Snt
    >;

  /*
   * Then compile $iter condition and body both with the current state of the
   * sentence.
   * e.Snt can contain (Comp Error) and (protected from errors) pattern or
   * format which comes from an outer block, so compile it together with the
   * condition.
   * If condition fails we should compute the body, so put the compiled
   * condition in a block and place a break from it to the failures stack.
   */
  (Comp Iter (BRANCH e.body) t.format (BRANCH e.condition)) e.Snt =
    <Gener-Label "iter"> :: t.label,
    <Gener-Label "exit_iter"> :: t.exit,
    <Save-Snt-State>,
    <Comp-Sentence s.tail? (v.fails ((BREAK t.label))) () e.condition e.Snt>
      :: e.comp-condition,
    <Pop-Snt-State>,
    <Comp-Sentence Notail (v.fails) () e.body t.format> :: e.comp-body,
    (FOR (/*cont-label*/) (t.exit) () ()
      (LABEL (t.label) e.comp-condition (BREAK t.exit)) e.comp-body
    );

  /*
   * In case of $trap/$with at first compile try-sentence.  All $fails from
   * it should become errors.
   * Then recall the state of the sentence and compile catching of an error
   * with a variable err.
   * e.Snt can contain (Comp Error) and (protected from errors) pattern or
   * format which comes from an outer block, so compile it together with both
   * sentences.
   */
  (TRY (BRANCH e.try) e.catch) e.Snt =
    <Save-Snt-State>,
    <Comp-Sentence Notail ((FATAL)) () e.try e.Snt> :: e.comp-try,
    <Pop-Snt-State>,
    <Gener-Err-Var> :: t.var,
    <Set-Var (Instantiated? True) t.var>,
    <Comp-Sentence s.tail? (v.fails) (t.var) e.catch e.Snt> :: e.comp-catch,
    (TRY e.comp-try) (CATCH-ERROR e.comp-catch);

  /*
   * In case of \? add Stake to the failures stack.  Add last fail after it
   * for <R 0 v.fails> continue to work.
   */
  (STAKE) e.Snt =
    <Comp-Sentence s.tail? (v.fails (Comp Stake) <R 0 v.fails>) () e.Snt>;

  /*
   * In case of \! forget all failure catchers after last \?.
   * If there is no Stake then we are inside negation or error (we assume the
   * program is correct).  So the right failure catcher is in the bottom of
   * the stack.
   */
  (CUT) e.Snt =
    {
      v.fails : $r v.earlier-fails (Comp Stake) e = v.earlier-fails;
      <L 0 v.fails>;
    } :: v.fails,
    <Comp-Sentence s.tail? (v.fails) () e.Snt>;

  /*
   * In case of = clear the failures stack up to the closest source.
   */
  (CUTALL) e.Snt =
    {
      v.fails : $r v.earlier-fails (Comp Source) e = v.earlier-fails;
      <L 0 v.fails>;
    } :: v.fails,
    <Comp-Sentence s.tail? (v.fails) () e.Snt>;

  /*
   * In case of = in the Refal-6 sense (non-transparent hedge for the fails),
   * $fail(k) should become $error(Fname "Unexpected fail"), so clear the
   * failures stack and put that value in it.
   */
  NOFAIL e.Snt =
    <Comp-Sentence s.tail? ((FATAL)) (e.last-Re) e.Snt>;

  /*
   * In case of $fail return last failure catcher.
   */
  (FAIL) e.Snt =
    v.fails : e (e.last-fail),
    e.last-fail;

  /*
   * In case of # we should proceed with the rest if the source is computed
   * to $fail.
   * We could compile the rest of the sentence and place it in the
   * failures stack.  But then the compiled sentence would be copied as many
   * times as there are $fail's to the upper level in the source.  So we
   * place compiled source in the block and put the break to exit from it in
   * the stack.
   * When compiling the source mark it as Notail as usual.
   * If the source isn't computed to $fail we should proceed with the last
   * failure catcher.
   */
  (NOT (BRANCH e.branch)) e.Snt =
    <Gener-Label "negation"> :: t.label,
    v.fails : e (e.last-fail),
//    <Save-Snt-State>,
    <Comp-Sentence Notail (((BREAK t.label))) () e.branch> e.last-fail
      :: e.comp-negation,
//    <Pop-Snt-State>,
    (LABEL (t.label) e.comp-negation) <Comp-Sentence s.tail? (v.fails) () e.Snt>;

  /*
   * In case of $error all fails become $error(Fname "Unexpected fail").  So
   * place that value in the failures stack and then compile the computation
   * of the rest of the sentence and the last Re which should be the value of
   * $error.
   */
  (ERROR) e.Snt =
    <Comp-Sentence Notail ((FATAL)) () e.Snt (Comp Error)>;

  (Comp Error) e.Snt =
    <Prepare-Res (e.last-Re)> : (e.Re),
    (ERROR e.Re);

  /*
   * Protection mark to be used between source and tail.  If there is $error
   * construction somewhere in the source then the tail shouldn't be
   * computed, but instead the source value should be used for throwing.
   */
  (Comp If-not-error) e.Snt =
    {
      e.Snt : e (Comp Error) =
        <Comp-Sentence s.tail? (v.fails) (e.last-Re) (Comp Error)>;
      <Comp-Sentence s.tail? (v.fails) (e.last-Re) e.Snt>;
    };

//  (Comp Fatal) = FATAL;

//  (Comp Retfail) = RETFAIL;

};



********** Sentence state stack and functions for work with it. **********

$box Snt-State;

/*
 * Put current state in the stack.
 */
Save-Snt-State = <Put &Snt-State <Vars-Copy-State>>;

/*
 * Set current state to that at the top of the stack.
 */
Recall-Snt-State = <Vars-Set-State <R 0 <? &Snt-State>>>;

/*
 * Pop the top from the stack and set current state to it.
 */
Pop-Snt-State =
  <Recall-Snt-State>,
  <Store &Snt-State <Middle 0 1 <? &Snt-State>>>;



********************** Function calls compilation. ***********************

/*
 * $func Extract-Calls e.Re = (e.last-Re) e.calls;
 *
 *
 *
 */
Extract-Calls {
  (CALL t.name e.arg) e.rest =
    <Lookup-Func t.name> :: s.linkage s.tag t.pragma (e.Fin) (e.Fout),
    <Extract-Calls e.arg> :: (e.last-Re) e.calls,
    <Prepare-Res <Split-Re (e.Fin) e.last-Re>> :: e.splited-Re,
    <RFP-Extract-Qualifiers t.name> :: t e.prefix,
    <Gener-Subst-Vars (e.Fout) e.prefix> :: e.Re,
    <Vars e.Re> :: e.vars,
    <Map &Set-Var- (Instantiated? True) (e.vars)> : e,
    {
      s.tag : FUNC? =   (Failable (CALL t.name (e.splited-Re) (e.vars)));
      (CALL t.name (e.splited-Re) (e.vars));
    } :: t.call,
    <Extract-Calls e.rest> :: (e.rest-Re) e.rest-calls,
    (e.Re e.rest-Re) e.calls <Vars-Decl e.vars> t.call e.rest-calls;
  (PAREN e.Re) e.rest =
    <Extract-Calls e.Re> :: (e.last-Re) e.calls,
    <Extract-Calls e.rest> :: (e.rest-Re) e.rest-calls,
    ((PAREN e.last-Re) e.rest-Re) e.calls e.rest-calls;
  t.Rt e.Re =
    <Extract-Calls e.Re> :: (e.last-Re) e.calls,
    (t.Rt e.last-Re) e.calls;
  /*empty*/ = () /*empty*/;
};


Comp-Calls (e.fail) e.calls, e.calls : {
  (Failable t.call) e.rest =
    (IF ((NOT t.call)) e.fail) <Comp-Calls (e.fail) e.rest>;
  t.call e.rest =
    t.call <Comp-Calls (e.fail) e.rest>;
  /*empty*/ = /*empty*/;
};



********** Preparation of vars and REs for following processing **********
*********** Compilation of static parts of result expressions ************

$func Static-Expr? s.create? e.Re = static? e.Re;

$func Static-Term? t.Rt = static? t.Rt;

$func Find-Ref-Funcs expr = expr;

$func Stub-Name t.name = t.stub-name;


/*
 * Extract static parts from each Re.
 * Also get the right names for variables generated during the preprocessing
 * stage, if those are in the expr. 
 */
Prepare-Res {
  (e.Re) e.rest = <Static-Expr? Create e.Re> :: s e.Re, (e.Re) <Prepare-Res e.rest>;
  /*empty*/     = /*empty*/;
};

/*
 * Find all the longest static parts in the upper level of Re.  Create STATIC
 * form in place of each one.
 * Return a tag pointing whether the whole expression is static and expression
 * with static parts replaced by STATIC forms.  Dynamic parts are returned
 * unchanged.
 */
Static-Expr? {
  s.create? t.Rt e.Re =
    <Static-Term? t.Rt> : {
      Static t.st-Rt =
        {
          e.Re : e1 t2 e3, <Static-Term? t2> : Dynamic t.dyn-Rt =
            <Static-Expr? Create e3> :: s e3,
            Dynamic
            <Create-Static <Find-Ref-Funcs t.st-Rt e1>> t.dyn-Rt e3;
          {
            s.create? : Create =
              Static
              <Create-Static <Find-Ref-Funcs t.st-Rt e.Re>>;
            Static <Find-Ref-Funcs t.st-Rt e.Re>;
          };
        };
      Dynamic t.dyn-Rt =
        <Static-Expr? Create e.Re> :: s e.Re,
        Dynamic t.dyn-Rt e.Re;
    };
  s.create? /*empty*/ = Static;
};


/*
 * The same as Static-Expr? but for terms.
 */
Static-Term? {
  symbol       = Static symbol;
  (PAREN e.Re) = <Static-Expr? Not-Create e.Re> :: static? e.Re, static? (PAREN e.Re);
  (REF t.name) = Static (REF t.name);
  t.var        = <Prepare-Vars t.var> : t.prep-var, Dynamic t.prep-var;
};


Prepare-Vars {
  (s.var-tag (e.prefix s.n)) e.rest, <Int? s.n> =
    {
      <Lookup &Prep-Vars e.prefix s.n>;
      <Gener-Vars ((s.var-tag)) e.prefix> :: e.var,
        <Bind &Prep-Vars (e.prefix s.n) (e.var)>,
        e.var;
    } :: e.var,
    e.var <Prepare-Vars e.rest>;
  t.var e.rest = t.var <Prepare-Vars e.rest>;
  /*empty*/ = /*empty*/;
};


$func Ref-Func? e = e;

Find-Ref-Funcs expr = <Map &Ref-Func? (expr)>;

Ref-Func? {
  (REF t.name) =
    {
      <Lookup-Func t.name> : {
        t t t ((EVAR)) ((EVAR)) = (FUNC t.name);
        s.linkage s.tag t.pragma (e.Fin) (e.Fout) =
          {
            <Lookup &Stub-Funcs t.name> : t.stub-name e =
              (FUNC t.stub-name);
            <Stub-Name t.name> :: t.stub-name,
              <Bind &Stub-Funcs (t.name)
                (t.stub-name s.tag (e.Fin) (e.Fout))>,
              (FUNC t.stub-name);
          };
      };
      (REF t.name);
    };
  term = term;
};


/*
 * Генерируем уникальные внутри модуля имена для функций-заглушек.
 */
Stub-Name (e.qualifiers s.name) =
  <To-Chars s.name> : {
    e1 '_' s.n, <Int? s.n> = e1 '_' <"+" s.n 1>;
    e1 = e1 '_' 0;
  } :: e.name,
  (e.qualifiers <To-Word e.name>) :: t.name,
  {
    <Lookup-Func t.name> : e = <Stub-Name t.name>;
    t.name;
  };



***************** Compilation of assignment to variables *****************

$func Comp-Assign-to-Var e = e;

Comp-Assign-to-Var (t.var (e.Re)) =
  {
    t.var : e.Re = /*empty*/;
    <Set-Var (Instantiated? True) t.var>, $fail;
    <Substitutable-Var? e.Re> = <Gener-Var-Assign t.var e.Re>;
    <Get-Var Decl t.var> : s = (ASSIGN <Vars-Print t.var> e.Re);
    <Vars-Decl t.var> : e, (EXPR <Vars-Print t.var> e.Re);
  };

Comp-Assigns e.assigns = <Map &Comp-Assign-to-Var (e.assigns)>;



************************** FORMAT compilation. ***************************

$box Aux-Index;

$func Gener-Aux-Var = t.new-aux-var;

Gener-Aux-Var =
  <? &Aux-Index> : s.n,
  <Store &Aux-Index <"+" s.n 1>>,
  (VAR ("aux" s.n));


$func Create-Aux-Vars (e.vars) e.splited-Re = e.assigns;


Comp-Format (e.last-Re) e.He =
  <Prepare-Vars <Vars e.He>> :: e.vars,
  <Prepare-Res <Split-Re (<Format-Exp e.He>) e.last-Re>> :: e.splited-Re,
  <Store &Aux-Index 1>,
  <Create-Aux-Vars (e.vars) e.splited-Re> :: e.assigns,
  <Comp-Assigns e.assigns>;

/*
 * Итак, e.vars -- все переменные, входящие в форматное выражение.  Каждая
 * переменная может входить в форматное выражение только один раз, поэтому
 * повторяющихся среди них нет.
 * e.splited-Re -- набор результатных выражений.  На каждую переменную из
 * e.vars по выражению, которое должно быть ей присвоено.
 * 
 * Если переменная t.var_i используется в выражении e.Re_j, и i /= j, то
 * переменной t.var_j значение должно быть присвоено раньше, чем перeменной
 * t.var_i.  Если же, по аналогичным соображениям, t.var_i должна получить
 * значение раньше t.var_j, необходимо завести вспомогательную переменную.
 *
 * Пример:
 * 
 * t1 (t1 t2) (t1 t3) :: t2 t1 t3
 *
 * t3 = (t1 + t3)();
 * aux_1 = t1;
 * t1 = (t1 + t2)()
 * t2 = aux_1;
 * 
 * В общем случае вспомогательная переменная требуется, если двум переменным
 * необходимы старые значения друг друга (возможно, не напрямую, а через
 * промежуточные переменные).
 *
 * Вместо того, чтобы искать и анализировать такие циклы, будем действовать по
 * методу "наибольшей пользы".  А именно:
 * 
 *   - Для каждой переменной выпишем все другие переменные, которым требуется
 *     её старое значение, а также отдельно те, старые значения которых
 *     требуются ей.
 *
 *   - Всем переменным, от старых значений которых ничего не зависит, можно
 *     смело присвоить новые значения.  При этом они исчезают из списков
 *     зависимостей оставшихся переменных.
 *
 *   - Все переменные, новые значения которых ни от чего не зависят, можно
 *     отложить, чтобы присвоить им значения тогда, когда будет удобно.  Т.е.
 *     тогда, когда списки зависящих от них переменных опустеют.
 *
 *   - Чтобы означить оставшиеся, нужны вспомогательные переменные.  Выберем
 *     одну из переменных, с максимальным списком тех, от которых она зависит,
 *     и положим её значение во вспомогательную переменную.  Так как мы сразу
 *     уменьшили кол-во зависимостей у максимального кол-ва переменных,
 *     локально мы добились наибольшей пользы, хотя не исключено, что глобально
 *     такой метод и не даст наименьшего кол-ва вспомогательных переменных.
 *     Кроме того, мы не пытаемся выбрать наилучшую переменную из нескольких с
 *     максимальным списком зависимостей.
 *
 *   - Повторяем всё это до тех пор, пока у каждой переменной не опустеет
 *     список зависящих от неё.
 *
 *
 * Для нашего примера:
 * 
 * t1 (t1 t2) (t1 t3) :: t2 t1 t3
 *
 * t1 -- (t2 t3) (t2)
 * t2 -- (t1)    (t1)
 * t3 -- ()      (t1)
 *
 *
 * Для каждой переменной var_i найдём все j /= i, такие что в Re_j встречается
 * var_i -- provide[i], и а также все j /= i, такие что var_j нужна для
 * подсчёта var_i, т.е. встречается в Re_i.
 *
 * Res-vars <- <Map &Vars (Res)>
 * for var_i in vars
 *     provide[i] <-
 *     for vars-Re_j in Res-vars, j /= i
 *         vars-Re_j : e var_i e = j
 *     require[i] <- <Res-vars[i] `*` vars[^i]> : e var_j e, j
 *
 * Res-vars = map Vars Res
 * provide, require =
 *   {   [ j | vars-Re_j <- Res-vars, j /= i, var_i `in` vars-Re_j ]
 *     , [ j | var_j <- Res-vars[i] `*` vars, i /= j]
 *     | var_i <- vars
 *   }
 *
 */

$func CAV e.vars (e.assigns) (e.delayed) = e.assigns;

$func Get-Vars e = e;
Get-Vars (e.Re) = (<Vars e.Re>);

Create-Aux-Vars (e.vars) e.splited-Re =
  <Zip (<Map &Get-Vars (e.splited-Re)>) (e.vars)> :: e.list,
  <Box> :: s.box,
  <Box> :: s.provide-i,
  <Box> :: s.require-i,
  {
    e.vars : e1 t.var-i e2,
      {
        e.list : e ((e.vars-Re) t.var-j) e,
          \{
            t.var-i : t.var-j = <Put s.require-i <And (e1 e2) e.vars-Re>>;
            e.vars-Re : e t.var-i e = <Put s.provide-i t.var-j>;
          },
          $fail;
        <L <Length e1> e.splited-Re> :: t.Re-i,
        <Put s.box (t.var-i t.Re-i (<? s.provide-i>) (<? s.require-i>))>,
          <Store s.provide-i /*empty*/>,
          <Store s.require-i /*empty*/>;
      },
      $fail;;
  },
  <CAV <? s.box> (/*assigns*/) (/*delayed*/)>;


/*
 * Если есть переменная, у которой список provide пуст, её можно посчитать.
 * Это выражается в том, что она (вместе с присваиваемым значением) добавляется
 * в список assigns, убирается из списка vars, а также из всех списков provide
 * и delayed.  В списках require её не было.
 *
 * CAV Res vars provide require assigns delayed =
 *   { i | var_i <- vars, provide_i == [] } ->     // Здесь неверно!  На переменные
 *                                                    из delayed тоже надо смотреть.
 *       vars    = vars - var_i
 *       provide = [ provide_j - i | provide_j <- provide ]
 *       assigns = assigns++[(var_i, Res[i])]
 *       delayed = [ (var_j, provide_j - i) | (var_j, provide_j) <- delayed ]
 *       CAV Res vars provide require assigns delayed
 */

$func Assign-Empty-Provides e.vars  = e.assigns (e.vars);

Assign-Empty-Provides {
  e1 (t.var-i t.Re-i (/*empty provide_i*/) (e.require-i)) e2 =
    <Box> :: s.vars,
    {
      e1 e2 : e (t.var-j t.Re-j (e.provide-j) (e.require-j)) e,
        <Put s.vars (t.var-j t.Re-j (<Sub (e.provide-j) t.var-i>) (e.require-j))>,
        $fail;;
    },
    (t.var-i t.Re-i) <Assign-Empty-Provides <? s.vars>>;
  e.vars = /*empty*/ (e.vars);
};


/*
 * Если есть переменная, у которой список require пуст, кладём её в delayed.
 * Она будет посчитана, когда у неё опустеет список provide, т.е. когда не
 * останется переменных, у которых она в списке require.
 */
$func Delay-Empty-Requires e.vars  = e.delayed (e.vars);

Delay-Empty-Requires {
  e1 t.var e2, t.var : (t.var-i t.Re-i (e.provide-i) (/*empty require_i*/)) =
    <Delay-Empty-Requires e2> :: e.delayed (e.vars),
    t.var e.delayed (e1 e.vars);
  e.vars = /*empty*/ (e.vars);
};


/*
 * Выбор переменной (из двух) с более длинным списком требуемых ей значений.
 */
$func Max-Require e = e;

Max-Require t.arg1 t.arg2 =
  t.arg1 : (t.var1 t.Re1 t.provide1 (e.require1)),
  t.arg2 : (t.var2 t.Re2 t.provide2 (e.require2)),
  {
    <"<" (<Length e.require1>) (<Length e.require2>)> = t.arg2;
    t.arg1;
  };


/*
 * Подставить вспомогательную переменную вместо исходной во всех результатных выражениях.
 * Присваивание к исходной переменной убрать (оно к этому моменту уже выполнено).
 * Убрать переменную из списков зависимостей.
 */
$func Subst-Aux-Var e = e;

Subst-Aux-Var t.var t.aux (t.v t.Re (e.provide) (e.require)), {
  t.var : t.v = /*empty*/;
  (
    t.v
    <Subst (t.var) ((t.aux)) t.Re>
    (<Sub (e.provide) t.var>)
    (<Sub (e.require) t.var>)
  );
};


/*
 * Извлечь присваивание из всей информации о переменной.
 */
$func Extract-Assigns e = e;
Extract-Assigns (t.var t.Re e) = (t.var t.Re);


/*
 * Основной цикл обработки присваиваний.
 *
 * 1) Из всех переменных (в том числе и отложенных), от которых больше ничего
 *    не зависит, сделать присваивания.
 * 2) Все переменные, которые больше ни от чего не зависят, отложить.
 * 3) Если осталось хотя бы две неотложенных переменных, выбирать из них ту,
 *    которая зависит от наибольшего числа переменных, подставить везде вместо
 *    неё вспомогательную, перейти к пункту 1.
 */
CAV e.vars (e.assigns) (e.delayed) =
  <Assign-Empty-Provides e.vars> :: e.new-assigns (e.vars),
  e.assigns e.new-assigns <Assign-Empty-Provides e.delayed> :: e.assigns (e.delayed),
  e.delayed <Delay-Empty-Requires e.vars> :: e.delayed (e.vars),
  {
    e.vars : t t e =
      <Foldr1 &Max-Require (e.vars)> : (t.var t.Re e),
      <Gener-Aux-Var> :: t.aux,
      e.assigns (t.aux (t.var)) (t.var t.Re) :: e.assigns,
      <Map &Subst-Aux-Var t.var t.aux (e.vars)> :: e.vars,
      <Map &Subst-Aux-Var t.var t.aux (e.delayed)> :: e.delayed,
      <CAV e.vars (e.assigns) (e.delayed)>;
    e.assigns <Map &Extract-Assigns (e.vars e.delayed)>;
  };




****************** Компиляция сопоставления с образцом *******************

Get-Clash-Sequence (e.last-Re) t.Pattern e.Snt =
  (/*e.clashes*/) (RESULT e.last-Re) t.Pattern e.Snt $iter {
    e.Snt : (RESULT e.Re) (s.dir e.Pe) e.rest =
      /*
       * Компилируем все константные выражения и заводим в табличке все
       * незаведённые переменные.  У старых переменных очищается память
       * на предмет клешей, в которых они раньше использовались.
       */
      <Prepare-Res (e.Re) (e.Pe)> : (e.R1) (e.P1),
      <Map &Set-Var- (Clashes /*empty*/) (<Vars e.R1 e.P1>)> : e,
      (e.clashes (e.R1) (s.dir e.P1)) e.rest;
  } :: (e.clashes) e.Snt,
  # \{
    e.Snt : \{
      (RESULT e.Re) (LEFT e) e = e.Re;
      (RESULT e.Re) (RIGHT e) e = e.Re;
    } :: e.Re,
      <Without-Calls? e.Re>;
  } =
  (e.clashes) e.Snt;

Without-Calls? e.Re =
  e.Re $iter {
    e.Re : t.Rt e.rest =
      t.Rt : {
        (CALL e) = $fail;
        (BLOCK e) = $fail;
        (PAREN e.Re1) = <Without-Calls? e.Re1>;
        t.symbol-or-var = /*empty*/;
      },
      e.rest;
  } :: e.Re,
  e.Re : /*empty*/;

$func CC s.tail? (v.fails) t.end-cycle e.Snt = e.asail-Snt;

Comp-Clashes (e.clashes) s.tail? (v.fails) e.Sentence =
  <Init-Clashes e.clashes>,
  <CC s.tail? (v.fails) <R 0 v.fails> e.Sentence>;

$func CC-Known-Lengths t.fail e.idxs = e.conds;

$func CC-Compute-Length t.fail t.end-cycle t.idx = e;

$func CC-Unknown-Lengths t.fail e.idxs = e.conds;

$func CC-Deref t.fail e.actions = e.actions;

$func CC-Eqs t.fail (e.assigns) e.eqs = e.actions;

CC s.tail? (v.fails) t.end-cycle e.Snt, {
  <Domain &Known-Lengths> : v.clashes =
    <CC-Known-Lengths t.end-cycle v.clashes>
    <CC s.tail? (v.fails) t.end-cycle e.Snt>;
  <Domain &Compute-Length> : (t.clash) e =
    <CC-Compute-Length <R 0 v.fails> t.end-cycle t.clash>
    <CC s.tail? (v.fails) t.end-cycle e.Snt>;
  <Domain &Unknown-Lengths> : e.clashes =
    <CC-Unknown-Lengths t.end-cycle e.clashes> :: e.conds,
    /*
     * Когда мы добрались до сюда, все условия на длины на текущем уровне
     * выписаны.  Невыполнение любого из оставшихся условий (на
     * соответствие типов, равенство, длины внутри скобок) ведёт не к
     * прекращению текущего цикла, а переход к его следующей итерации.
     * Поэтому в качестве t.end-cycle везде дальше подставляется текущий
     * откат.
     */
    <Update-Hard-Parts> : {
      v.actions =
        e.conds <CC-Deref <R 0 v.fails> v.actions>
        <CC s.tail? (v.fails) <R 0 v.fails> e.Snt>;
      /*empty*/ =
        e.conds <CC-Eqs <R 0 v.fails> () <? &Eqs>> :: e.actions,
        <Store &Eqs /*empty*/>,
        {
          <Compose-Source> :: e.assign =
            e.actions <CC-Eqs <R 0 v.fails> () e.assign>
            <CC s.tail? (v.fails) <R 0 v.fails> e.Snt>;
          {
            <Get-Cycle> :: s.split (e.left) (e.right) (e.len)
                    t.var t.l-var t.r-var =
              {
                e.left : 0, e.right : 0 = /*empty*/ t.var;
                <Gener-Vars ((VAR)) "subexpr_" t.var> : t.sub-var,
                  (SUBEXPR t.sub-var t.var (e.left)
                    ((INFIX "-" (e.len) (e.left e.right))))
                  t.sub-var;
              } :: e.subexpr t.var,
              {
                s.split : RSPLIT =
                  t.r-var t.l-var DEC-ITER;
                t.l-var t.r-var INC-ITER;
              } :: t.l-var t.r-var s.iter-op,
              <Gener-Label "continue"> :: t.cont-label,
              <Gener-Label "exit"> :: t.break-label,
              e.actions e.subexpr
              (s.split t.var (<Get-Var Min t.l-var>) t.l-var t.r-var)
              (FOR (t.cont-label) (t.break-label) () ((s.iter-op t.var))
                (IF ((NOT (CHECK-ITER t.var))) <Concat <R 0 v.fails>>)
                <CC s.tail?     (v.fails ((CONTINUE t.cont-label)))
                  <R 0 v.fails> e.Snt>
                (BREAK t.break-label)
              );
            e.actions <Comp-Sentence s.tail? (v.fails) () e.Snt>;
          };
        };
    };
};

CC-Known-Lengths (e.fail) e.idxs, {
  e.idxs : (t.idx) e.rest =
    <Put &Checked-Lengths t.idx>,
    <Lookup &Known-Lengths t.idx> : (e.len-Re) (e.len-Pe),
    (IF ((INFIX "!=" (e.len-Re) (e.len-Pe))) e.fail)
    <CC-Known-Lengths (e.fail) e.rest>;
  <RFP-Clear-Table &Known-Lengths>;
};

CC-Compute-Length (e.fail) (e.end-cycle) t.idx =
  <Lookup &Compute-Length t.idx> : t.var s.mult (e.minuend) (e.subtrahend),
  <Create-Int-Var ("len") Aux e.minuend> :: t.m-var e.m-assign,
  <Create-Int-Var ("len") Aux e.subtrahend> :: t.s-var e.s-assign,
  <Get-Var Min t.var> :: e.min,
  ((INFIX "<" (t.m-var)
        ((INFIX "+" (t.s-var)
              ((INFIX "*" (e.min) (s.mult)))
  ))                    )) :: e.min-cond,
  <Get-Var Max t.var> : {
    /*empty*/;
    e.max =
      ((INFIX ">" (t.m-var)
            ((INFIX "+" (t.s-var)
                  ((INFIX "*" (e.max) (s.mult)))
      ))                        ));
  } :: e.max-cond,
  (INFIX "%" ((INFIX "-" (t.m-var) (t.s-var))) (s.mult)) :: e.div-cond,
  <Create-Int-Var ("len_") t.var
    (INFIX "/" ((INFIX "-" (t.m-var) (t.s-var))) (s.mult))
  > :: t.len-var e.len-assign,
  <Set-Var (Length t.len-var) t.var>,
  <Unbind &Compute-Length t.idx>,
  <Put &Checked-Lengths t.idx>,
  <Get-Var Clashes t.var> :: e.clashes,
  <Map &Reclassify-Clash (<Sub (e.clashes) <? &Checked-Lengths>>)> : e,
  e.m-assign e.s-assign
  (IF ((INFIX "||" e.min-cond e.max-cond)) e.end-cycle)
  (IF (e.div-cond) e.fail)
  e.len-assign;

$func  Get-Min e = e;

$func? Get-Max e = e;

CC-Unknown-Lengths (e.fail) e.idxs, {
  e.idxs : (t.idx) e.rest =
    <Lookup &Unknown-Lengths t.idx> : (e.len-Re) (e.len-Pe) (e.vars-Re) (e.vars-Pe),
    {
      <Get-Max e.vars-Re> :: e.max =
        <Get-Min e.vars-Pe> :: e.min,
        ((INFIX "<" (e.len-Re e.max) (e.len-Pe e.min)));
      /*empty*/;
    } :: e.cond1,
    {
      <Get-Max e.vars-Pe> :: e.max =
        <Get-Min e.vars-Re> :: e.min,
        ((INFIX ">" (e.len-Re e.min) (e.len-Pe e.max)));
      /*empty*/;
    } :: e.cond2,
    {
      e.cond1 : /*empty*/, e.cond2 : /*empty*/ = /*empty*/;
      (IF ((INFIX "||" e.cond1 e.cond2)) e.fail);
    } :: e.cond,
    e.cond
    <CC-Unknown-Lengths (e.fail) e.rest>;
  <RFP-Clear-Table &Unknown-Lengths>;
};

Get-Min
{
  t.var e.vars = <Get-Var Min t.var> <Get-Min e.vars>;
  /*empty*/ = /*empty*/;
};

Get-Max
{
  t.var e.vars = <Get-Var Max t.var> : v.max, v.max <Get-Max e.vars>;
  /*empty*/ = /*empty*/;
};

$func Pos (e.Re) s.dir e.pos = e.pos;

Pos {
  (e.Re) RIGHT e.pos = (INFIX "-" ((LENGTH e.Re)) (1) (e.pos));
  (e.Re) LEFT  e.pos = e.pos;
};

/*
 * Информацию о проверках и заведении переменных, необходимых для создания
 * клешей из содержимого скобок, кодируем на ASAIL.
 */
CC-Deref (e.fail) e.actions, e.actions : {
  (SYMBOL? e.Re (s.dir e.pos)) e.rest =
    (IF ((SYMBOL? e.Re (<Pos (e.Re) s.dir e.pos>))) e.fail)
    <CC-Deref (e.fail) e.rest>;
  (DEREF t.var e.Re (s.dir e.pos)) e.rest =
    (DEREF t.var e.Re (<Pos (e.Re) s.dir e.pos>))
    <CC-Deref (e.fail) e.rest>;
  /*empty*/ = /*empty*/;
};

CC-Eqs (e.fail) (e.assigns) e.eqs, {
  e.eqs : ((e.Re) (s.dir e.pos) t.Pt (e.len)) e.rest =
    {
      e.Re : t,
        <Get-Known-Length e.Re> : e.len (), // FIXME: здесь надо использовать
                          //        калькулятор
        s.dir e.pos : \{
          LEFT 0;
          RIGHT e.len;
        } =
        e.Re;;
    } :: e.Re-term,
    {
      e.len : 1 = TERM-EQ;      // FIXME: здесь надо использовать
                  //        калькулятор
      EQ;
    } :: s.eq,
    <Pos (e.Re) s.dir e.pos> :: e.pos,
    {
      \{
        <Get-Var Instantiated? t.Pt> : True = t.Pt (e.Re);
        t.Pt : \{
          (REF e);
          (STATIC e);
        }, {
          <Var? e.Re-term> = e.Re-term (t.Pt);
          t.Pt (e.Re);
        };
      } :: el (er),
        (IF ((NOT (s.eq el (er) (e.pos)))) e.fail) :: t.cond,
        {
          /*
           * Мы предполагаем, что во всех пришедших e.eqs все e.Re
           * уже были определены ранее.
           */
          e.assigns : $r e1 (s.op t.Pt e.def) e2 =
            <CC-Eqs (e.fail) (e1 (s.op t.Pt e.def) t.cond e2) e.rest>;
          t.cond <CC-Eqs (e.fail) (e.assigns) e.rest>;
        };
      <Set-Var (Instantiated? True) t.Pt>,
        {
          t.Pt : (SVAR e) =
            (IF
              ((NOT (SYMBOL? e.Re (<Pos (e.Re) s.dir e.pos>))))
              e.fail
            );;
        } :: e.cond,
        {
          <Get-Var Decl t.Pt> : s =
            e.cond <CC-Eqs (e.fail) (e.assigns
              (ASSIGN t.Pt (SUBEXPR e.Re (e.pos) (e.len))))
              e.rest>;
          <Vars-Decl t.Pt> : e,
            e.cond <CC-Eqs (e.fail) (e.assigns
              (SUBEXPR t.Pt e.Re (e.pos) (e.len))) e.rest>;
        };
    };
  e.assigns e.eqs;
};




Gener-Label e.QualifiedName =
  {
    <Lookup &Labels e.QualifiedName> : s.num,
      <"+" s.num 1>;
    1;
  } :: s.num,
  <Bind &Labels (e.QualifiedName) (s.num)>,
  (e.QualifiedName s.num);

Add-To-Label (e.label) e.name = <Gener-Label e.label "_" e.name>;




Lookup-Func t.Fname, \{
  <Lookup &Fun t.Fname>;
  <Lookup &Fun? t.Fname>;
} : s.linkage s.tag t.pragma (e.Fin) (e.Fout) =
  s.linkage s.tag t.pragma (e.Fin) (e.Fout);