source: to-imperative/trunk/compiler/rfp_compile.rf @ 1950

Last change on this file since 1950 was 1950, checked in by orlov, 15 years ago
  • A lot of changes for the compilation to Java. Self-translates to compilable Java-code!
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 43.2 KB
Line 
1// $Source$
2// $Revision: 1950 $
3// $Date: 2006-05-07 01:17:28 +0000 (Sun, 07 May 2006) $
4
5$use "rfpc";
6$use "rfp_helper";
7$use "rfp_check";
8$use "rfp_as2as";
9$use "rfp_format";
10$use "rfp_vars";
11$use "rfp_const";
12$use "rfp_clashes";
13
14$use StdIO;
15$use Table;
16$use Box;
17$use Arithm;
18$use Access;
19$use Compare;
20$use Convert;
21$use Class;
22$use Apply;
23$use Dos;
24$use List;
25
26
27/*
28 * Table for storing object names.
29 */
30$table Objects;
31
32/*
33 * Table for storing parameters of referenced functions.
34 */
35$table Stub-Funcs;
36
37/*
38 * Box for storing function out format
39 */
40$box Out-Format;
41
42/*
43 * Box for storing names for function result variables
44 */
45$box Res-Vars;
46
47/*
48 * Following table is used by Gener-Label function for obtaining unical (for
49 * certain function) label name.
50 * e.Key ::= e.QualifiedName      (parameter given to Gener-Label)
51 * e.Val ::= [Int]          (last index used with such e.QualifiedName)
52 */
53$table Labels;
54
55/*
56 * Table for storing variables used in place of preprocessor-generated ones.
57 */
58$table Prep-Vars;
59
60
61$func Compile (e.targets) (e.headers) e.Items = e.Compiled-Items (INTERFACE e.headers);
62
63$func Comp-Func-Stubs = e.asail-funcs;
64
65$func Comp-Func s.tag t.name e.params-and-body = e.compiled-func;
66
67$func Set-Drops (e.declared-exprs) e.comp-func = (e.declared-exprs) e.result-func;
68
69$func Comp-Sentence e.Sentence = e.asail-sentence;
70
71$func Save-Snt-State = ;
72
73$func Recall-Snt-State = ;
74
75$func Pop-Snt-State = ;
76
77$func Extract-Calls e.Re = (e.last-Re) e.calls;
78
79$func Get-Clash-Sequence (e.last-Re) e.Snt = (e.clashes) e.rest-of-the-Sentence;
80
81$func? Without-Calls? e.Re = ;
82
83$func Comp-Clashes (e.clashes) s.tail? (v.fails) e.Sentence = e.asail-sentence;
84
85$func Gener-Label e.QualifiedName = t.label;
86
87$func Add-To-Label t.label e.name = t.label;
88
89$func Comp-Calls e.Re = e.calls;
90
91$func Prepare-Vars e.vars = e.vars;
92
93$func Prepare-Res e.Reult-exprs = e.Result-exprs;
94
95$func Comp-Assigns e.assignments = e.asail-assignments;
96
97$func Comp-Format (e.last-Re) e.He = e.assignments;
98
99
100
101************ Get AS-Items and targets, and pass it to Compile ************
102
103/*
104 * Ящик для объявлений статических функций, констант и объектов.  Все они
105 * выписываются в самом начале тела модуля.
106 */
107$box Declarations;
108
109$box Trace-Names;
110
111$table Includes;
112
113RFP-Compile e.Items =
114  { <Lookup &RFP-Options ITEMS>;; } :: e.targets,
115  <RFP-Clear-Table &Stub-Funcs>,
116  <RFP-Clear-Table &Includes>,
117  <Store &Trace-Names /*empty*/>,
118  <Store &Declarations /*empty*/>,
119  <Init-Consts>,
120  <Compile (e.targets) () e.Items> :: e.Items t.Interface,
121  <Comp-Func-Stubs> :: e.stub-funcs,
122  t.Interface
123  (MODULE <Domain &Includes> <? &Trace-Names> <? &Declarations> <Comp-Consts> e.Items e.stub-funcs);
124
125
126
127****************** Choose needed items and compile them ******************
128
129Compile (e.targets) (e.headers) e.Items, {
130  e.Items : e t.item e.rest,
131    {
132      e.targets : v =
133        e.targets : e t.name e,
134        t.item : (t t t t.name e);;
135    },
136    t.item : {
137      (IMPORT s.tag t.pragma t.name e) =
138        {
139          t.pragma : (PRAGMA e (FILE e.fname) e) =
140            <RFP-Extract-Qualifiers t.name> :: (e.mod-name) e,
141            <Bind &Includes (INPUT (e.mod-name) e.fname) ()>;;
142        },
143        () /*empty*/;
144      (TRACE t.name) =
145        <Put &Trace-Names (TRACE t.name)>,
146        () /*empty*/;
147      (EXTERN t.pragma t.name) =
148        <Put &Declarations (EXTERN t.name)>,
149        () /*empty*/;
150      (s.link s.tag t.pragma t.name (e.in) (e.out) e.body), FUNC FUNC? TFUNC : e s.tag e =
151        {
152          <? &Declarations> : $r e (s t.name) e = /*empty*/;
153          (DECL-FUNC t.name);
154        } :: e.decl,
155        <Put &Declarations e.decl>,
156        {
157          s.link : EXPORT = e.decl;
158           /*empty*/;
159        } :: e.decl,
160        {
161          e.body : (BRANCH t.p e.branch) =
162            <Comp-Func s.tag t.name <Del-Pragmas (e.in) (e.out) e.branch>>;;
163        } :: e.comp-func,
164        (e.decl) e.comp-func;
165      (s.link CONST t.pragma t.name e.expr) =
166        (CONSTEXPR s.link t.name (e.expr) e.expr) :: t.const,
167        <Put &Declarations t.const>,
168        {
169          s.link : EXPORT = ((DECL-OBJ t.name)) /*empty*/;
170          () /*empty*/;
171        };
172      (EXPORT s.tag t.pragma t.name) =
173        <Put &Declarations (OBJ EXPORT s.tag t.name)>,
174        ((DECL-OBJ t.name)) /*empty*/;
175      (LOCAL  s.tag t.pragma t.name) =
176        <Put &Declarations (OBJ LOCAL s.tag t.name)>,
177        () /*empty*/;
178    } :: (e.decl) e.item =
179    e.item <Compile (e.targets) (e.headers e.decl) e.rest>;
180  /*<Comp-Func-Stubs>*/ (INTERFACE e.headers);
181};
182
183
184
185$func Gener-Stub e = e;
186
187/*
188 * For each referenced function generate a stub one with format e = e.
189 */
190Comp-Func-Stubs = <Map &Gener-Stub (<Domain &Stub-Funcs>)>;
191
192Gener-Stub (t.name) =
193  <Lookup &Stub-Funcs t.name> : t.stub-name s.tag (e.Fin) (e.Fout),
194  <Put &Declarations (DECL-FUNC t.stub-name)>,
195  <Gener-Vars (e.Fin) "stub"> :: e.He,
196  <Comp-Func STUB t.stub-name ((EVAR ("arg" 1))) ((EVAR))
197    (LEFT e.He) (CUTALL) (RESULT (CALL t.name e.He))>;
198
199
200
201Comp-Func s.tag t.name (e.in) (e.out) e.Sentence =
202  <RFP-Clear-Table &Labels>,
203  <RFP-Clear-Table &Prep-Vars>,
204  <Init-Vars>,
205  <Vars <Gener-Vars (e.out) "res">> :: e.res-vars,
206  <Vars-Decl Result e.res-vars> : e,
207  <Store &Res-Vars e.res-vars>,
208  <Store &Out-Format <Format-Exp e.out>>,
209  <Prepare-Res (e.in)> : (e.arg),
210  <Vars e.arg> :: e.arg-vars,
211  <Map &Set-Var- (Instantiated? True) (e.arg-vars)> : e,
212  s.tag : {
213    FUNC = FUNC (FATAL);
214    FUNC? = FUNC? (RETFAIL);
215    TFUNC = TFUNC (FATAL);
216    STUB =
217      <Prepare-Res (Apply Apply "Unexpected fail")> : (e.message),
218      FUNC? (RETFAIL) ((ERROR e.message));
219  } :: s.tag e.fails,
220  (s.tag t.name (<Vars-Print e.arg-vars>) (<Vars-Print e.res-vars>)
221    <Comp-Sentence Tail (e.fails) (e.arg) e.Sentence>
222  ) :: e.comp-func,
223*       <Set-Drops () <Gener-Var-Names e.comp-func>> :: t e.comp-func,
224  <Gener-Var-Names e.comp-func> :: e.comp-func,
225//!     <Post-Comp (e.res-vars) e.comp-func> :: t e.result,
226//!     e.result;
227  e.comp-func;
228//  :: (e.func-decl) e.func-body,
229//  () <Domain &Declarations> $iter {
230//    e.vars : (t.var) e.rest-vars,
231//      (e.var-decls (DECL t.var)) e.rest-vars;
232//  } :: (e.var-decls) e.vars,
233//  e.vars : /*empty*/,
234//  (e.func-decl e.var-decls e.func-body);
235
236Set-Drops (e.declared) e.comp-func =
237  e.comp-func () (e.declared) $iter {
238    e.comp-func : t.first e.rest, {
239      t.first : \{
240        (EXPR t.var e) = (DROP t.var) (t.first) t.var Init;
241        (DEREF t.var e) = (DROP t.var) (t.first) t.var Init;
242        (SUBEXPR t.var e) = (DROP t.var) (t.first) t.var Init;
243        (DECL Expr t.var) = (DROP t.var) () t.var Decl;
244        (DECL "int" t.var) = /*empty*/ () t.var Decl;
245      } :: e.drop (e.constr) t.var s.init,
246        {
247          e.declared : e1 t.var s.old-init e2, s.old-init : {
248            Init, {
249              t.var : (VAR ("const" e)) =
250                e.rest (e.result-func) (e.declared);
251              e.rest (e.result-func e.drop e.constr) (e.declared);
252            };
253            Decl, s.init : {
254              Decl =
255                e.rest (e.result-func) (e.declared);
256              Init =
257                t.first : (s.method t.var e.args),
258                e.rest (e.result-func (ASSIGN t.var (s.method e.args)))
259                (e1 e2 t.var s.init);
260                /*
261                 * FIXME: if s.method is EXPR, it shouldn't be written.
262                 */
263            };
264          };
265          e.rest (e.result-func t.first) (e.declared t.var s.init);
266        };
267      t.first : (LABEL (t.label) e.expr) =
268        <Set-Drops (e.declared) e.expr> :: (e.declared) e.expr,
269        e.rest (e.result-func (LABEL (t.label) e.expr)) (e.declared);
270      t.first : (e.expr) =
271        <Set-Drops (e.declared) e.expr> :: t e.expr,
272        e.rest (e.result-func (e.expr)) (e.declared);
273      t.first : s.symbol =
274        e.rest (e.result-func s.symbol) (e.declared);
275    };
276  } :: e.comp-func (e.result-func) (e.declared),
277  e.comp-func : /*empty*/ =
278  (e.declared) e.result-func;
279
280
281Comp-Sentence s.tail? (v.fails) (e.last-Re) e.Sentence, e.Sentence : {
282
283  /*empty*/ = /*empty*/;
284
285  /*
286   * In case of Re look if we should do a tailcall.  If not, then compile
287   * function calls from the Re and assign results to the out parameters or
288   * use them in compilation of the rest of the sentence.
289   */
290  (RESULT e.Re) e.Snt =
291    {
292      /*
293       * If the Re is the last action in the sentence then we can do
294       * tailcall if one of the following is true:
295       *  - Re is a call of non-failable function;
296       *  - Re is a call of a failable function, current function is
297       *  failable, and the failures stack is empty.
298       * In both cases out format of the called function should coincide
299       * with those of compiled one.
300       * FIXME: really we can do tailcall if all the parameters of
301       * compiled function that won't get their values from the call can
302       * be assigned from other sources.  Some support from runtime is
303       * needed though.
304       */
305      e.Snt : /*empty*/, s.tail? : Tail, e.Re : (CALL t.name e.arg),
306        {
307          <In-Table? &Fun? t.name> =
308            v.fails : (RETFAIL),
309            TAILCALL?;
310          TAILCALL;
311        } :: s.tailcall,
312        <Lookup-Func t.name> :: s.linkage s.tag t.pragma (e.Fin) (e.Fout),
313        <Subformat? (e.Fout) (<? &Out-Format>)> =
314        <Extract-Calls e.arg> :: (e.last-Re) e.calls,
315        <Prepare-Res <Split-Re (e.Fin) e.last-Re>> :: e.splited-Re,
316        <Comp-Calls <R 0 v.fails> e.calls>
317        (s.tailcall t.name (e.splited-Re) (<? &Res-Vars>));
318
319      <Extract-Calls e.Re> :: (e.last-Re) e.calls,
320        <Comp-Calls <R 0 v.fails> e.calls> :: e.comp-calls,
321        {
322          e.Snt : /*empty*/, Tail Tail-in-Trap : e s.tail? e =
323            <Split-Re (<? &Out-Format>) e.last-Re> :: e.splited-Re,
324            <Prepare-Res e.splited-Re> :: e.splited-Re,
325            e.comp-calls <Comp-Assigns <Zip (<? &Res-Vars>) (e.splited-Re)>>;
326
327          e.comp-calls <Comp-Sentence s.tail? (v.fails) (e.last-Re) e.Snt>;
328        };
329    };
330
331  /*
332   * In case of He compile assignments from last Re and then (with new state
333   * of variables) proceed with the rest of the sentence.
334   */
335  (FORMAT e.He) e.Snt =
336    <Comp-Format (e.last-Re) e.He>
337    <Comp-Sentence s.tail? (v.fails) () e.Snt>;
338
339  /*
340   * In case of Pe get from the begining of the sentence a maximum possible
341   * sequence of clashes and compile it.  New values of variables from the
342   * clashes use in the compilation of the rest of the sentence.
343   */
344  (s.dir e.Pattern) e.Snt, s.dir : \{ LEFT; RIGHT; } =
345    <Get-Clash-Sequence (e.last-Re) e.Sentence> :: (e.clashes) e.Sentence,
346    <Comp-Clashes (e.clashes) s.tail? (v.fails) e.Sentence>;
347
348  (s.block) e, BLOCK BLOCK? : e s.block e = <WriteLN! &StdErr "Empty block?">, $fail;
349
350  /*
351   * In case of a block first see if its results are needed for something
352   * after the block and determine whether the block is a source.  Then
353   * compile each branch in turn.
354   */
355  (s.block e.branches) e.Snt,
356    s.block : \{
357      BLOCK = (FATAL);
358      BLOCK?;
359    } :: e.fatal? =
360    /*
361     * If the block initializes an $iter then extract from the $iter the He
362     * for placing it in the end of each branch.
363     * Then look if the block is used by a format expression.
364     * If so, we should declare variables from that expression before
365     * entering any branch -- those should be visible after the block.
366     * The format expression is placed in the end of each branch.
367     * But if a branch computes to $error, the expression shouldn't be
368     * used, so protect it with (Comp If-not-error).
369     * If next after the block is (Comp Error) then block results should be
370     * used as values for $error, so place (Comp Error) in the end of each
371     * branch.
372     * If next after the block is (Comp If-not-error) then our block is in
373     * the end of a branch of an outer block and has next pattern or format
374     * inherited from there.  In that case we should place all the sentence
375     * rest in the end of each branch because the block can be inside the
376     * $error already.
377     */
378    {
379      e.Snt : (ITER t.body t.format t.cond) e.rest =
380        t.format (Comp Iter t.body t.format t.cond) e.rest;
381      e.Snt;
382    } :: e.Snt,
383    e.Snt : {
384      (FORMAT e.format) e.rest =
385        <Prepare-Vars <Vars e.format>> :: e.vars,
386        (e.vars) ((Comp If-not-error) (FORMAT e.format))
387        ((Comp Source)) e.rest;
388      (Comp Error) e.rest =
389        () ((Comp Error)) () /*empty*/;
390      (Comp If-not-error) e.rest =
391        () (e.Snt) () /*empty*/;
392      e = () () () e.Snt;
393    } :: (e.out-vars) (e.next-terms) (e.source?) e.Snt,
394    /*
395     * The block is a source if after it goes format expression
396     * (in that case e.source? isn't empty) or e.Snt isn't empty.
397     * Branches in the block are tail sentences if the current sentence is
398     * tail and the block isn't a source.
399     */
400    {
401      \{ e.source? : v; e.Snt : v; } = ((Comp Source) <R 0 v.fails>) Notail;
402      () s.tail?;
403    } :: (e.source?) s.tail-branch?,
404    /*
405     * In case our block is a source we should mark the position in the
406     * failures stack, so that we can jump to it after CUTALL.  And if our
407     * block isn't failable we should add (FATAL) to the end of the stack.
408     */
409    v.fails e.source? e.fatal? :: v.branch-fails,
410    /*
411     * Before compile the branches mark all out-vars as declared.
412     */
413    <Vars-Decl Expr e.out-vars> :: e.decls,
414    /*
415     * We put all compiled branches in a block, so positive return from a
416     * branch is a break from that block.
417     * Each branch in its turn is placed in its own block, so for a $fail
418     * to the next branch we should just break from that inner block.
419     * Each branch is compiled with the current sentence state and the
420     * state is recalled after that.  When all branches are compiled the
421     * state is popped out from the stack.
422     * If last branch fails then the whole block fails, and return from the
423     * last branch is return from the block.  So the last branch isn't
424     * placed in a block and is processed with the failures stack that was
425     * before entering the block.  Note: this trick helps us find more
426     * tailcalls.  If the call of a failable function is on the last branch
427     * of the block and the failures stack is empty we can do tailcall.
428     * When the last branch is compiled with the block's stack, all we
429     * should do is to check it.
430     */
431    <Gener-Label "block"> :: t.label,
432    <Save-Snt-State>,
433    (e.branches) /*e.comp-branches*/ $iter {
434      e.branches : (BRANCH e.branch) e.rest-br =
435        <Add-To-Label t.label "branch"> :: t.br-label,
436        <Comp-Sentence
437          s.tail-branch?
438          (v.branch-fails ((BREAK t.br-label)))
439          (e.last-Re)
440          e.branch e.next-terms
441        > :: e.comp-br,
442        <Recall-Snt-State>,
443        (e.rest-br) e.comp-branches (LABEL (t.br-label) e.comp-br (BREAK t.label));
444    } :: (e.branches) e.comp-branches,
445    e.branches : (BRANCH e.branch) =
446    <Comp-Sentence
447      s.tail-branch? (v.branch-fails) (e.last-Re) e.branch e.next-terms
448    > :: e.last-branch,
449    <Pop-Snt-State>,
450    <Vars-Reset e.out-vars>,
451    e.decls (LABEL (t.label) e.comp-branches e.last-branch)
452    <Comp-Sentence s.tail? (v.fails) () e.Snt>;
453
454  /*
455   * In case of $iter first of all compile initial assignment to the hard
456   * expression.
457   */
458  (ITER t.body t.format t.cond) e.Snt =
459    <Comp-Sentence s.tail? (v.fails) (e.last-Re)
460      t.format (Comp Iter t.body t.format t.cond) e.Snt
461    >;
462
463  /*
464   * Before compiling $iter condition or body we should forget available info
465   * about all format variables, because that info can be changed during
466   * cycle iterations.
467   * Then compile $iter condition and body both with the current state of the
468   * sentence.
469   * e.Snt can contain (Comp Error) and (protected from errors) pattern or
470   * format which comes from an outer block, so compile it together with the
471   * condition.
472   * If condition fails we should compute the body, so put the compiled
473   * condition in a block and place a break from it to the failures stack.
474   */
475  (Comp Iter (BRANCH e.body) t.format (BRANCH e.condition)) e.Snt =
476    t.format : (FORMAT e.Fe),
477    <Vars-Reset <Prepare-Vars <Vars e.Fe>>>,
478    <Save-Snt-State>,
479    <Gener-Label "iter"> :: t.label,
480    <Gener-Label "exit_iter"> :: t.exit,
481    <Comp-Sentence s.tail? (v.fails ((BREAK t.label))) () e.condition e.Snt>
482      :: e.comp-condition,
483    <Pop-Snt-State>,
484    <Comp-Sentence Notail (v.fails) () e.body t.format> :: e.comp-body,
485    (FOR (/*cont-label*/) (t.exit) () ()
486      (LABEL (t.label) e.comp-condition (BREAK t.exit)) e.comp-body
487    );
488
489  /*
490   * In case of $trap/$with at first compile try-sentence.  All $fails from
491   * it should become errors.
492   * Then recall the state of the sentence and compile catching of an error
493   * with a variable err.
494   * e.Snt can contain (Comp Error) and (protected from errors) pattern or
495   * format which comes from an outer block, so compile it together with both
496   * sentences.
497   */
498  (TRY (BRANCH e.try) e.catch) e.Snt =
499    <Save-Snt-State>,
500    {
501      s.tail? : Tail = Tail-in-Trap;
502      s.tail?;
503    } :: s.tail-in-trap?,
504    <Comp-Sentence s.tail-in-trap? ((FATAL)) () e.try e.Snt> :: e.comp-try,
505    <Pop-Snt-State>,
506    <Gener-Err-Var> :: t.var,
507    <Set-Var (Instantiated? True) t.var>,
508    <Comp-Sentence s.tail? (v.fails) (t.var) e.catch e.Snt> :: e.comp-catch,
509    (TRY e.comp-try) (CATCH-ERROR e.comp-catch);
510
511  /*
512   * In case of \? add Stake to the failures stack.  Add last fail after it
513   * for <R 0 v.fails> continue to work.
514   */
515  (STAKE) e.Snt =
516    <Comp-Sentence s.tail? (v.fails (Comp Stake) <R 0 v.fails>) () e.Snt>;
517
518  /*
519   * In case of \! forget all failure catchers after last \?.
520   * If there is no Stake then we are inside negation or error (we assume the
521   * program is correct).  So the right failure catcher is in the bottom of
522   * the stack.
523   */
524  (CUT) e.Snt =
525    {
526      v.fails : $r v.earlier-fails (Comp Stake) e = v.earlier-fails;
527      <L 0 v.fails>;
528    } :: v.fails,
529    <Comp-Sentence s.tail? (v.fails) () e.Snt>;
530
531  /*
532   * In case of = clear the failures stack up to the closest source.
533   */
534  (CUTALL) e.Snt =
535    {
536      v.fails : $r v.earlier-fails (Comp Source) e = v.earlier-fails;
537      <L 0 v.fails>;
538    } :: v.fails,
539    <Comp-Sentence s.tail? (v.fails) () e.Snt>;
540
541  /*
542   * In case of = in the Refal-6 sense (non-transparent hedge for the fails),
543   * $fail(k) should become $error(Fname "Unexpected fail"), so clear the
544   * failures stack and put that value in it.
545   */
546  NOFAIL e.Snt =
547    <Comp-Sentence s.tail? ((FATAL)) (e.last-Re) e.Snt>;
548
549  /*
550   * In case of $fail return last failure catcher.
551   */
552  (FAIL) e.Snt =
553    v.fails : e (e.last-fail),
554    e.last-fail;
555
556  /*
557   * In case of # we should proceed with the rest if the source is computed
558   * to $fail.
559   * We could compile the rest of the sentence and place it in the
560   * failures stack.  But then the compiled sentence would be copied as many
561   * times as there are $fail's to the upper level in the source.  So we
562   * place compiled source in the block and put the break to exit from it in
563   * the stack.
564   * When compiling the source mark it as Notail as usual.
565   * If the source isn't computed to $fail we should proceed with the last
566   * failure catcher.
567   */
568  (NOT (BRANCH e.branch)) e.Snt =
569    <Gener-Label "negation"> :: t.label,
570    v.fails : e (e.last-fail),
571//    <Save-Snt-State>,
572    <Comp-Sentence Notail (((BREAK t.label))) () e.branch> e.last-fail
573      :: e.comp-negation,
574//    <Pop-Snt-State>,
575    (LABEL (t.label) e.comp-negation) <Comp-Sentence s.tail? (v.fails) () e.Snt>;
576
577  /*
578   * In case of $error all fails become $error(Fname "Unexpected fail").  So
579   * place that value in the failures stack and then compile the computation
580   * of the rest of the sentence and the last Re which should be the value of
581   * $error.
582   */
583  (ERROR) e.Snt =
584    <Comp-Sentence Notail ((FATAL)) () e.Snt (Comp Error)>;
585
586  (Comp Error) e.Snt =
587    <Prepare-Res (e.last-Re)> : (e.Re),
588    (ERROR e.Re);
589
590  /*
591   * Protection mark to be used between source and tail.  If there is $error
592   * construction somewhere in the source then the tail shouldn't be
593   * computed, but instead the source value should be used for throwing.
594   */
595  (Comp If-not-error) e.Snt =
596    {
597      e.Snt : e (Comp Error) =
598        <Comp-Sentence s.tail? (v.fails) (e.last-Re) (Comp Error)>;
599      <Comp-Sentence s.tail? (v.fails) (e.last-Re) e.Snt>;
600    };
601
602//  (Comp Fatal) = FATAL;
603
604//  (Comp Retfail) = RETFAIL;
605
606};
607
608
609
610********** Sentence state stack and functions for work with it. **********
611
612$box Snt-State;
613
614/*
615 * Put current state in the stack.
616 */
617Save-Snt-State = <Put &Snt-State <Vars-Copy-State>>;
618
619/*
620 * Set current state to that at the top of the stack.
621 */
622Recall-Snt-State = <Vars-Set-State <R 0 <? &Snt-State>>>;
623
624/*
625 * Pop the top from the stack and set current state to it.
626 */
627Pop-Snt-State =
628  <Recall-Snt-State>,
629  <Store &Snt-State <Middle 0 1 <? &Snt-State>>>;
630
631
632
633********************** Function calls compilation. ***********************
634
635/*
636 * $func Extract-Calls e.Re = (e.last-Re) e.calls;
637 *
638 *
639 *
640 */
641Extract-Calls {
642  (CALL t.name e.arg) e.rest =
643    <Lookup-Func t.name> :: s.linkage s.tag t.pragma (e.Fin) (e.Fout),
644    <Extract-Calls e.arg> :: (e.last-Re) e.calls,
645    <Prepare-Res <Split-Re (e.Fin) e.last-Re>> :: e.splited-Re,
646    <RFP-Extract-Qualifiers t.name> :: t e.prefix,
647    <Gener-Subst-Vars (e.Fout) e.prefix> :: e.Re,
648    <Vars e.Re> :: e.vars,
649    <Map &Set-Var- (Instantiated? True) (e.vars)> : e,
650    {
651      s.tag : FUNC? =   (Failable (CALL t.name (e.splited-Re) (e.vars)));
652      (CALL t.name (e.splited-Re) (e.vars));
653    } :: t.call,
654    <Extract-Calls e.rest> :: (e.rest-Re) e.rest-calls,
655    (e.Re e.rest-Re) e.calls <Vars-Decl Result e.vars> t.call e.rest-calls;
656  (PAREN e.Re) e.rest =
657    <Extract-Calls e.Re> :: (e.last-Re) e.calls,
658    <Extract-Calls e.rest> :: (e.rest-Re) e.rest-calls,
659    ((PAREN e.last-Re) e.rest-Re) e.calls e.rest-calls;
660  t.Rt e.Re =
661    <Extract-Calls e.Re> :: (e.last-Re) e.calls,
662    (t.Rt e.last-Re) e.calls;
663  /*empty*/ = () /*empty*/;
664};
665
666
667Comp-Calls (e.fail) e.calls, e.calls : {
668  (Failable t.call) e.rest =
669    (IF ((NOT t.call)) e.fail) <Comp-Calls (e.fail) e.rest>;
670  t.call e.rest =
671    t.call <Comp-Calls (e.fail) e.rest>;
672  /*empty*/ = /*empty*/;
673};
674
675
676
677********** Preparation of vars and REs for following processing **********
678*********** Compilation of static parts of result expressions ************
679
680$func Static-Expr? s.create? e.Re = static? e.Re;
681
682$func Ref-Func? t = t;
683
684$func Static-Term? t.Rt = static? e.Re;
685
686$func Stub-Name t.name = t.stub-name;
687
688
689/*
690 * Extract static parts from each Re.
691 * Also get the right names for variables generated during the preprocessing
692 * stage, if those are in the expr.
693 */
694Prepare-Res {
695  (e.Re) e.rest = <Static-Expr? Create e.Re> :: s e.Re, (e.Re) <Prepare-Res e.rest>;
696  /*empty*/     = /*empty*/;
697};
698
699/*
700 * Find all the longest static parts in the upper level of Re.  Create STATIC
701 * form in place of each one.
702 * Return a tag pointing whether the whole expression is static and expression
703 * with static parts replaced by STATIC forms.  Dynamic parts are returned
704 * unchanged.
705 */
706Static-Expr? s.create? e.Re =
707  (/*e.static*/) e.Re $iter {
708    e.Re : t.Rt e.rest =
709      <Static-Term? t.Rt> : {
710        Static e.st-Re =
711          (e.static e.st-Re) e.rest;
712        Dynamic t.dyn-Rt =
713          <Static-Expr? Create e.rest> :: s e.rest,
714          (e.static) (Dynamic t.dyn-Rt e.rest);
715      };
716    (e.static);
717  } :: (e.static) e.Re,
718  e.Re : \{
719    /*empty*/, {
720      s.create? : Create =
721        Static <Create-Static e.static>;
722      Static e.static;
723    };
724    (Dynamic e.dynamic) = Dynamic <Create-Static e.static> e.dynamic;
725  };
726
727/*
728 * The same as Static-Expr? but for terms.
729 */
730Static-Term? {
731  symbol       = Static symbol;
732  (PAREN e.Re) = <Static-Expr? Not-Create e.Re> :: static? e.Re, static? (PAREN e.Re);
733  (REF t.name) = Static <Ref-Func? (REF t.name)>;
734  (STATIC t.name) = Static <Get-Static (STATIC t.name)>;
735  t.var        = <Prepare-Vars t.var> : t.prep-var, Dynamic t.prep-var;
736};
737
738Ref-Func? {
739  (REF t.name) =
740    {
741      <Lookup-Func t.name> : {
742        s.linkage s.tag t.pragma ((EVAR)) ((EVAR)) = (s.tag t.name);
743        s.linkage s.tag t.pragma (e.Fin) (e.Fout) =
744          {
745            <Lookup &Stub-Funcs t.name> : t.stub-name e =
746              (FUNC? t.stub-name);
747            <Stub-Name t.name> :: t.stub-name,
748              <Bind &Stub-Funcs (t.name)
749                (t.stub-name s.tag (e.Fin) (e.Fout))>,
750              (FUNC? t.stub-name);
751          };
752      };
753      (REF t.name);
754    };
755  term = term;
756};
757
758Prepare-Vars {
759  (s.var-tag (e.prefix s.n)) e.rest, <Int? s.n> =
760    {
761      <Lookup &Prep-Vars e.prefix s.n>;
762      <Gener-Vars ((s.var-tag)) e.prefix> :: e.var,
763        <Bind &Prep-Vars (e.prefix s.n) (e.var)>,
764        e.var;
765    } :: e.var,
766    e.var <Prepare-Vars e.rest>;
767  t.var e.rest = t.var <Prepare-Vars e.rest>;
768  /*empty*/ = /*empty*/;
769};
770
771/*
772 * Генерируем уникальные внутри модуля имена для функций-заглушек.
773 */
774Stub-Name (e.qualifiers s.name) =
775  <To-Chars s.name> : {
776    e1 '_' s.n, <Int? s.n> = e1 '_' <"+" s.n 1>;
777    e1 = e1 '_' 0;
778  } :: e.name,
779  (/*e.qualifiers*/ <To-Word e.name>) :: t.name,
780  {
781    <Lookup-Func t.name> : e = <Stub-Name t.name>;
782    t.name;
783  };
784
785
786
787***************** Compilation of assignment to variables *****************
788
789$func Comp-Assign-to-Var t.var e.Re (e.assigned-vars) = e.assign (e.used-vars);
790
791Comp-Assign-to-Var t.var e.Re (e.assigned-vars) =
792  {
793    t.var : e.Re = /*empty*/ ();
794    <Vars-Reset t.var>, $fail;
795    <Substitutable-Var? e.Re>, # \{ e.assigned-vars : e t.var e; } =
796      <Gener-Var-Assign t.var e.Re> ();
797    <Get-Var Decl t.var> : s = (ASSIGN <Vars-Print t.var> e.Re) (<Vars e.Re>);
798    <Vars-Decl Expr t.var> : e, (EXPR <Vars-Print t.var> e.Re) (<Vars e.Re>);
799  };
800
801Comp-Assigns e.assigns =
802  e.assigns (/*e.assigned-vars*/) (/*e.comp-assigns*/) $iter {
803    e.assigns : (t.var (e.Re)) e.rest =
804      <Comp-Assign-to-Var t.var e.Re (e.assigned-vars)> :: e.c-as (e.a-vs),
805      e.rest (e.assigned-vars e.a-vs) (e.comp-assigns e.c-as);
806  } :: e.assigns (e.assigned-vars) (e.comp-assigns),
807  e.assigns : /*empty*/ =
808  e.comp-assigns;
809
810
811
812************************** FORMAT compilation. ***************************
813
814$box Aux-Index;
815
816$func Gener-Aux-Var = t.new-aux-var;
817
818Gener-Aux-Var =
819  <? &Aux-Index> : s.n,
820  <Store &Aux-Index <"+" s.n 1>>,
821  (VAR ("aux" s.n));
822
823
824$func Create-Aux-Vars (e.vars) e.splited-Re = e.assigns;
825
826
827Comp-Format (e.last-Re) e.He =
828  <Prepare-Vars <Vars e.He>> :: e.vars,
829  <Prepare-Res <Split-Re (<Format-Exp e.He>) e.last-Re>> :: e.splited-Re,
830  <Store &Aux-Index 1>,
831  <Create-Aux-Vars (e.vars) e.splited-Re> :: e.assigns,
832  <Comp-Assigns e.assigns>;
833
834/*
835 * Итак, e.vars -- все переменные, входящие в форматное выражение.  Каждая
836 * переменная может входить в форматное выражение только один раз, поэтому
837 * повторяющихся среди них нет.
838 * e.splited-Re -- набор результатных выражений.  На каждую переменную из
839 * e.vars по выражению, которое должно быть ей присвоено.
840 *
841 * Если переменная t.var_i используется в выражении e.Re_j, и i /= j, то
842 * переменной t.var_j значение должно быть присвоено раньше, чем перeменной
843 * t.var_i.  Если же, по аналогичным соображениям, t.var_i должна получить
844 * значение раньше t.var_j, необходимо завести вспомогательную переменную.
845 *
846 * Пример:
847 *
848 * t1 (t1 t2) (t1 t3) :: t2 t1 t3
849 *
850 * t3 = (t1 + t3)();
851 * aux_1 = t1;
852 * t1 = (t1 + t2)()
853 * t2 = aux_1;
854 *
855 * В общем случае вспомогательная переменная требуется, если двум переменным
856 * необходимы старые значения друг друга (возможно, не напрямую, а через
857 * промежуточные переменные).
858 *
859 * Вместо того, чтобы искать и анализировать такие циклы, будем действовать по
860 * методу "наибольшей пользы".  А именно:
861 *
862 *   - Для каждой переменной выпишем все другие переменные, которым требуется
863 *     её старое значение, а также отдельно те, старые значения которых
864 *     требуются ей.
865 *
866 *   - Всем переменным, от старых значений которых ничего не зависит, можно
867 *     смело присвоить новые значения.  При этом они исчезают из списков
868 *     зависимостей оставшихся переменных.
869 *
870 *   - Все переменные, новые значения которых ни от чего не зависят, можно
871 *     отложить, чтобы присвоить им значения тогда, когда будет удобно.  Т.е.
872 *     тогда, когда списки зависящих от них переменных опустеют.
873 *
874 *   - Чтобы означить оставшиеся, нужны вспомогательные переменные.  Выберем
875 *     одну из переменных, с максимальным списком тех, от которых она зависит,
876 *     и положим её значение во вспомогательную переменную.  Так как мы сразу
877 *     уменьшили кол-во зависимостей у максимального кол-ва переменных,
878 *     локально мы добились наибольшей пользы, хотя не исключено, что глобально
879 *     такой метод и не даст наименьшего кол-ва вспомогательных переменных.
880 *     Кроме того, мы не пытаемся выбрать наилучшую переменную из нескольких с
881 *     максимальным списком зависимостей.
882 *
883 *   - Повторяем всё это до тех пор, пока у каждой переменной не опустеет
884 *     список зависящих от неё.
885 *
886 *
887 * Для нашего примера:
888 *
889 * t1 (t1 t2) (t1 t3) :: t2 t1 t3
890 *
891 * t1 -- (t2 t3) (t2)
892 * t2 -- (t1)    (t1)
893 * t3 -- ()      (t1)
894 *
895 *
896 * Для каждой переменной var_i найдём все j /= i, такие что в Re_j встречается
897 * var_i -- provide[i], и а также все j /= i, такие что var_j нужна для
898 * подсчёта var_i, т.е. встречается в Re_i.
899 *
900 * Res-vars <- <Map &Vars (Res)>
901 * for var_i in vars
902 *     provide[i] <-
903 *     for vars-Re_j in Res-vars, j /= i
904 *         vars-Re_j : e var_i e = j
905 *     require[i] <- <Res-vars[i] `*` vars[^i]> : e var_j e, j
906 *
907 * Res-vars = map Vars Res
908 * provide, require =
909 *   {   [ j | vars-Re_j <- Res-vars, j /= i, var_i `in` vars-Re_j ]
910 *     , [ j | var_j <- Res-vars[i] `*` vars, i /= j]
911 *     | var_i <- vars
912 *   }
913 *
914 */
915
916$func CAV e.vars (e.assigns) (e.delayed) = e.assigns;
917
918$func Get-Vars e = e;
919Get-Vars (e.Re) = (<Vars e.Re>);
920
921Create-Aux-Vars (e.vars) e.splited-Re =
922  <Zip (<Map &Get-Vars (e.splited-Re)>) (e.vars)> :: e.list,
923  <Box> :: s.box,
924  <Box> :: s.provide-i,
925  <Box> :: s.require-i,
926  {
927    e.vars : e1 t.var-i e2,
928      {
929        e.list : e ((e.vars-Re) t.var-j) e,
930          \{
931            t.var-i : t.var-j = <Put s.require-i <And (e1 e2) e.vars-Re>>;
932            e.vars-Re : e t.var-i e = <Put s.provide-i t.var-j>;
933          },
934          $fail;
935        <L <Length e1> e.splited-Re> :: t.Re-i,
936        <Put s.box (t.var-i t.Re-i (<? s.provide-i>) (<? s.require-i>))>,
937          <Store s.provide-i /*empty*/>,
938          <Store s.require-i /*empty*/>;
939      },
940      $fail;;
941  },
942  <CAV <? s.box> (/*assigns*/) (/*delayed*/)>;
943
944
945/*
946 * Если есть переменная, у которой список provide пуст, её можно посчитать.
947 * Это выражается в том, что она (вместе с присваиваемым значением) добавляется
948 * в список assigns, убирается из списка vars, а также из всех списков provide
949 * и delayed.  В списках require её не было.
950 *
951 * CAV Res vars provide require assigns delayed =
952 *   { i | var_i <- vars, provide_i == [] } ->     // Здесь неверно!  На переменные
953 *                                                    из delayed тоже надо смотреть.
954 *       vars    = vars - var_i
955 *       provide = [ provide_j - i | provide_j <- provide ]
956 *       assigns = assigns++[(var_i, Res[i])]
957 *       delayed = [ (var_j, provide_j - i) | (var_j, provide_j) <- delayed ]
958 *       CAV Res vars provide require assigns delayed
959 */
960
961$func Assign-Empty-Provides e.vars  = e.assigns (e.vars);
962
963Assign-Empty-Provides {
964  e1 (t.var-i t.Re-i (/*empty provide_i*/) (e.require-i)) e2 =
965    <Box> :: s.vars,
966    {
967      e1 e2 : e (t.var-j t.Re-j (e.provide-j) (e.require-j)) e,
968        <Put s.vars (t.var-j t.Re-j (<Sub (e.provide-j) t.var-i>) (e.require-j))>,
969        $fail;;
970    },
971    (t.var-i t.Re-i) <Assign-Empty-Provides <? s.vars>>;
972  e.vars = /*empty*/ (e.vars);
973};
974
975
976/*
977 * Если есть переменная, у которой список require пуст, кладём её в delayed.
978 * Она будет посчитана, когда у неё опустеет список provide, т.е. когда не
979 * останется переменных, у которых она в списке require.
980 */
981$func Delay-Empty-Requires e.vars  = e.delayed (e.vars);
982
983Delay-Empty-Requires {
984  e1 t.var e2, t.var : (t.var-i t.Re-i (e.provide-i) (/*empty require_i*/)) =
985    <Delay-Empty-Requires e2> :: e.delayed (e.vars),
986    t.var e.delayed (e1 e.vars);
987  e.vars = /*empty*/ (e.vars);
988};
989
990
991/*
992 * Выбор переменной (из двух) с более длинным списком требуемых ей значений.
993 */
994$func Max-Require e = e;
995
996Max-Require t.arg1 t.arg2 =
997  t.arg1 : (t.var1 t.Re1 t.provide1 (e.require1)),
998  t.arg2 : (t.var2 t.Re2 t.provide2 (e.require2)),
999  {
1000    <"<" (<Length e.require1>) (<Length e.require2>)> = t.arg2;
1001    t.arg1;
1002  };
1003
1004
1005/*
1006 * Подставить вспомогательную переменную вместо исходной во всех результатных выражениях.
1007 * Присваивание к исходной переменной убрать (оно к этому моменту уже выполнено).
1008 * Убрать переменную из списков зависимостей.
1009 */
1010$func Subst-Aux-Var e = e;
1011
1012Subst-Aux-Var t.var t.aux (t.v t.Re (e.provide) (e.require)), {
1013  t.var : t.v = /*empty*/;
1014  (
1015    t.v
1016    <Subst (t.var) ((t.aux)) t.Re>
1017    (<Sub (e.provide) t.var>)
1018    (<Sub (e.require) t.var>)
1019  );
1020};
1021
1022
1023/*
1024 * Извлечь присваивание из всей информации о переменной.
1025 */
1026$func Extract-Assigns e = e;
1027Extract-Assigns (t.var t.Re e) = (t.var t.Re);
1028
1029
1030/*
1031 * Основной цикл обработки присваиваний.
1032 *
1033 * 1) Из всех переменных (в том числе и отложенных), от которых больше ничего
1034 *    не зависит, сделать присваивания.
1035 * 2) Все переменные, которые больше ни от чего не зависят, отложить.
1036 * 3) Если осталось хотя бы две неотложенных переменных, выбирать из них ту,
1037 *    которая зависит от наибольшего числа переменных, подставить везде вместо
1038 *    неё вспомогательную, перейти к пункту 1.
1039 */
1040CAV e.vars (e.assigns) (e.delayed) =
1041  <Assign-Empty-Provides e.vars> :: e.new-assigns (e.vars),
1042  e.assigns e.new-assigns <Assign-Empty-Provides e.delayed> :: e.assigns (e.delayed),
1043  e.delayed <Delay-Empty-Requires e.vars> :: e.delayed (e.vars),
1044  {
1045    e.vars : t t e =
1046      <Foldr1 &Max-Require (e.vars)> : (t.var t.Re e),
1047      <Gener-Aux-Var> :: t.aux,
1048      e.assigns (t.aux (t.var)) (t.var t.Re) :: e.assigns,
1049      <Map &Subst-Aux-Var t.var t.aux (e.vars)> :: e.vars,
1050      <Map &Subst-Aux-Var t.var t.aux (e.delayed)> :: e.delayed,
1051      <CAV e.vars (e.assigns) (e.delayed)>;
1052    e.assigns <Map &Extract-Assigns (e.vars e.delayed)>;
1053  };
1054
1055
1056
1057
1058****************** Компиляция сопоставления с образцом *******************
1059
1060Get-Clash-Sequence (e.last-Re) t.Pattern e.Snt =
1061  (/*e.clashes*/) (RESULT e.last-Re) t.Pattern e.Snt $iter {
1062    e.Snt : (RESULT e.Re) (s.dir e.Pe) e.rest =
1063      /*
1064       * Компилируем все константные выражения и заводим в табличке все
1065       * незаведённые переменные.  У старых переменных очищается память
1066       * на предмет клешей, в которых они раньше использовались.
1067       */
1068      <Prepare-Res (e.Re) (e.Pe)> : (e.R1) (e.P1),
1069      <Map &Set-Var- (Clashes /*empty*/) (<Vars e.R1 e.P1>)> : e,
1070      (e.clashes (e.R1) (s.dir e.P1)) e.rest;
1071  } :: (e.clashes) e.Snt,
1072  # \{
1073    e.Snt : \{
1074      (RESULT e.Re) (LEFT e) e = e.Re;
1075      (RESULT e.Re) (RIGHT e) e = e.Re;
1076    } :: e.Re,
1077      <Without-Calls? e.Re>;
1078  } =
1079  (e.clashes) e.Snt;
1080
1081Without-Calls? e.Re =
1082  e.Re $iter {
1083    e.Re : t.Rt e.rest =
1084      t.Rt : {
1085        (CALL e) = $fail;
1086        (BLOCK e) = $fail;
1087        (PAREN e.Re1) = <Without-Calls? e.Re1>;
1088        t.symbol-or-var = /*empty*/;
1089      },
1090      e.rest;
1091  } :: e.Re,
1092  e.Re : /*empty*/;
1093
1094$func CC s.tail? (v.fails) t.end-cycle e.Snt = e.asail-Snt;
1095
1096Comp-Clashes (e.clashes) s.tail? (v.fails) e.Sentence =
1097  <Init-Clashes e.clashes>,
1098  <CC s.tail? (v.fails) <R 0 v.fails> e.Sentence>;
1099
1100$func CC-Known-Lengths t.fail e.idxs = e.conds;
1101
1102$func CC-Compute-Length t.fail t.end-cycle t.idx = e;
1103
1104$func CC-Unknown-Lengths t.fail e.idxs = e.conds;
1105
1106$func CC-Deref t.fail e.actions = e.actions;
1107
1108$func CC-Eqs t.fail (e.assigns) e.eqs = e.actions;
1109
1110CC s.tail? (v.fails) t.end-cycle e.Snt, {
1111  <Domain &Known-Lengths> : v.clashes =
1112    <CC-Known-Lengths t.end-cycle v.clashes>
1113    <CC s.tail? (v.fails) t.end-cycle e.Snt>;
1114  <Domain &Compute-Length> : (t.clash) e =
1115    <CC-Compute-Length <R 0 v.fails> t.end-cycle t.clash>
1116    <CC s.tail? (v.fails) t.end-cycle e.Snt>;
1117  <Domain &Unknown-Lengths> : e.clashes =
1118    <CC-Unknown-Lengths t.end-cycle e.clashes> :: e.conds,
1119    /*
1120     * Когда мы добрались до сюда, все условия на длины на текущем уровне
1121     * выписаны.  Невыполнение любого из оставшихся условий (на
1122     * соответствие типов, равенство, длины внутри скобок) ведёт не к
1123     * прекращению текущего цикла, а переход к его следующей итерации.
1124     * Поэтому в качестве t.end-cycle везде дальше подставляется текущий
1125     * откат.
1126     */
1127    <Update-Hard-Parts> : {
1128      v.actions =
1129        e.conds <CC-Deref <R 0 v.fails> v.actions>
1130        <CC s.tail? (v.fails) <R 0 v.fails> e.Snt>;
1131      /*empty*/ =
1132        e.conds <CC-Eqs <R 0 v.fails> () <? &Eqs>> :: e.actions,
1133        <Store &Eqs /*empty*/>,
1134        {
1135          <Compose-Source> :: e.assign =
1136            e.actions <CC-Eqs <R 0 v.fails> () e.assign>
1137            <CC s.tail? (v.fails) <R 0 v.fails> e.Snt>;
1138          {
1139            <Get-Cycle> :: s.split (e.left) (e.right) (e.len)
1140                    t.var t.l-var t.r-var =
1141              {
1142                e.left : 0, e.right : 0 = /*empty*/ t.var;
1143                <Gener-Vars ((VAR)) "subexpr_" t.var> : t.sub-var,
1144                  (SUBEXPR t.sub-var t.var (e.left)
1145                    ((INFIX "-" (e.len) (e.left e.right))))
1146                  t.sub-var;
1147              } :: e.subexpr t.var,
1148              {
1149                s.split : RSPLIT =
1150                  t.r-var t.l-var DEC-ITER;
1151                t.l-var t.r-var INC-ITER;
1152              } :: t.l-var t.r-var s.iter-op,
1153              <Gener-Label "continue"> :: t.cont-label,
1154              <Gener-Label "exit"> :: t.break-label,
1155              e.actions e.subexpr
1156              (s.split t.var (<Get-Var Min t.l-var>) t.l-var t.r-var)
1157              (FOR (t.cont-label) (t.break-label) () ((s.iter-op t.var))
1158                (IF ((NOT (CHECK-ITER t.var))) <Concat <R 0 v.fails>>)
1159                <CC s.tail?     (v.fails ((CONTINUE t.cont-label)))
1160                  <R 0 v.fails> e.Snt>
1161                (BREAK t.break-label)
1162              );
1163            e.actions <Comp-Sentence s.tail? (v.fails) () e.Snt>;
1164          };
1165        };
1166    };
1167};
1168
1169CC-Known-Lengths (e.fail) e.idxs, {
1170  e.idxs : (t.idx) e.rest =
1171    <Put &Checked-Lengths t.idx>,
1172    <Lookup &Known-Lengths t.idx> : (e.len-Re) (e.len-Pe),
1173    (IF ((INFIX "!=" (e.len-Re) (e.len-Pe))) e.fail)
1174    <CC-Known-Lengths (e.fail) e.rest>;
1175  <RFP-Clear-Table &Known-Lengths>;
1176};
1177
1178CC-Compute-Length (e.fail) (e.end-cycle) t.idx =
1179  <Lookup &Compute-Length t.idx> : t.var s.mult (e.minuend) (e.subtrahend),
1180  <Get-Var Min t.var> :: e.min,
1181  {
1182    t.var : (Len-Var e) =
1183      <Unbind &Compute-Length t.idx>,
1184      (IF ((INFIX "<" (e.minuend)
1185          ((INFIX "+" (e.subtrahend)
1186            ((INFIX "*" (e.min) (s.mult)))
1187        ))      ))
1188        e.end-cycle
1189      );
1190    <Create-Int-Var ("len") Aux e.minuend> :: t.m-var e.m-assign,
1191      <Create-Int-Var ("len") Aux e.subtrahend> :: t.s-var e.s-assign,
1192      ((INFIX "<" (t.m-var)
1193        ((INFIX "+" (t.s-var)
1194              ((INFIX "*" (e.min) (s.mult)))
1195        ))                      )) :: e.min-cond,
1196      <Get-Var Max t.var> : {
1197        /*empty*/;
1198        e.max =
1199          ((INFIX ">" (t.m-var)
1200            ((INFIX "+" (t.s-var)
1201                  ((INFIX "*" (e.max) (s.mult)))
1202          ))                    ));
1203      } :: e.max-cond,
1204      (INFIX "%" ((INFIX "-" (t.m-var) (t.s-var))) (s.mult)) :: e.div-cond,
1205      <Create-Int-Var ("len_") t.var
1206        (INFIX "/" ((INFIX "-" (t.m-var) (t.s-var))) (s.mult))
1207      > :: t.len-var e.len-assign,
1208      <Set-Var (Length t.len-var) t.var>,
1209      <Unbind &Compute-Length t.idx>,
1210      <Put &Checked-Lengths t.idx>,
1211      <Get-Var Clashes t.var> :: e.clashes,
1212      <Map &Reclassify-Clash (<Sub (e.clashes) <? &Checked-Lengths>>)> : e,
1213      e.m-assign e.s-assign
1214      (IF ((INFIX "||" e.min-cond e.max-cond)) e.end-cycle)
1215      (IF (e.div-cond) e.fail)
1216      e.len-assign;
1217  };
1218
1219$func  Get-Min e = e;
1220
1221$func? Get-Max e = e;
1222
1223CC-Unknown-Lengths (e.fail) e.idxs, {
1224  e.idxs : (t.idx) e.rest =
1225    <Lookup &Unknown-Lengths t.idx> : (e.len-Re) (e.len-Pe) (e.vars-Re) (e.vars-Pe),
1226    {
1227      <Get-Max e.vars-Re> :: e.max =
1228        <Get-Min e.vars-Pe> :: e.min,
1229        ((INFIX "<" (e.len-Re e.max) (e.len-Pe e.min)));
1230      /*empty*/;
1231    } :: e.cond1,
1232    {
1233      <Get-Max e.vars-Pe> :: e.max =
1234        <Get-Min e.vars-Re> :: e.min,
1235        ((INFIX ">" (e.len-Re e.min) (e.len-Pe e.max)));
1236      /*empty*/;
1237    } :: e.cond2,
1238    {
1239      e.cond1 : /*empty*/, e.cond2 : /*empty*/ = /*empty*/;
1240      (IF ((INFIX "||" e.cond1 e.cond2)) e.fail);
1241    } :: e.cond,
1242    e.cond
1243    <CC-Unknown-Lengths (e.fail) e.rest>;
1244  <RFP-Clear-Table &Unknown-Lengths>;
1245};
1246
1247Get-Min
1248{
1249  t.var e.vars = <Get-Var Min t.var> <Get-Min e.vars>;
1250  /*empty*/ = /*empty*/;
1251};
1252
1253Get-Max
1254{
1255  t.var e.vars = <Get-Var Max t.var> : v.max, v.max <Get-Max e.vars>;
1256  /*empty*/ = /*empty*/;
1257};
1258
1259$func Pos (e.Re) s.dir e.pos = e.pos;
1260
1261Pos {
1262  (e.Re) RIGHT e.pos = (INFIX "-" ((LENGTH e.Re)) (1) (e.pos));
1263  (e.Re) LEFT  e.pos = e.pos;
1264};
1265
1266/*
1267 * Информацию о проверках и заведении переменных, необходимых для создания
1268 * клешей из содержимого скобок, кодируем на ASAIL.
1269 */
1270CC-Deref (e.fail) e.actions, e.actions : {
1271  (SYMBOL? e.Re (s.dir e.pos)) e.rest =
1272    (IF ((SYMBOL? e.Re (<Pos (e.Re) s.dir e.pos>))) e.fail)
1273    <CC-Deref (e.fail) e.rest>;
1274  (DEREF t.var e.Re (s.dir e.pos)) e.rest =
1275    (DEREF t.var e.Re (<Pos (e.Re) s.dir e.pos>))
1276    <CC-Deref (e.fail) e.rest>;
1277  /*empty*/ = /*empty*/;
1278};
1279
1280CC-Eqs (e.fail) (e.assigns) e.eqs, {
1281  e.eqs : ((e.Re) (s.dir e.pos) t.Pt (e.len)) e.rest =
1282    {
1283      e.Re : t,
1284        <Get-Known-Length e.Re> : e.len (), // FIXME: здесь надо использовать
1285                          //        калькулятор
1286        s.dir e.pos : \{
1287          LEFT 0;
1288          RIGHT e.len;
1289        } =
1290        e.Re;;
1291    } :: e.Re-term,
1292    {
1293      e.len : 1 = TERM-EQ;      // FIXME: здесь надо использовать
1294                  //        калькулятор
1295      EQ;
1296    } :: s.eq,
1297    <Pos (e.Re) s.dir e.pos> :: e.pos,
1298    {
1299      \{
1300        <Get-Var Instantiated? t.Pt> : True = t.Pt (e.Re);
1301        t.Pt : \{
1302          (REF e);
1303          (STATIC e);
1304        }, {
1305          <Var? e.Re-term> = e.Re-term (t.Pt);
1306          t.Pt (e.Re);
1307        };
1308      } :: el (er),
1309        (IF ((NOT (s.eq el (er) (e.pos)))) e.fail) :: t.cond,
1310        {
1311          /*
1312           * Мы предполагаем, что во всех пришедших e.eqs все e.Re
1313           * уже были определены ранее.
1314           */
1315          e.assigns : $r e1 (s.op t.Pt e.def) e2 =
1316            <CC-Eqs (e.fail) (e1 (s.op t.Pt e.def) t.cond e2) e.rest>;
1317          t.cond <CC-Eqs (e.fail) (e.assigns) e.rest>;
1318        };
1319      <Set-Var (Instantiated? True) t.Pt>,
1320        {
1321          t.Pt : (SVAR e) =
1322            (IF
1323              ((NOT (SYMBOL? e.Re (<Pos (e.Re) s.dir e.pos>))))
1324              e.fail
1325            );;
1326        } :: e.cond,
1327        {
1328          <Get-Var Decl t.Pt> : s =
1329            e.cond <CC-Eqs (e.fail) (e.assigns
1330              (ASSIGN t.Pt (SUBEXPR e.Re (e.pos) (e.len))))
1331              e.rest>;
1332          <Vars-Decl Expr t.Pt> : e,
1333            e.cond <CC-Eqs (e.fail) (e.assigns
1334              (SUBEXPR t.Pt e.Re (e.pos) (e.len))) e.rest>;
1335        };
1336    };
1337  e.assigns e.eqs;
1338};
1339
1340
1341
1342
1343Gener-Label e.QualifiedName =
1344  {
1345    <Lookup &Labels e.QualifiedName> : s.num,
1346      <"+" s.num 1>;
1347    1;
1348  } :: s.num,
1349  <Bind &Labels (e.QualifiedName) (s.num)>,
1350  (e.QualifiedName s.num);
1351
1352Add-To-Label (e.label) e.name = <Gener-Label e.label "_" e.name>;
1353
1354
1355
1356
1357Lookup-Func t.Fname, \{
1358  <Lookup &Fun t.Fname>;
1359  <Lookup &Fun? t.Fname>;
1360} : s.linkage s.tag t.pragma (e.Fin) (e.Fout) =
1361  s.linkage s.tag t.pragma (e.Fin) (e.Fout);
1362
Note: See TracBrowser for help on using the repository browser.