source: to-imperative/trunk/compiler/rfp_compile.rf @ 1208

Last change on this file since 1208 was 1208, checked in by orlov, 17 years ago
  • Put constant declarations in cc-files instead of hh-ones.
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 41.5 KB
Line 
1// $Source$
2// $Revision: 1208 $
3// $Date: 2003-08-14 10:00:20 +0000 (Thu, 14 Aug 2003) $
4
5$use "rfpc";
6$use "rfp_list";
7$use "rfp_helper";
8$use "rfp_check";
9$use "rfp_as2as";
10$use "rfp_format";
11$use "rfp_vars";
12$use "rfp_const";
13$use "rfp_clashes";
14
15$use StdIO;
16$use Table;
17$use Box;
18$use Arithm;
19$use Access;
20$use Compare;
21$use Convert;
22$use Class;
23$use Apply;
24$use Dos;
25
26
27/*
28 * Table for storing object names.
29 */
30$table Objects;
31
32/*
33 * Table for storing parameters of referenced functions.
34 */
35$table Stub-Funcs;
36
37/*
38 * Box for storing function out format
39 */
40$box Out-Format;
41
42/*
43 * Box for storing names for function result variables
44 */
45$box Res-Vars;
46
47/*
48 * Following table is used by Gener-Label function for obtaining unical (for
49 * certain function) label name.
50 * e.Key ::= e.QualifiedName      (parameter given to Gener-Label)
51 * e.Val ::= [Int]          (last index used with such e.QualifiedName)
52 */
53$table Labels;
54
55/*
56 * Table for storing variables used in place of preprocessor-generated ones.
57 */
58$table Prep-Vars;
59
60
61$func Compile (e.targets) (e.headers) e.Items = e.Compiled-Items (INTERFACE e.headers);
62
63$func Comp-Func-Stubs = e.asail-funcs;
64
65$func Comp-Func s.tag t.name e.params-and-body = e.compiled-func;
66
67$func Set-Drops (e.declared-exprs) e.comp-func = (e.declared-exprs) e.result-func;
68
69$func Comp-Sentence e.Sentence = e.asail-sentence;
70
71$func Save-Snt-State = ;
72
73$func Recall-Snt-State = ;
74
75$func Pop-Snt-State = ;
76
77$func Extract-Calls e.Re = (e.last-Re) e.calls;
78
79$func Get-Clash-Sequence (e.last-Re) e.Snt = (e.clashes) e.rest-of-the-Sentence;
80
81$func? Without-Calls? e.Re = ;
82
83$func Comp-Clashes (e.clashes) s.tail? (v.fails) e.Sentence = e.asail-sentence;
84
85$func Gener-Label e.QualifiedName = t.label;
86
87$func Add-To-Label t.label e.name = t.label;
88
89$func Comp-Calls e.Re = e.calls;
90
91$func Prepare-Vars e.vars = e.vars;
92
93$func Prepare-Res e.Reult-exprs = e.Result-exprs;
94
95$func Comp-Assigns e.assignments = e.asail-assignments;
96
97$func Comp-Format (e.last-Re) e.He = e.assignments;
98
99
100
101************ Get AS-Items and targets, and pass it to Compile ************
102
103/*
104 * Ящик для объявлений статических функций, констант и объектов.  Все они
105 * выписываются в самом начале тела модуля.
106 */
107$box Declarations;
108
109RFP-Compile e.Items =
110  { <Lookup &RFP-Options ITEMS>;; } :: e.targets,
111  <RFP-Clear-Table &Stub-Funcs>,
112  <Store &Declarations /*empty*/>,
113  <Init-Consts>,
114  <Compile (e.targets) () e.Items> :: e.Items t.Interface,
115  <Comp-Func-Stubs> :: e.stub-funcs,
116  t.Interface (MODULE <? &Declarations> <Comp-Consts> e.Items e.stub-funcs);
117
118
119
120****************** Choose needed items and compile them ******************
121
122Compile (e.targets) (e.headers) e.Items, {
123  e.Items : e t.item e.rest,
124    {
125      e.targets : v =
126        e.targets : e t.name e,
127        t.item : (t t t t.name e);;
128    },
129    t.item : {
130      (IMPORT e) = () /*empty*/;
131      (s.link s.tag t.pragma t.name (e.in) (e.out) e.body), FUNC FUNC? : e s.tag e =
132        {
133          s.link : EXPORT = (DECL-FUNC t.name);
134          <Put &Declarations (DECL-FUNC t.name)> = /*empty*/;
135        } :: e.decl,
136        {
137          e.body : (BRANCH t.p e.branch) =
138            <Comp-Func s.tag t.name <Del-Pragmas (e.in) (e.out) e.branch>>;;
139        } :: e.comp-func,
140        (e.decl) e.comp-func;
141      (s.link CONST t.pragma t.name e.expr) =
142        (CONSTEXPR s.link t.name (e.expr) e.expr) :: t.const,
143        <Put &Declarations t.const>,
144        {
145          s.link : EXPORT = ((DECL-OBJ t.name)) /*empty*/;
146          () /*empty*/;
147        };
148      (EXPORT s.tag t.pragma t.name) =
149        <Put &Declarations (OBJ EXPORT s.tag t.name)>,
150        ((DECL-OBJ t.name)) /*empty*/;
151      (LOCAL  s.tag t.pragma t.name) =
152        <Put &Declarations (OBJ LOCAL s.tag t.name)>,
153        () /*empty*/;
154    } :: (e.decl) e.item =
155    e.item <Compile (e.targets) (e.headers e.decl) e.rest>;
156  /*<Comp-Func-Stubs>*/ (INTERFACE e.headers);
157};
158
159
160
161$func Gener-Stub e = e;
162
163/*
164 * For each referenced function generate a stub one with format e = e.
165 */
166Comp-Func-Stubs = <Map &Gener-Stub (<Domain &Stub-Funcs>)>;
167
168Gener-Stub (t.name) =
169  <Lookup &Stub-Funcs t.name> : t.stub-name s.tag (e.Fin) (e.Fout),
170  <Put &Declarations (DECL-FUNC t.stub-name)>,
171  <Gener-Vars (e.Fin) "stub"> :: e.He,
172  <Comp-Func s.tag t.stub-name ((EVAR ("arg" 1))) ((EVAR))
173    (LEFT e.He) (RESULT (CALL t.name e.He))>;
174
175
176
177Comp-Func s.tag t.name (e.in) (e.out) e.Sentence =
178  <RFP-Clear-Table &Labels>,
179  <RFP-Clear-Table &Prep-Vars>,
180  <Init-Vars>,
181  <Vars <Gener-Vars (e.out) "res">> :: e.res-vars,
182  <Vars-Decl e.res-vars> : e,
183  <Store &Res-Vars e.res-vars>,
184  <Store &Out-Format <Format-Exp e.out>>,
185  <Prepare-Res (e.in)> : (e.arg),
186  <Vars e.arg> :: e.arg-vars,
187  <Map &Set-Var- (Instantiated? True) (e.arg-vars)> : e,
188  s.tag : {
189    FUNC = FATAL;
190    FUNC? = RETFAIL;
191  } :: t.retfail,
192  (FUNC t.name (<Vars-Print e.arg-vars>) (<Vars-Print e.res-vars>)
193    <Comp-Sentence Tail ((t.retfail)) (e.arg) e.Sentence>
194  ) :: e.comp-func,
195*       <Set-Drops () <Gener-Var-Names e.comp-func>> :: t e.comp-func,
196  <Gener-Var-Names e.comp-func> :: e.comp-func,
197//!     <Post-Comp (e.res-vars) e.comp-func> :: t e.result,
198//!     e.result;
199  e.comp-func;
200//  :: (e.func-decl) e.func-body,
201//  () <Domain &Declarations> $iter {
202//    e.vars : (t.var) e.rest-vars,
203//      (e.var-decls (DECL t.var)) e.rest-vars;
204//  } :: (e.var-decls) e.vars,
205//  e.vars : /*empty*/,
206//  (e.func-decl e.var-decls e.func-body);
207
208Set-Drops (e.declared) e.comp-func =
209  e.comp-func () (e.declared) $iter {
210    e.comp-func : t.first e.rest, {
211      t.first : \{
212        (EXPR t.var e) = (DROP t.var) (t.first) t.var Init;
213        (DEREF t.var e) = (DROP t.var) (t.first) t.var Init;
214        (SUBEXPR t.var e) = (DROP t.var) (t.first) t.var Init;
215        (DECL Expr t.var) = (DROP t.var) () t.var Decl;
216        (DECL "int" t.var) = /*empty*/ () t.var Decl;
217      } :: e.drop (e.constr) t.var s.init,
218        {
219          e.declared : e1 t.var s.old-init e2, s.old-init : {
220            Init, {
221              t.var : (VAR ("const" e)) =
222                e.rest (e.result-func) (e.declared);
223              e.rest (e.result-func e.drop e.constr) (e.declared);
224            };
225            Decl, s.init : {
226              Decl =
227                e.rest (e.result-func) (e.declared);
228              Init =
229                t.first : (s.method t.var e.args),
230                e.rest (e.result-func (ASSIGN t.var (s.method e.args)))
231                (e1 e2 t.var s.init);
232                /*
233                 * FIXME: if s.method is EXPR, it shouldn't be written.
234                 */
235            };
236          };
237          e.rest (e.result-func t.first) (e.declared t.var s.init);
238        };
239      t.first : (LABEL (t.label) e.expr) =
240        <Set-Drops (e.declared) e.expr> :: (e.declared) e.expr,
241        e.rest (e.result-func (LABEL (t.label) e.expr)) (e.declared);
242      t.first : (e.expr) =
243        <Set-Drops (e.declared) e.expr> :: t e.expr,
244        e.rest (e.result-func (e.expr)) (e.declared);
245      t.first : s.symbol =
246        e.rest (e.result-func s.symbol) (e.declared);
247    };
248  } :: e.comp-func (e.result-func) (e.declared),
249  e.comp-func : /*empty*/ =
250  (e.declared) e.result-func;
251
252
253Comp-Sentence s.tail? (v.fails) (e.last-Re) e.Sentence, e.Sentence : {
254
255  /*empty*/ = /*empty*/;
256
257  /*
258   * In case of Re look if we should do a tailcall.  If not, then compile
259   * function calls from the Re and assign results to the out parameters or
260   * use them in compilation of the rest of the sentence.
261   */
262  (RESULT e.Re) e.Snt =
263    {
264      /*
265       * If the Re is the last action in the sentence then we can do
266       * tailcall if one of the following is true:
267       *  - Re is a call of non-failable function;
268       *  - Re is a call of a failable function, current function is
269       *  failable, and the failures stack is empty.
270       * In both cases out format of the called function should coincide
271       * with those of compiled one.
272       * FIXME: really we can do tailcall if all the parameters of
273       * compiled function that won't get their values from the call can
274       * be assigned from other sources.  Some support from runtime is
275       * needed though.
276       */
277      e.Snt : /*empty*/, s.tail? : Tail, e.Re : (CALL t.name e.arg),
278        { <In-Table? &Fun? t.name> = v.fails : (RETFAIL);; },
279        <Lookup-Func t.name> :: s.linkage s.tag t.pragma (e.Fin) (e.Fout),
280        <Subformat? (e.Fout) (<? &Out-Format>)> =
281        <Extract-Calls e.arg> :: (e.last-Re) e.calls,
282        <Prepare-Res <Split-Re (e.Fin) e.last-Re>> :: e.splited-Re,
283        <Comp-Calls <R 0 v.fails> e.calls>
284        (TAILCALL t.name (e.splited-Re) (<? &Res-Vars>));
285
286      <Extract-Calls e.Re> :: (e.last-Re) e.calls,
287        <Comp-Calls <R 0 v.fails> e.calls> :: e.comp-calls,
288        {
289          e.Snt : /*empty*/, s.tail? : Tail =
290            <Split-Re (<? &Out-Format>) e.last-Re> :: e.splited-Re,
291            <Prepare-Res e.splited-Re> :: e.splited-Re,
292            e.comp-calls <Comp-Assigns <Zip (<? &Res-Vars>) (e.splited-Re)>>;
293
294          e.comp-calls <Comp-Sentence s.tail? (v.fails) (e.last-Re) e.Snt>;
295        };
296    };
297
298  /*
299   * In case of He compile assignments from last Re and then (with new state
300   * of variables) proceed with the rest of the sentence.
301   */
302  (FORMAT e.He) e.Snt =
303    <Comp-Format (e.last-Re) e.He>
304    <Comp-Sentence s.tail? (v.fails) () e.Snt>;
305
306  /*
307   * In case of Pe get from the begining of the sentence a maximum possible
308   * sequence of clashes and compile it.  New values of variables from the
309   * clashes use in the compilation of the rest of the sentence.
310   */
311  (s.dir e.Pattern) e.Snt, s.dir : \{ LEFT; RIGHT; } =
312    <Get-Clash-Sequence (e.last-Re) e.Sentence> :: (e.clashes) e.Sentence,
313    <Comp-Clashes (e.clashes) s.tail? (v.fails) e.Sentence>;
314
315  (s.block) e, BLOCK BLOCK? : e s.block e = <WriteLN! &StdErr "Empty block?">, $fail;
316
317  /*
318   * In case of a block first see if its results are needed for something
319   * after the block and determine whether the block is a source.  Then
320   * compile each branch in turn.
321   */
322  (s.block e.branches) e.Snt,
323    s.block : \{
324      BLOCK = (FATAL);
325      BLOCK?;
326    } :: e.fatal? =
327    /*
328     * If the block initializes an $iter then extract from the $iter the He
329     * for placing it in the end of each branch.
330     * Then look if the block is used by a pattern or format expression.
331     * If so, we should declare variables from that expression before
332     * entering any branch -- those should be visible after the block.
333     * Pattern or format expression is placed in the end of each branch.
334     * But if a branch computes to $error, the expression shouldn't be
335     * used, so protect it with (Comp If-not-error).
336     * If next after the block is (Comp Error) then block results should be
337     * used as values for $error, so place (Comp Error) in the end of each
338     * branch.
339     * If next after the block is (Comp If-not-error) then our block is in
340     * the end of a branch of an outer block and has next pattern or format
341     * inherited from there.  In that case we should place all the sentence
342     * rest in the end of each branch because the block can be inside the
343     * $error already.
344     */
345    {
346      e.Snt : (ITER t.body t.format t.cond) e.rest =
347        t.format (Comp Iter t.body t.format t.cond) e.rest;
348      e.Snt;
349    } :: e.Snt,
350    e.Snt : {
351      t.first e.rest, t.first : \{
352        (LEFT e.pattern) = e.pattern;
353        (RIGHT e.pattern) = e.pattern;
354        (FORMAT e.format) = e.format;
355      } :: e.expr =
356        <Prepare-Vars <Vars e.expr>> :: e.vars,
357        (e.vars) ((Comp If-not-error) t.first)
358        ((Comp Source)) e.rest;
359      (Comp Error) e.rest =
360        () ((Comp Error)) () /*empty*/;
361      (Comp If-not-error) e.rest =
362        () (e.Snt) () /*empty*/;
363      e = () () () e.Snt;
364    } :: (e.out-vars) (e.next-terms) (e.source?) e.Snt,
365    /*
366     * The block is a source if after it goes pattern or format expression
367     * (in that case e.source? isn't empty) or e.Snt isn't empty.
368     * Branches in the block are tail sentences if the current sentence is
369     * tail and the block isn't a source.
370     */
371    {
372      \{ e.source? : v; e.Snt : v; } = ((Comp Source) <R 0 v.fails>) Notail;
373      s.tail? : Tail = () Tail;
374      () Notail;
375    } :: (e.source?) s.tail-branch?,
376    /*
377     * In case our block is a source we should mark the position in the
378     * failures stack, so that we can jump to it after CUTALL.  And if our
379     * block isn't failable we should add (FATAL) to the end of the stack.
380     */
381    v.fails e.source? e.fatal? :: v.branch-fails,
382    /*
383     * Before compile the branches mark all out-vars as declared.
384     */
385    <Vars-Decl e.out-vars> :: e.decls,
386    /*
387     * We put all compiled branches in a block, so positive return from a
388     * branch is a break from that block.
389     * Each branch in its turn is placed in its own block, so for a $fail
390     * to the next branch we should just break from that inner block.
391     * Each branch is compiled with the current sentence state and the
392     * state is recalled after that.  When all branches are compiled the
393     * state is popped out from the stack.
394     * If last branch fails then the whole block fails, and return from the
395     * last branch is return from the block.  So the last branch isn't
396     * placed in a block and is processed with the failures stack that was
397     * before entering the block.  Note: this trick helps us find more
398     * tailcalls.  If the call of a failable function is on the last branch
399     * of the block and the failures stack is empty we can do tailcall.
400     * When the last branch is compiled with the block's stack, all we
401     * should do is to check it.
402     */
403    <Gener-Label "block"> :: t.label,
404    <Save-Snt-State>,
405    (e.branches) /*e.comp-branches*/ $iter {
406      e.branches : (BRANCH e.branch) e.rest-br =
407        <Add-To-Label t.label "branch"> :: t.br-label,
408        <Comp-Sentence
409          s.tail-branch?
410          (v.branch-fails ((BREAK t.br-label)))
411          (e.last-Re)
412          e.branch e.next-terms
413        > :: e.comp-br,
414        <Recall-Snt-State>,
415        (e.rest-br) e.comp-branches (LABEL (t.br-label) e.comp-br (BREAK t.label));
416    } :: (e.branches) e.comp-branches,
417    e.branches : (BRANCH e.branch) =
418    <Comp-Sentence
419      s.tail-branch? (v.branch-fails) (e.last-Re) e.branch e.next-terms
420    > :: e.last-branch,
421    <Pop-Snt-State>,
422    <Map &Set-Var- (Instantiated? True) (e.out-vars)> : e,
423    e.decls (LABEL (t.label) e.comp-branches e.last-branch)
424    <Comp-Sentence s.tail? (v.fails) () e.Snt>;
425
426  /*
427   * In case of $iter first of all compile initial assignment to the hard
428   * expression.
429   */
430  (ITER t.body t.format t.cond) e.Snt =
431    <Comp-Sentence s.tail? (v.fails) (e.last-Re)
432      t.format (Comp Iter t.body t.format t.cond) e.Snt
433    >;
434
435  /*
436   * Then compile $iter condition and body both with the current state of the
437   * sentence.
438   * e.Snt can contain (Comp Error) and (protected from errors) pattern or
439   * format which comes from an outer block, so compile it together with the
440   * condition.
441   * If condition fails we should compute the body, so put the compiled
442   * condition in a block and place a break from it to the failures stack.
443   */
444  (Comp Iter (BRANCH e.body) t.format (BRANCH e.condition)) e.Snt =
445    <Gener-Label "iter"> :: t.label,
446    <Gener-Label "exit_iter"> :: t.exit,
447    <Save-Snt-State>,
448    <Comp-Sentence s.tail? (v.fails ((BREAK t.label))) () e.condition e.Snt>
449      :: e.comp-condition,
450    <Pop-Snt-State>,
451    <Comp-Sentence Notail (v.fails) () e.body t.format> :: e.comp-body,
452    (FOR (/*cont-label*/) (t.exit) () ()
453      (LABEL (t.label) e.comp-condition (BREAK t.exit)) e.comp-body
454    );
455
456  /*
457   * In case of $trap/$with at first compile try-sentence.  All $fails from
458   * it should become errors.
459   * Then recall the state of the sentence and compile catching of an error
460   * with a variable err.
461   * e.Snt can contain (Comp Error) and (protected from errors) pattern or
462   * format which comes from an outer block, so compile it together with both
463   * sentences.
464   */
465  (TRY (BRANCH e.try) e.catch) e.Snt =
466    <Save-Snt-State>,
467    <Comp-Sentence Notail ((FATAL)) () e.try e.Snt> :: e.comp-try,
468    <Pop-Snt-State>,
469    <Gener-Err-Var> :: t.var,
470    <Set-Var (Instantiated? True) t.var>,
471    <Comp-Sentence s.tail? (v.fails) (t.var) e.catch e.Snt> :: e.comp-catch,
472    (TRY e.comp-try) (CATCH-ERROR e.comp-catch);
473
474  /*
475   * In case of \? add Stake to the failures stack.  Add last fail after it
476   * for <R 0 v.fails> continue to work.
477   */
478  (STAKE) e.Snt =
479    <Comp-Sentence s.tail? (v.fails (Comp Stake) <R 0 v.fails>) () e.Snt>;
480
481  /*
482   * In case of \! forget all failure catchers after last \?.
483   * If there is no Stake then we are inside negation or error (we assume the
484   * program is correct).  So the right failure catcher is in the bottom of
485   * the stack.
486   */
487  (CUT) e.Snt =
488    {
489      v.fails : $r v.earlier-fails (Comp Stake) e = v.earlier-fails;
490      <L 0 v.fails>;
491    } :: v.fails,
492    <Comp-Sentence s.tail? (v.fails) () e.Snt>;
493
494  /*
495   * In case of = clear the failures stack up to the closest source.
496   */
497  (CUTALL) e.Snt =
498    {
499      v.fails : $r v.earlier-fails (Comp Source) e = v.earlier-fails;
500      <L 0 v.fails>;
501    } :: v.fails,
502    <Comp-Sentence s.tail? (v.fails) () e.Snt>;
503
504  /*
505   * In case of = in the Refal-6 sense (non-transparent hedge for the fails),
506   * $fail(k) should become $error(Fname "Unexpected fail"), so clear the
507   * failures stack and put that value in it.
508   */
509  NOFAIL e.Snt =
510    <Comp-Sentence s.tail? ((FATAL)) (e.last-Re) e.Snt>;
511
512  /*
513   * In case of $fail return last failure catcher.
514   */
515  (FAIL) e.Snt =
516    v.fails : e (e.last-fail),
517    e.last-fail;
518
519  /*
520   * In case of # we should proceed with the rest if the source is computed
521   * to $fail.
522   * We could compile the rest of the sentence and place it in the
523   * failures stack.  But then the compiled sentence would be copied as many
524   * times as there are $fail's to the upper level in the source.  So we
525   * place compiled source in the block and put the break to exit from it in
526   * the stack.
527   * When compiling the source mark it as Notail as usual.
528   * If the source isn't computed to $fail we should proceed with the last
529   * failure catcher.
530   */
531  (NOT (BRANCH e.branch)) e.Snt =
532    <Gener-Label "negation"> :: t.label,
533    v.fails : e (e.last-fail),
534//    <Save-Snt-State>,
535    <Comp-Sentence Notail (((BREAK t.label))) () e.branch> e.last-fail
536      :: e.comp-negation,
537//    <Pop-Snt-State>,
538    (LABEL (t.label) e.comp-negation) <Comp-Sentence s.tail? (v.fails) () e.Snt>;
539
540  /*
541   * In case of $error all fails become $error(Fname "Unexpected fail").  So
542   * place that value in the failures stack and then compile the computation
543   * of the rest of the sentence and the last Re which should be the value of
544   * $error.
545   */
546  (ERROR) e.Snt =
547    <Comp-Sentence Notail ((FATAL)) () e.Snt (Comp Error)>;
548
549  (Comp Error) e.Snt =
550    <Prepare-Res (e.last-Re)> : (e.Re),
551    (ERROR e.Re);
552
553  /*
554   * Protection mark to be used between source and tail.  If there is $error
555   * construction somewhere in the source then the tail shouldn't be
556   * computed, but instead the source value should be used for throwing.
557   */
558  (Comp If-not-error) e.Snt =
559    {
560      e.Snt : e (Comp Error) =
561        <Comp-Sentence s.tail? (v.fails) (e.last-Re) (Comp Error)>;
562      <Comp-Sentence s.tail? (v.fails) (e.last-Re) e.Snt>;
563    };
564
565//  (Comp Fatal) = FATAL;
566
567//  (Comp Retfail) = RETFAIL;
568
569};
570
571
572
573********** Sentence state stack and functions for work with it. **********
574
575$box Snt-State;
576
577/*
578 * Put current state in the stack.
579 */
580Save-Snt-State = <Put &Snt-State <Vars-Copy-State>>;
581
582/*
583 * Set current state to that at the top of the stack.
584 */
585Recall-Snt-State = <Vars-Set-State <R 0 <? &Snt-State>>>;
586
587/*
588 * Pop the top from the stack and set current state to it.
589 */
590Pop-Snt-State =
591  <Recall-Snt-State>,
592  <Store &Snt-State <Middle 0 1 <? &Snt-State>>>;
593
594
595
596********************** Function calls compilation. ***********************
597
598/*
599 * $func Extract-Calls e.Re = (e.last-Re) e.calls;
600 *
601 *
602 *
603 */
604Extract-Calls {
605  (CALL t.name e.arg) e.rest =
606    <Lookup-Func t.name> :: s.linkage s.tag t.pragma (e.Fin) (e.Fout),
607    <Extract-Calls e.arg> :: (e.last-Re) e.calls,
608    <Prepare-Res <Split-Re (e.Fin) e.last-Re>> :: e.splited-Re,
609    <RFP-Extract-Qualifiers t.name> :: t e.prefix,
610    <Gener-Subst-Vars (e.Fout) e.prefix> :: e.Re,
611    <Vars e.Re> :: e.vars,
612    <Map &Set-Var- (Instantiated? True) (e.vars)> : e,
613    {
614      s.tag : FUNC? =   (Failable (CALL t.name (e.splited-Re) (e.vars)));
615      (CALL t.name (e.splited-Re) (e.vars));
616    } :: t.call,
617    <Extract-Calls e.rest> :: (e.rest-Re) e.rest-calls,
618    (e.Re e.rest-Re) e.calls <Vars-Decl e.vars> t.call e.rest-calls;
619  (PAREN e.Re) e.rest =
620    <Extract-Calls e.Re> :: (e.last-Re) e.calls,
621    <Extract-Calls e.rest> :: (e.rest-Re) e.rest-calls,
622    ((PAREN e.last-Re) e.rest-Re) e.calls e.rest-calls;
623  t.Rt e.Re =
624    <Extract-Calls e.Re> :: (e.last-Re) e.calls,
625    (t.Rt e.last-Re) e.calls;
626  /*empty*/ = () /*empty*/;
627};
628
629
630Comp-Calls (e.fail) e.calls, e.calls : {
631  (Failable t.call) e.rest =
632    (IF ((NOT t.call)) e.fail) <Comp-Calls (e.fail) e.rest>;
633  t.call e.rest =
634    t.call <Comp-Calls (e.fail) e.rest>;
635  /*empty*/ = /*empty*/;
636};
637
638
639
640********** Preparation of vars and REs for following processing **********
641*********** Compilation of static parts of result expressions ************
642
643$func Static-Expr? s.create? e.Re = static? e.Re;
644
645$func Static-Term? t.Rt = static? t.Rt;
646
647$func Find-Ref-Funcs expr = expr;
648
649$func Stub-Name t.name = t.stub-name;
650
651
652/*
653 * Extract static parts from each Re.
654 * Also get the right names for variables generated during the preprocessing
655 * stage, if those are in the expr.
656 */
657Prepare-Res {
658  (e.Re) e.rest = <Static-Expr? Create e.Re> :: s e.Re, (e.Re) <Prepare-Res e.rest>;
659  /*empty*/     = /*empty*/;
660};
661
662/*
663 * Find all the longest static parts in the upper level of Re.  Create STATIC
664 * form in place of each one.
665 * Return a tag pointing whether the whole expression is static and expression
666 * with static parts replaced by STATIC forms.  Dynamic parts are returned
667 * unchanged.
668 */
669Static-Expr? {
670  s.create? t.Rt e.Re =
671    <Static-Term? t.Rt> : {
672      Static t.st-Rt =
673        {
674          e.Re : e1 t2 e3, <Static-Term? t2> : Dynamic t.dyn-Rt =
675            <Static-Expr? Create e3> :: s e3,
676            Dynamic
677            <Create-Static <Find-Ref-Funcs t.st-Rt e1>> t.dyn-Rt e3;
678          {
679            s.create? : Create =
680              Static
681              <Create-Static <Find-Ref-Funcs t.st-Rt e.Re>>;
682            Static <Find-Ref-Funcs t.st-Rt e.Re>;
683          };
684        };
685      Dynamic t.dyn-Rt =
686        <Static-Expr? Create e.Re> :: s e.Re,
687        Dynamic t.dyn-Rt e.Re;
688    };
689  s.create? /*empty*/ = Static;
690};
691
692
693/*
694 * The same as Static-Expr? but for terms.
695 */
696Static-Term? {
697  symbol       = Static symbol;
698  (PAREN e.Re) = <Static-Expr? Not-Create e.Re> :: static? e.Re, static? (PAREN e.Re);
699  (REF t.name) = Static (REF t.name);
700  t.var        = <Prepare-Vars t.var> : t.prep-var, Dynamic t.prep-var;
701};
702
703
704Prepare-Vars {
705  (s.var-tag (e.prefix s.n)) e.rest, <Int? s.n> =
706    {
707      <Lookup &Prep-Vars e.prefix s.n>;
708      <Gener-Vars ((s.var-tag)) e.prefix> :: e.var,
709        <Bind &Prep-Vars (e.prefix s.n) (e.var)>,
710        e.var;
711    } :: e.var,
712    e.var <Prepare-Vars e.rest>;
713  t.var e.rest = t.var <Prepare-Vars e.rest>;
714  /*empty*/ = /*empty*/;
715};
716
717
718$func Ref-Func? e = e;
719
720Find-Ref-Funcs expr = <Map &Ref-Func? (expr)>;
721
722Ref-Func? {
723  (REF t.name) =
724    {
725      <Lookup-Func t.name> : {
726        t t t ((EVAR)) ((EVAR)) = (FUNC t.name);
727        s.linkage s.tag t.pragma (e.Fin) (e.Fout) =
728          {
729            <Lookup &Stub-Funcs t.name> : t.stub-name e =
730              (FUNC t.stub-name);
731            <Stub-Name t.name> :: t.stub-name,
732              <Bind &Stub-Funcs (t.name)
733                (t.stub-name s.tag (e.Fin) (e.Fout))>,
734              (FUNC t.stub-name);
735          };
736      };
737      (REF t.name);
738    };
739  term = term;
740};
741
742
743/*
744 * Генерируем уникальные внутри модуля имена для функций-заглушек.
745 */
746Stub-Name (e.qualifiers s.name) =
747  <To-Chars s.name> : {
748    e1 '_' s.n, <Int? s.n> = e1 '_' <"+" s.n 1>;
749    e1 = e1 '_' 0;
750  } :: e.name,
751  (e.qualifiers <To-Word e.name>) :: t.name,
752  {
753    <Lookup-Func t.name> : e = <Stub-Name t.name>;
754    t.name;
755  };
756
757
758
759***************** Compilation of assignment to variables *****************
760
761$func Comp-Assign-to-Var e = e;
762
763Comp-Assign-to-Var (t.var (e.Re)) =
764  {
765    t.var : e.Re = /*empty*/;
766    <Set-Var (Instantiated? True) t.var>, $fail;
767    <Substitutable-Var? e.Re> = <Gener-Var-Assign t.var e.Re>;
768    <Get-Var Decl t.var> : s = (ASSIGN <Vars-Print t.var> e.Re);
769    <Vars-Decl t.var> : e, (EXPR <Vars-Print t.var> e.Re);
770  };
771
772Comp-Assigns e.assigns = <Map &Comp-Assign-to-Var (e.assigns)>;
773
774
775
776************************** FORMAT compilation. ***************************
777
778$box Aux-Index;
779
780$func Gener-Aux-Var = t.new-aux-var;
781
782Gener-Aux-Var =
783  <? &Aux-Index> : s.n,
784  <Store &Aux-Index <"+" s.n 1>>,
785  (VAR ("aux" s.n));
786
787
788$func Create-Aux-Vars (e.vars) e.splited-Re = e.assigns;
789
790
791Comp-Format (e.last-Re) e.He =
792  <Prepare-Vars <Vars e.He>> :: e.vars,
793  <Prepare-Res <Split-Re (<Format-Exp e.He>) e.last-Re>> :: e.splited-Re,
794  <Store &Aux-Index 1>,
795  <Create-Aux-Vars (e.vars) e.splited-Re> :: e.assigns,
796  <Comp-Assigns e.assigns>;
797
798/*
799 * Итак, e.vars -- все переменные, входящие в форматное выражение.  Каждая
800 * переменная может входить в форматное выражение только один раз, поэтому
801 * повторяющихся среди них нет.
802 * e.splited-Re -- набор результатных выражений.  На каждую переменную из
803 * e.vars по выражению, которое должно быть ей присвоено.
804 *
805 * Если переменная t.var_i используется в выражении e.Re_j, и i /= j, то
806 * переменной t.var_j значение должно быть присвоено раньше, чем перeменной
807 * t.var_i.  Если же, по аналогичным соображениям, t.var_i должна получить
808 * значение раньше t.var_j, необходимо завести вспомогательную переменную.
809 *
810 * Пример:
811 *
812 * t1 (t1 t2) (t1 t3) :: t2 t1 t3
813 *
814 * t3 = (t1 + t3)();
815 * aux_1 = t1;
816 * t1 = (t1 + t2)()
817 * t2 = aux_1;
818 *
819 * В общем случае вспомогательная переменная требуется, если двум переменным
820 * необходимы старые значения друг друга (возможно, не напрямую, а через
821 * промежуточные переменные).
822 *
823 * Вместо того, чтобы искать и анализировать такие циклы, будем действовать по
824 * методу "наибольшей пользы".  А именно:
825 *
826 *   - Для каждой переменной выпишем все другие переменные, которым требуется
827 *     её старое значение, а также отдельно те, старые значения которых
828 *     требуются ей.
829 *
830 *   - Всем переменным, от старых значений которых ничего не зависит, можно
831 *     смело присвоить новые значения.  При этом они исчезают из списков
832 *     зависимостей оставшихся переменных.
833 *
834 *   - Все переменные, новые значения которых ни от чего не зависят, можно
835 *     отложить, чтобы присвоить им значения тогда, когда будет удобно.  Т.е.
836 *     тогда, когда списки зависящих от них переменных опустеют.
837 *
838 *   - Чтобы означить оставшиеся, нужны вспомогательные переменные.  Выберем
839 *     одну из переменных, с максимальным списком тех, от которых она зависит,
840 *     и положим её значение во вспомогательную переменную.  Так как мы сразу
841 *     уменьшили кол-во зависимостей у максимального кол-ва переменных,
842 *     локально мы добились наибольшей пользы, хотя не исключено, что глобально
843 *     такой метод и не даст наименьшего кол-ва вспомогательных переменных.
844 *     Кроме того, мы не пытаемся выбрать наилучшую переменную из нескольких с
845 *     максимальным списком зависимостей.
846 *
847 *   - Повторяем всё это до тех пор, пока у каждой переменной не опустеет
848 *     список зависящих от неё.
849 *
850 *
851 * Для нашего примера:
852 *
853 * t1 (t1 t2) (t1 t3) :: t2 t1 t3
854 *
855 * t1 -- (t2 t3) (t2)
856 * t2 -- (t1)    (t1)
857 * t3 -- ()      (t1)
858 *
859 *
860 * Для каждой переменной var_i найдём все j /= i, такие что в Re_j встречается
861 * var_i -- provide[i], и а также все j /= i, такие что var_j нужна для
862 * подсчёта var_i, т.е. встречается в Re_i.
863 *
864 * Res-vars <- <Map &Vars (Res)>
865 * for var_i in vars
866 *     provide[i] <-
867 *     for vars-Re_j in Res-vars, j /= i
868 *         vars-Re_j : e var_i e = j
869 *     require[i] <- <Res-vars[i] `*` vars[^i]> : e var_j e, j
870 *
871 * Res-vars = map Vars Res
872 * provide, require =
873 *   {   [ j | vars-Re_j <- Res-vars, j /= i, var_i `in` vars-Re_j ]
874 *     , [ j | var_j <- Res-vars[i] `*` vars, i /= j]
875 *     | var_i <- vars
876 *   }
877 *
878 */
879
880$func CAV e.vars (e.assigns) (e.delayed) = e.assigns;
881
882$func Get-Vars e = e;
883Get-Vars (e.Re) = (<Vars e.Re>);
884
885Create-Aux-Vars (e.vars) e.splited-Re =
886  <Zip (<Map &Get-Vars (e.splited-Re)>) (e.vars)> :: e.list,
887  <Box> :: s.box,
888  <Box> :: s.provide-i,
889  <Box> :: s.require-i,
890  {
891    e.vars : e1 t.var-i e2,
892      {
893        e.list : e ((e.vars-Re) t.var-j) e,
894          \{
895            t.var-i : t.var-j = <Put s.require-i <And (e1 e2) e.vars-Re>>;
896            e.vars-Re : e t.var-i e = <Put s.provide-i t.var-j>;
897          },
898          $fail;
899        <L <Length e1> e.splited-Re> :: t.Re-i,
900        <Put s.box (t.var-i t.Re-i (<? s.provide-i>) (<? s.require-i>))>,
901          <Store s.provide-i /*empty*/>,
902          <Store s.require-i /*empty*/>;
903      },
904      $fail;;
905  },
906  <CAV <? s.box> (/*assigns*/) (/*delayed*/)>;
907
908
909/*
910 * Если есть переменная, у которой список provide пуст, её можно посчитать.
911 * Это выражается в том, что она (вместе с присваиваемым значением) добавляется
912 * в список assigns, убирается из списка vars, а также из всех списков provide
913 * и delayed.  В списках require её не было.
914 *
915 * CAV Res vars provide require assigns delayed =
916 *   { i | var_i <- vars, provide_i == [] } ->     // Здесь неверно!  На переменные
917 *                                                    из delayed тоже надо смотреть.
918 *       vars    = vars - var_i
919 *       provide = [ provide_j - i | provide_j <- provide ]
920 *       assigns = assigns++[(var_i, Res[i])]
921 *       delayed = [ (var_j, provide_j - i) | (var_j, provide_j) <- delayed ]
922 *       CAV Res vars provide require assigns delayed
923 */
924
925$func Assign-Empty-Provides e.vars  = e.assigns (e.vars);
926
927Assign-Empty-Provides {
928  e1 (t.var-i t.Re-i (/*empty provide_i*/) (e.require-i)) e2 =
929    <Box> :: s.vars,
930    {
931      e1 e2 : e (t.var-j t.Re-j (e.provide-j) (e.require-j)) e,
932        <Put s.vars (t.var-j t.Re-j (<Sub (e.provide-j) t.var-i>) (e.require-j))>,
933        $fail;;
934    },
935    (t.var-i t.Re-i) <Assign-Empty-Provides <? s.vars>>;
936  e.vars = /*empty*/ (e.vars);
937};
938
939
940/*
941 * Если есть переменная, у которой список require пуст, кладём её в delayed.
942 * Она будет посчитана, когда у неё опустеет список provide, т.е. когда не
943 * останется переменных, у которых она в списке require.
944 */
945$func Delay-Empty-Requires e.vars  = e.delayed (e.vars);
946
947Delay-Empty-Requires {
948  e1 t.var e2, t.var : (t.var-i t.Re-i (e.provide-i) (/*empty require_i*/)) =
949    <Delay-Empty-Requires e2> :: e.delayed (e.vars),
950    t.var e.delayed (e1 e.vars);
951  e.vars = /*empty*/ (e.vars);
952};
953
954
955/*
956 * Выбор переменной (из двух) с более длинным списком требуемых ей значений.
957 */
958$func Max-Require e = e;
959
960Max-Require t.arg1 t.arg2 =
961  t.arg1 : (t.var1 t.Re1 t.provide1 (e.require1)),
962  t.arg2 : (t.var2 t.Re2 t.provide2 (e.require2)),
963  {
964    <"<" (<Length e.require1>) (<Length e.require2>)> = t.arg2;
965    t.arg1;
966  };
967
968
969/*
970 * Подставить вспомогательную переменную вместо исходной во всех результатных выражениях.
971 * Присваивание к исходной переменной убрать (оно к этому моменту уже выполнено).
972 * Убрать переменную из списков зависимостей.
973 */
974$func Subst-Aux-Var e = e;
975
976Subst-Aux-Var t.var t.aux (t.v t.Re (e.provide) (e.require)), {
977  t.var : t.v = /*empty*/;
978  (
979    t.v
980    <Subst (t.var) ((t.aux)) t.Re>
981    (<Sub (e.provide) t.var>)
982    (<Sub (e.require) t.var>)
983  );
984};
985
986
987/*
988 * Извлечь присваивание из всей информации о переменной.
989 */
990$func Extract-Assigns e = e;
991Extract-Assigns (t.var t.Re e) = (t.var t.Re);
992
993
994/*
995 * Основной цикл обработки присваиваний.
996 *
997 * 1) Из всех переменных (в том числе и отложенных), от которых больше ничего
998 *    не зависит, сделать присваивания.
999 * 2) Все переменные, которые больше ни от чего не зависят, отложить.
1000 * 3) Если осталось хотя бы две неотложенных переменных, выбирать из них ту,
1001 *    которая зависит от наибольшего числа переменных, подставить везде вместо
1002 *    неё вспомогательную, перейти к пункту 1.
1003 */
1004CAV e.vars (e.assigns) (e.delayed) =
1005  <Assign-Empty-Provides e.vars> :: e.new-assigns (e.vars),
1006  e.assigns e.new-assigns <Assign-Empty-Provides e.delayed> :: e.assigns (e.delayed),
1007  e.delayed <Delay-Empty-Requires e.vars> :: e.delayed (e.vars),
1008  {
1009    e.vars : t t e =
1010      <Foldr1 &Max-Require (e.vars)> : (t.var t.Re e),
1011      <Gener-Aux-Var> :: t.aux,
1012      e.assigns (t.aux (t.var)) (t.var t.Re) :: e.assigns,
1013      <Map &Subst-Aux-Var t.var t.aux (e.vars)> :: e.vars,
1014      <Map &Subst-Aux-Var t.var t.aux (e.delayed)> :: e.delayed,
1015      <CAV e.vars (e.assigns) (e.delayed)>;
1016    e.assigns <Map &Extract-Assigns (e.vars e.delayed)>;
1017  };
1018
1019
1020
1021
1022****************** Компиляция сопоставления с образцом *******************
1023
1024Get-Clash-Sequence (e.last-Re) t.Pattern e.Snt =
1025  (/*e.clashes*/) (RESULT e.last-Re) t.Pattern e.Snt $iter {
1026    e.Snt : (RESULT e.Re) (s.dir e.Pe) e.rest =
1027      /*
1028       * Компилируем все константные выражения и заводим в табличке все
1029       * незаведённые переменные.  У старых переменных очищается память
1030       * на предмет клешей, в которых они раньше использовались.
1031       */
1032      <Prepare-Res (e.Re) (e.Pe)> : (e.R1) (e.P1),
1033      <Map &Set-Var- (Clashes /*empty*/) (<Vars e.R1 e.P1>)> : e,
1034      (e.clashes (e.R1) (s.dir e.P1)) e.rest;
1035  } :: (e.clashes) e.Snt,
1036  # \{
1037    e.Snt : \{
1038      (RESULT e.Re) (LEFT e) e = e.Re;
1039      (RESULT e.Re) (RIGHT e) e = e.Re;
1040    } :: e.Re,
1041      <Without-Calls? e.Re>;
1042  } =
1043  (e.clashes) e.Snt;
1044
1045Without-Calls? e.Re =
1046  e.Re $iter {
1047    e.Re : t.Rt e.rest =
1048      t.Rt : {
1049        (CALL e) = $fail;
1050        (BLOCK e) = $fail;
1051        (PAREN e.Re1) = <Without-Calls? e.Re1>;
1052        t.symbol-or-var = /*empty*/;
1053      },
1054      e.rest;
1055  } :: e.Re,
1056  e.Re : /*empty*/;
1057
1058$func CC s.tail? (v.fails) t.end-cycle e.Snt = e.asail-Snt;
1059
1060Comp-Clashes (e.clashes) s.tail? (v.fails) e.Sentence =
1061  <Init-Clashes e.clashes>,
1062  <CC s.tail? (v.fails) <R 0 v.fails> e.Sentence>;
1063
1064$func CC-Known-Lengths t.fail e.idxs = e.conds;
1065
1066$func CC-Compute-Length t.fail t.end-cycle t.idx = e;
1067
1068$func CC-Unknown-Lengths t.fail e.idxs = e.conds;
1069
1070$func CC-Deref t.fail e.actions = e.actions;
1071
1072$func CC-Eqs t.fail (e.assigns) e.eqs = e.actions;
1073
1074CC s.tail? (v.fails) t.end-cycle e.Snt, {
1075  <Domain &Known-Lengths> : v.clashes =
1076    <CC-Known-Lengths t.end-cycle v.clashes>
1077    <CC s.tail? (v.fails) t.end-cycle e.Snt>;
1078  <Domain &Compute-Length> : (t.clash) e =
1079    <CC-Compute-Length <R 0 v.fails> t.end-cycle t.clash>
1080    <CC s.tail? (v.fails) t.end-cycle e.Snt>;
1081  <Domain &Unknown-Lengths> : e.clashes =
1082    <CC-Unknown-Lengths t.end-cycle e.clashes> :: e.conds,
1083    /*
1084     * Когда мы добрались до сюда, все условия на длины на текущем уровне
1085     * выписаны.  Невыполнение любого из оставшихся условий (на
1086     * соответствие типов, равенство, длины внутри скобок) ведёт не к
1087     * прекращению текущего цикла, а переход к его следующей итерации.
1088     * Поэтому в качестве t.end-cycle везде дальше подставляется текущий
1089     * откат.
1090     */
1091    <Update-Hard-Parts> : {
1092      v.actions =
1093        e.conds <CC-Deref <R 0 v.fails> v.actions>
1094        <CC s.tail? (v.fails) <R 0 v.fails> e.Snt>;
1095      /*empty*/ =
1096        e.conds <CC-Eqs <R 0 v.fails> () <? &Eqs>> :: e.actions,
1097        <Store &Eqs /*empty*/>,
1098        {
1099          <Compose-Source> :: e.assign =
1100            e.actions <CC-Eqs <R 0 v.fails> () e.assign>
1101            <CC s.tail? (v.fails) <R 0 v.fails> e.Snt>;
1102          {
1103            <Get-Cycle> :: s.split (e.left) (e.right) (e.len)
1104                    t.var t.l-var t.r-var =
1105              {
1106                e.left : 0, e.right : 0 = /*empty*/ t.var;
1107                <Gener-Vars ((VAR)) "subexpr_" t.var> : t.sub-var,
1108                  (SUBEXPR t.sub-var t.var (e.left)
1109                    ((INFIX "-" (e.len) (e.left e.right))))
1110                  t.sub-var;
1111              } :: e.subexpr t.var,
1112              {
1113                s.split : RSPLIT =
1114                  t.r-var t.l-var DEC-ITER;
1115                t.l-var t.r-var INC-ITER;
1116              } :: t.l-var t.r-var s.iter-op,
1117              <Gener-Label "continue"> :: t.cont-label,
1118              <Gener-Label "exit"> :: t.break-label,
1119              e.actions e.subexpr
1120              (s.split t.var (<Get-Var Min t.l-var>) t.l-var t.r-var)
1121              (FOR (t.cont-label) (t.break-label) () ((s.iter-op t.var))
1122                (IF ((NOT (CHECK-ITER t.var))) <Concat <R 0 v.fails>>)
1123                <CC s.tail?     (v.fails ((CONTINUE t.cont-label)))
1124                  <R 0 v.fails> e.Snt>
1125                (BREAK t.break-label)
1126              );
1127            e.actions <Comp-Sentence s.tail? (v.fails) () e.Snt>;
1128          };
1129        };
1130    };
1131};
1132
1133CC-Known-Lengths (e.fail) e.idxs, {
1134  e.idxs : (t.idx) e.rest =
1135    <Put &Checked-Lengths t.idx>,
1136    <Lookup &Known-Lengths t.idx> : (e.len-Re) (e.len-Pe),
1137    (IF ((INFIX "!=" (e.len-Re) (e.len-Pe))) e.fail)
1138    <CC-Known-Lengths (e.fail) e.rest>;
1139  <RFP-Clear-Table &Known-Lengths>;
1140};
1141
1142CC-Compute-Length (e.fail) (e.end-cycle) t.idx =
1143  <Lookup &Compute-Length t.idx> : t.var s.mult (e.minuend) (e.subtrahend),
1144  <Create-Int-Var ("len") Aux e.minuend> :: t.m-var e.m-assign,
1145  <Create-Int-Var ("len") Aux e.subtrahend> :: t.s-var e.s-assign,
1146  <Get-Var Min t.var> :: e.min,
1147  ((INFIX "<" (t.m-var)
1148        ((INFIX "+" (t.s-var)
1149              ((INFIX "*" (e.min) (s.mult)))
1150  ))                    )) :: e.min-cond,
1151  <Get-Var Max t.var> : {
1152    /*empty*/;
1153    e.max =
1154      ((INFIX ">" (t.m-var)
1155            ((INFIX "+" (t.s-var)
1156                  ((INFIX "*" (e.max) (s.mult)))
1157      ))                        ));
1158  } :: e.max-cond,
1159  (INFIX "%" ((INFIX "-" (t.m-var) (t.s-var))) (s.mult)) :: e.div-cond,
1160  <Create-Int-Var ("len_") t.var
1161    (INFIX "/" ((INFIX "-" (t.m-var) (t.s-var))) (s.mult))
1162  > :: t.len-var e.len-assign,
1163  <Set-Var (Length t.len-var) t.var>,
1164  <Unbind &Compute-Length t.idx>,
1165  <Put &Checked-Lengths t.idx>,
1166  <Get-Var Clashes t.var> :: e.clashes,
1167  <Map &Reclassify-Clash (<Sub (e.clashes) <? &Checked-Lengths>>)> : e,
1168  e.m-assign e.s-assign
1169  (IF ((INFIX "||" e.min-cond e.max-cond)) e.end-cycle)
1170  (IF (e.div-cond) e.fail)
1171  e.len-assign;
1172
1173$func  Get-Min e = e;
1174
1175$func? Get-Max e = e;
1176
1177CC-Unknown-Lengths (e.fail) e.idxs, {
1178  e.idxs : (t.idx) e.rest =
1179    <Lookup &Unknown-Lengths t.idx> : (e.len-Re) (e.len-Pe) (e.vars-Re) (e.vars-Pe),
1180    {
1181      <Get-Max e.vars-Re> :: e.max =
1182        <Get-Min e.vars-Pe> :: e.min,
1183        ((INFIX "<" (e.len-Re e.max) (e.len-Pe e.min)));
1184      /*empty*/;
1185    } :: e.cond1,
1186    {
1187      <Get-Max e.vars-Pe> :: e.max =
1188        <Get-Min e.vars-Re> :: e.min,
1189        ((INFIX ">" (e.len-Re e.min) (e.len-Pe e.max)));
1190      /*empty*/;
1191    } :: e.cond2,
1192    {
1193      e.cond1 : /*empty*/, e.cond2 : /*empty*/ = /*empty*/;
1194      (IF ((INFIX "||" e.cond1 e.cond2)) e.fail);
1195    } :: e.cond,
1196    e.cond
1197    <CC-Unknown-Lengths (e.fail) e.rest>;
1198  <RFP-Clear-Table &Unknown-Lengths>;
1199};
1200
1201Get-Min
1202{
1203  t.var e.vars = <Get-Var Min t.var> <Get-Min e.vars>;
1204  /*empty*/ = /*empty*/;
1205};
1206
1207Get-Max
1208{
1209  t.var e.vars = <Get-Var Max t.var> : v.max, v.max <Get-Max e.vars>;
1210  /*empty*/ = /*empty*/;
1211};
1212
1213$func Pos (e.Re) s.dir e.pos = e.pos;
1214
1215Pos {
1216  (e.Re) RIGHT e.pos = (INFIX "-" ((LENGTH e.Re)) (1) (e.pos));
1217  (e.Re) LEFT  e.pos = e.pos;
1218};
1219
1220/*
1221 * Информацию о проверках и заведении переменных, необходимых для создания
1222 * клешей из содержимого скобок, кодируем на ASAIL.
1223 */
1224CC-Deref (e.fail) e.actions, e.actions : {
1225  (SYMBOL? e.Re (s.dir e.pos)) e.rest =
1226    (IF ((SYMBOL? e.Re (<Pos (e.Re) s.dir e.pos>))) e.fail)
1227    <CC-Deref (e.fail) e.rest>;
1228  (DEREF t.var e.Re (s.dir e.pos)) e.rest =
1229    (DEREF t.var e.Re (<Pos (e.Re) s.dir e.pos>))
1230    <CC-Deref (e.fail) e.rest>;
1231  /*empty*/ = /*empty*/;
1232};
1233
1234CC-Eqs (e.fail) (e.assigns) e.eqs, {
1235  e.eqs : ((e.Re) (s.dir e.pos) t.Pt (e.len)) e.rest =
1236    {
1237      e.Re : t,
1238        <Get-Known-Length e.Re> : e.len (), // FIXME: здесь надо использовать
1239                          //        калькулятор
1240        s.dir e.pos : \{
1241          LEFT 0;
1242          RIGHT e.len;
1243        } =
1244        e.Re;;
1245    } :: e.Re-term,
1246    {
1247      e.len : 1 = TERM-EQ;      // FIXME: здесь надо использовать
1248                  //        калькулятор
1249      EQ;
1250    } :: s.eq,
1251    <Pos (e.Re) s.dir e.pos> :: e.pos,
1252    {
1253      \{
1254        <Get-Var Instantiated? t.Pt> : True = t.Pt (e.Re);
1255        t.Pt : \{
1256          (REF e);
1257          (STATIC e);
1258        }, {
1259          <Var? e.Re-term> = e.Re-term (t.Pt);
1260          t.Pt (e.Re);
1261        };
1262      } :: el (er),
1263        (IF ((NOT (s.eq el (er) (e.pos)))) e.fail) :: t.cond,
1264        {
1265          /*
1266           * Мы предполагаем, что во всех пришедших e.eqs все e.Re
1267           * уже были определены ранее.
1268           */
1269          e.assigns : $r e1 (s.op t.Pt e.def) e2 =
1270            <CC-Eqs (e.fail) (e1 (s.op t.Pt e.def) t.cond e2) e.rest>;
1271          t.cond <CC-Eqs (e.fail) (e.assigns) e.rest>;
1272        };
1273      <Set-Var (Instantiated? True) t.Pt>,
1274        {
1275          t.Pt : (SVAR e) =
1276            (IF
1277              ((NOT (SYMBOL? e.Re (<Pos (e.Re) s.dir e.pos>))))
1278              e.fail
1279            );;
1280        } :: e.cond,
1281        {
1282          <Get-Var Decl t.Pt> : s =
1283            e.cond <CC-Eqs (e.fail) (e.assigns
1284              (ASSIGN t.Pt (SUBEXPR e.Re (e.pos) (e.len))))
1285              e.rest>;
1286          <Vars-Decl t.Pt> : e,
1287            e.cond <CC-Eqs (e.fail) (e.assigns
1288              (SUBEXPR t.Pt e.Re (e.pos) (e.len))) e.rest>;
1289        };
1290    };
1291  e.assigns e.eqs;
1292};
1293
1294
1295
1296
1297Gener-Label e.QualifiedName =
1298  {
1299    <Lookup &Labels e.QualifiedName> : s.num,
1300      <"+" s.num 1>;
1301    1;
1302  } :: s.num,
1303  <Bind &Labels (e.QualifiedName) (s.num)>,
1304  (e.QualifiedName s.num);
1305
1306Add-To-Label (e.label) e.name = <Gener-Label e.label "_" e.name>;
1307
1308
1309
1310
1311Lookup-Func t.Fname, \{
1312  <Lookup &Fun t.Fname>;
1313  <Lookup &Fun? t.Fname>;
1314} : s.linkage s.tag t.pragma (e.Fin) (e.Fout) =
1315  s.linkage s.tag t.pragma (e.Fin) (e.Fout);
1316
Note: See TracBrowser for help on using the repository browser.