source: to-imperative/trunk/compiler/rfp_compile.rf @ 2026

Last change on this file since 2026 was 2026, checked in by orlov, 15 years ago
  • Fixed old bug in the compiler.

samples/Syntax/block5.rf test passes at last.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 43.3 KB
Line 
1// $Source$
2// $Revision: 2026 $
3// $Date: 2006-07-16 14:26:16 +0000 (Sun, 16 Jul 2006) $
4
5$use "rfpc";
6$use "rfp_helper";
7$use "rfp_check";
8$use "rfp_as2as";
9$use "rfp_format";
10$use "rfp_vars";
11$use "rfp_const";
12$use "rfp_clashes";
13
14$use StdIO;
15$use Table;
16$use Box;
17$use Arithm;
18$use Access;
19$use Compare;
20$use Convert;
21$use Class;
22$use Apply;
23$use Dos;
24$use List;
25
26
27/*
28 * Table for storing object names.
29 */
30$table Objects;
31
32/*
33 * Table for storing parameters of referenced functions.
34 */
35$table Stub-Funcs;
36
37/*
38 * Box for storing function out format
39 */
40$box Out-Format;
41
42/*
43 * Box for storing names for function result variables
44 */
45$box Res-Vars;
46
47/*
48 * Following table is used by Gener-Label function for obtaining unical (for
49 * certain function) label name.
50 * e.Key ::= e.QualifiedName      (parameter given to Gener-Label)
51 * e.Val ::= [Int]          (last index used with such e.QualifiedName)
52 */
53$table Labels;
54
55/*
56 * Table for storing variables used in place of preprocessor-generated ones.
57 */
58$table Prep-Vars;
59
60
61$func Compile (e.targets) (e.headers) e.Items = e.Compiled-Items (INTERFACE e.headers);
62
63$func Comp-Func-Stubs = e.asail-funcs;
64
65$func Comp-Func s.tag t.name e.params-and-body = e.compiled-func;
66
67$func Set-Drops (e.declared-exprs) e.comp-func = (e.declared-exprs) e.result-func;
68
69$func Comp-Sentence e.Sentence = e.asail-sentence;
70
71$func Save-Snt-State = ;
72
73$func Recall-Snt-State = ;
74
75$func Pop-Snt-State = ;
76
77$func Extract-Calls e.Re = (e.last-Re) e.calls;
78
79$func Get-Clash-Sequence (e.last-Re) e.Snt = (e.clashes) e.rest-of-the-Sentence;
80
81$func? Without-Calls? e.Re = ;
82
83$func Comp-Clashes (e.clashes) s.tail? (v.fails) e.Sentence = e.asail-sentence;
84
85$func Gener-Label e.QualifiedName = t.label;
86
87$func Add-To-Label t.label e.name = t.label;
88
89$func Comp-Calls e.Re = e.calls;
90
91$func Prepare-Vars e.vars = e.vars;
92
93$func Prepare-Res e.Reult-exprs = e.Result-exprs;
94
95$func Comp-Assigns e.assignments = e.asail-assignments;
96
97$func Comp-Format (e.last-Re) e.He = e.assignments;
98
99
100
101************ Get AS-Items and targets, and pass it to Compile ************
102
103/*
104 * Ящик для объявлений статических функций, констант и объектов.  Все они
105 * выписываются в самом начале тела модуля.
106 */
107$box Declarations;
108
109$box Trace-Names;
110
111$table Includes;
112
113RFP-Compile e.Items =
114  { <Lookup &RFP-Options ITEMS>;; } :: e.targets,
115  <RFP-Clear-Table &Stub-Funcs>,
116  <RFP-Clear-Table &Includes>,
117  <Store &Trace-Names /*empty*/>,
118  <Store &Declarations /*empty*/>,
119  <Init-Consts>,
120  <Compile (e.targets) () e.Items> :: e.Items t.Interface,
121  <Comp-Func-Stubs> :: e.stub-funcs,
122  t.Interface
123  (MODULE <Domain &Includes> <? &Trace-Names> <? &Declarations> <Comp-Consts> e.Items e.stub-funcs);
124
125
126
127****************** Choose needed items and compile them ******************
128
129Compile (e.targets) (e.headers) e.Items, {
130  e.Items : e t.item e.rest,
131    {
132      e.targets : v =
133        e.targets : e t.name e,
134        t.item : (t t t t.name e);;
135    },
136    t.item : {
137      (IMPORT s.tag t.pragma t.name e) =
138        {
139          t.pragma : (PRAGMA e (FILE e.fname) e) =
140            <RFP-Extract-Qualifiers t.name> :: (e.mod-name) e,
141            <Bind &Includes (INPUT (e.mod-name) e.fname) ()>;;
142        },
143        () /*empty*/;
144      (TRACE t.name) =
145        <Put &Trace-Names (TRACE t.name)>,
146        () /*empty*/;
147      (EXTERN t.pragma t.name) =
148        <Put &Declarations (EXTERN t.name)>,
149        () /*empty*/;
150      (s.link s.tag t.pragma t.name (e.in) (e.out) e.body), FUNC FUNC? TFUNC : e s.tag e =
151        {
152          <? &Declarations> : $r e (s t.name) e = /*empty*/;
153          (DECL-FUNC t.name);
154        } :: e.decl,
155        <Put &Declarations e.decl>,
156        {
157          s.link : EXPORT = e.decl;
158           /*empty*/;
159        } :: e.decl,
160        {
161          e.body : (BRANCH t.p e.branch) =
162            <Comp-Func s.tag t.name <Del-Pragmas (e.in) (e.out) e.branch>>;;
163        } :: e.comp-func,
164        (e.decl) e.comp-func;
165      (s.link CONST t.pragma t.name e.expr) =
166        (CONSTEXPR s.link t.name (e.expr) e.expr) :: t.const,
167        <Put &Declarations t.const>,
168        {
169          s.link : EXPORT = ((DECL-OBJ t.name)) /*empty*/;
170          () /*empty*/;
171        };
172      (EXPORT s.tag t.pragma t.name) =
173        <Put &Declarations (OBJ EXPORT s.tag t.name)>,
174        ((DECL-OBJ t.name)) /*empty*/;
175      (LOCAL  s.tag t.pragma t.name) =
176        <Put &Declarations (OBJ LOCAL s.tag t.name)>,
177        () /*empty*/;
178    } :: (e.decl) e.item =
179    e.item <Compile (e.targets) (e.headers e.decl) e.rest>;
180  /*<Comp-Func-Stubs>*/ (INTERFACE e.headers);
181};
182
183
184
185$func Gener-Stub e = e;
186
187/*
188 * For each referenced function generate a stub one with format e = e.
189 */
190Comp-Func-Stubs = <Map &Gener-Stub (<Domain &Stub-Funcs>)>;
191
192Gener-Stub (t.name) =
193  <Lookup &Stub-Funcs t.name> : t.stub-name s.tag (e.Fin) (e.Fout),
194  <Put &Declarations (DECL-FUNC t.stub-name)>,
195  <Gener-Vars (e.Fin) "stub"> :: e.He,
196  <Comp-Func STUB t.stub-name ((EVAR ("arg" 1))) ((EVAR))
197    (LEFT e.He) (CUTALL) (RESULT (CALL t.name e.He))>;
198
199
200
201Comp-Func s.tag t.name (e.in) (e.out) e.Sentence =
202  <RFP-Clear-Table &Labels>,
203  <RFP-Clear-Table &Prep-Vars>,
204  <Init-Vars>,
205  <Vars <Gener-Vars (e.out) "res">> :: e.res-vars,
206  <Vars-Decl Result e.res-vars> : e,
207  <Store &Res-Vars e.res-vars>,
208  <Store &Out-Format <Format-Exp e.out>>,
209  <Prepare-Res (e.in)> : (e.arg),
210  <Vars e.arg> :: e.arg-vars,
211  <Map &Set-Var- (Instantiated? True) (e.arg-vars)> : e,
212  s.tag : {
213    FUNC = FUNC (FATAL);
214    FUNC? = FUNC? (RETFAIL);
215    TFUNC = TFUNC (FATAL);
216    STUB =
217      <Prepare-Res (Apply Apply "Unexpected fail")> : (e.message),
218      FUNC? (RETFAIL) ((ERROR e.message));
219  } :: s.tag e.fails,
220  (s.tag t.name (<Vars-Print e.arg-vars>) (<Vars-Print e.res-vars>)
221    <Comp-Sentence Tail (e.fails) (e.arg) e.Sentence>
222  ) :: e.comp-func,
223*       <Set-Drops () <Gener-Var-Names e.comp-func>> :: t e.comp-func,
224  <Gener-Var-Names e.comp-func> :: e.comp-func,
225//!     <Post-Comp (e.res-vars) e.comp-func> :: t e.result,
226//!     e.result;
227  e.comp-func;
228//  :: (e.func-decl) e.func-body,
229//  () <Domain &Declarations> $iter {
230//    e.vars : (t.var) e.rest-vars,
231//      (e.var-decls (DECL t.var)) e.rest-vars;
232//  } :: (e.var-decls) e.vars,
233//  e.vars : /*empty*/,
234//  (e.func-decl e.var-decls e.func-body);
235
236Set-Drops (e.declared) e.comp-func =
237  e.comp-func () (e.declared) $iter {
238    e.comp-func : t.first e.rest, {
239      t.first : \{
240        (EXPR t.var e) = (DROP t.var) (t.first) t.var Init;
241        (DEREF t.var e) = (DROP t.var) (t.first) t.var Init;
242        (SUBEXPR t.var e) = (DROP t.var) (t.first) t.var Init;
243        (DECL Expr t.var) = (DROP t.var) () t.var Decl;
244        (DECL "int" t.var) = /*empty*/ () t.var Decl;
245      } :: e.drop (e.constr) t.var s.init,
246        {
247          e.declared : e1 t.var s.old-init e2, s.old-init : {
248            Init, {
249              t.var : (VAR ("const" e)) =
250                e.rest (e.result-func) (e.declared);
251              e.rest (e.result-func e.drop e.constr) (e.declared);
252            };
253            Decl, s.init : {
254              Decl =
255                e.rest (e.result-func) (e.declared);
256              Init =
257                t.first : (s.method t.var e.args),
258                e.rest (e.result-func (ASSIGN t.var (s.method e.args)))
259                (e1 e2 t.var s.init);
260                /*
261                 * FIXME: if s.method is EXPR, it shouldn't be written.
262                 */
263            };
264          };
265          e.rest (e.result-func t.first) (e.declared t.var s.init);
266        };
267      t.first : (LABEL (t.label) e.expr) =
268        <Set-Drops (e.declared) e.expr> :: (e.declared) e.expr,
269        e.rest (e.result-func (LABEL (t.label) e.expr)) (e.declared);
270      t.first : (e.expr) =
271        <Set-Drops (e.declared) e.expr> :: t e.expr,
272        e.rest (e.result-func (e.expr)) (e.declared);
273      t.first : s.symbol =
274        e.rest (e.result-func s.symbol) (e.declared);
275    };
276  } :: e.comp-func (e.result-func) (e.declared),
277  e.comp-func : /*empty*/ =
278  (e.declared) e.result-func;
279
280
281Comp-Sentence s.tail? (v.fails) (e.last-Re) e.Sentence, e.Sentence : {
282
283  /*empty*/ = /*empty*/;
284
285  /*
286   * In case of Re look if we should do a tailcall.  If not, then compile
287   * function calls from the Re and assign results to the out parameters or
288   * use them in compilation of the rest of the sentence.
289   */
290  (RESULT e.Re) e.Snt =
291    {
292      /*
293       * If the Re is the last action in the sentence then we can do
294       * tailcall if one of the following is true:
295       *  - Re is a call of non-failable function;
296       *  - Re is a call of a failable function, current function is
297       *  failable, and the failures stack is empty.
298       * In both cases out format of the called function should coincide
299       * with those of compiled one.
300       * FIXME: really we can do tailcall if all the parameters of
301       * compiled function that won't get their values from the call can
302       * be assigned from other sources.  Some support from runtime is
303       * needed though.
304       */
305      e.Snt : /*empty*/, s.tail? : Tail, e.Re : (CALL t.name e.arg),
306        {
307          <In-Table? &Fun? t.name> =
308            v.fails : (RETFAIL),
309            TAILCALL?;
310          TAILCALL;
311        } :: s.tailcall,
312        <Lookup-Func t.name> :: s.linkage s.tag t.pragma (e.Fin) (e.Fout),
313        <Subformat? (e.Fout) (<? &Out-Format>)> =
314        <Extract-Calls e.arg> :: (e.last-Re) e.calls,
315        <Prepare-Res <Split-Re (e.Fin) e.last-Re>> :: e.splited-Re,
316        <Comp-Calls <R 0 v.fails> e.calls>
317        (s.tailcall t.name (e.splited-Re) (<? &Res-Vars>));
318
319      <Extract-Calls e.Re> :: (e.last-Re) e.calls,
320        <Comp-Calls <R 0 v.fails> e.calls> :: e.comp-calls,
321        {
322          e.Snt : /*empty*/, Tail Tail-in-Trap : e s.tail? e =
323            <Split-Re (<? &Out-Format>) e.last-Re> :: e.splited-Re,
324            <Prepare-Res e.splited-Re> :: e.splited-Re,
325            e.comp-calls <Comp-Assigns <Zip (<? &Res-Vars>) (e.splited-Re)>>;
326
327          e.comp-calls <Comp-Sentence s.tail? (v.fails) (e.last-Re) e.Snt>;
328        };
329    };
330
331  /*
332   * In case of He compile assignments from last Re and then (with new state
333   * of variables) proceed with the rest of the sentence.
334   */
335  (FORMAT e.He) e.Snt =
336    <Comp-Format (e.last-Re) e.He>
337    <Comp-Sentence s.tail? (v.fails) () e.Snt>;
338
339  /*
340   * In case of Pe get from the begining of the sentence a maximum possible
341   * sequence of clashes and compile it.  New values of variables from the
342   * clashes use in the compilation of the rest of the sentence.
343   */
344  (s.dir e.Pattern) e.Snt, s.dir : \{ LEFT; RIGHT; } =
345    <Get-Clash-Sequence (e.last-Re) e.Sentence> :: (e.clashes) e.Sentence,
346    <Comp-Clashes (e.clashes) s.tail? (v.fails) e.Sentence>;
347
348  (s.block) e, BLOCK BLOCK? : e s.block e = <WriteLN! &StdErr "Empty block?">, $fail;
349
350  /*
351   * In case of a block first see if its results are needed for something
352   * after the block and determine whether the block is a source.  Then
353   * compile each branch in turn.
354   */
355  (s.block e.branches) e.Snt,
356    s.block : \{
357      BLOCK = (FATAL);
358      BLOCK?;
359    } :: e.fatal? =
360    /*
361     * If the block initializes an $iter then extract from the $iter the He
362     * for placing it in the end of each branch.
363     * Then look if the block is used by a format expression.
364     * If so, we should declare variables from that expression before
365     * entering any branch -- those should be visible after the block.
366     * The format expression is placed in the end of each branch.
367     * But if a branch computes to $error, the expression shouldn't be
368     * used, so protect it with (Comp If-not-error).
369     * If next after the block is (Comp Error) then block results should be
370     * used as values for $error, so place (Comp Error) in the end of each
371     * branch.
372     * If next after the block is (Comp If-not-error) then our block is in
373     * the end of a branch of an outer block and has next pattern or format
374     * inherited from there.  In that case we should place all the sentence
375     * rest in the end of each branch because the block can be inside the
376     * $error already.
377     */
378    {
379      e.Snt : (ITER t.body t.format t.cond) e.rest =
380        t.format (Comp Iter t.body t.format t.cond) e.rest;
381      e.Snt;
382    } :: e.Snt,
383    e.Snt : {
384      (FORMAT e.format) e.rest =
385        <Prepare-Vars <Vars e.format>> :: e.vars,
386        (e.vars) ((Comp If-not-error) (FORMAT e.format))
387        ((Comp Source)) e.rest;
388      (Comp Error) e.rest =
389        () ((Comp Error)) () /*empty*/;
390      (Comp If-not-error) e.rest =
391        () (e.Snt) () /*empty*/;
392      e = () () () e.Snt;
393    } :: (e.out-vars) (e.next-terms) (e.source?) e.Snt,
394    /*
395     * The block is a source if after it goes format expression
396     * (in that case e.source? isn't empty) or e.Snt isn't empty.
397     * Branches in the block are tail sentences if the current sentence is
398     * tail and the block isn't a source.
399     */
400    {
401      \{ e.source? : v; e.Snt : v; } = ((Comp Source) <R 0 v.fails>) Notail;
402      () s.tail?;
403    } :: (e.source?) s.tail-branch?,
404    /*
405     * In case our block is a source we should mark the position in the
406     * failures stack, so that we can jump to it after CUTALL.  And if our
407     * block isn't failable we should add (FATAL) to the end of the stack.
408     */
409    v.fails e.source? e.fatal? :: v.branch-fails,
410    /*
411     * Before compile the branches mark all out-vars as declared.
412     */
413    <Vars-Decl Expr e.out-vars> :: e.decls,
414    /*
415     * We put all compiled branches in a block, so positive return from a
416     * branch is a break from that block.
417     * Each branch in its turn is placed in its own block, so for a $fail
418     * to the next branch we should just break from that inner block.
419     * Each branch is compiled with the current sentence state and the
420     * state is recalled after that.  When all branches are compiled the
421     * state is popped out from the stack.
422     * If last branch fails then the whole block fails, and return from the
423     * last branch is return from the block.  So the last branch isn't
424     * placed in a block and is processed with the failures stack that was
425     * before entering the block.  Note: this trick helps us find more
426     * tailcalls.  If the call of a failable function is on the last branch
427     * of the block and the failures stack is empty we can do tailcall.
428     * When the last branch is compiled with the block's stack, all we
429     * should do is to check it.
430     */
431    <Gener-Label "block"> :: t.label,
432    <Save-Snt-State>,
433    (e.branches) /*e.comp-branches*/ $iter {
434      e.branches : (BRANCH e.branch) e.rest-br =
435        <Add-To-Label t.label "branch"> :: t.br-label,
436        <Comp-Sentence
437          s.tail-branch?
438          (v.branch-fails ((BREAK t.br-label)))
439          (e.last-Re)
440          e.branch e.next-terms
441        > :: e.comp-br,
442        <Recall-Snt-State>,
443        (e.rest-br) e.comp-branches (LABEL (t.br-label) e.comp-br (BREAK t.label));
444    } :: (e.branches) e.comp-branches,
445    e.branches : (BRANCH e.branch) =
446    <Comp-Sentence
447      s.tail-branch? (v.branch-fails) (e.last-Re) e.branch e.next-terms
448    > :: e.last-branch,
449    <Pop-Snt-State>,
450    <Vars-Reset e.out-vars>,
451    e.decls (LABEL (t.label) e.comp-branches e.last-branch)
452    <Comp-Sentence s.tail? (v.fails) () e.Snt>;
453
454  /*
455   * In case of $iter first of all compile initial assignment to the hard
456   * expression.
457   */
458  (ITER t.body t.format t.cond) e.Snt =
459    <Comp-Sentence s.tail? (v.fails) (e.last-Re)
460      t.format (Comp Iter t.body t.format t.cond) e.Snt
461    >;
462
463  /*
464   * Before compiling $iter condition or body we should forget available info
465   * about all format variables, because that info can be changed during
466   * cycle iterations.
467   * Then compile $iter condition and body both with the current state of the
468   * sentence.
469   * e.Snt can contain (Comp Error) and (protected from errors) pattern or
470   * format which comes from an outer block, so compile it together with the
471   * condition.
472   * If condition fails we should compute the body, so put the compiled
473   * condition in a block and place a break from it to the failures stack.
474   */
475  (Comp Iter (BRANCH e.body) t.format (BRANCH e.condition)) e.Snt =
476    t.format : (FORMAT e.Fe),
477    <Vars-Reset <Prepare-Vars <Vars e.Fe>>>,
478    <Save-Snt-State>,
479    <Gener-Label "iter"> :: t.label,
480    <Gener-Label "exit_iter"> :: t.exit,
481    <Comp-Sentence s.tail? (v.fails ((BREAK t.label))) () e.condition e.Snt>
482      :: e.comp-condition,
483    <Pop-Snt-State>,
484    <Comp-Sentence Notail (v.fails) () e.body t.format> :: e.comp-body,
485    (FOR (/*cont-label*/) (t.exit) () ()
486      (LABEL (t.label) e.comp-condition (BREAK t.exit)) e.comp-body
487    );
488
489  /*
490   * In case of $trap/$with at first compile try-sentence.  All $fails from
491   * it should become errors.
492   * Then recall the state of the sentence and compile catching of an error
493   * with a variable err.
494   * e.Snt can contain (Comp Error) and (protected from errors) pattern or
495   * format which comes from an outer block, so compile it together with both
496   * sentences.
497   */
498  (TRY (BRANCH e.try) e.catch) e.Snt =
499    <Save-Snt-State>,
500    {
501      s.tail? : Tail = Tail-in-Trap;
502      s.tail?;
503    } :: s.tail-in-trap?,
504    <Comp-Sentence s.tail-in-trap? ((FATAL)) () e.try e.Snt> :: e.comp-try,
505    <Pop-Snt-State>,
506    <Gener-Err-Var> :: t.var,
507    <Set-Var (Instantiated? True) t.var>,
508    <Comp-Sentence s.tail? (v.fails) (t.var) e.catch e.Snt> :: e.comp-catch,
509    (TRY e.comp-try) (CATCH-ERROR e.comp-catch);
510
511  /*
512   * In case of \? add Stake to the failures stack.  Add last fail after it
513   * for <R 0 v.fails> continue to work.
514   */
515  (STAKE) e.Snt =
516    <Comp-Sentence s.tail? (v.fails (Comp Stake) <R 0 v.fails>) () e.Snt>;
517
518  /*
519   * In case of \! forget all failure catchers after last \?.
520   * If there is no Stake then we are inside negation or error (we assume the
521   * program is correct).  So the right failure catcher is in the bottom of
522   * the stack.
523   */
524  (CUT) e.Snt =
525    {
526      v.fails : $r v.earlier-fails (Comp Stake) e = v.earlier-fails;
527      <L 0 v.fails>;
528    } :: v.fails,
529    <Comp-Sentence s.tail? (v.fails) () e.Snt>;
530
531  /*
532   * In case of = clear the failures stack up to the closest source.
533   * Don't clear last fail after it for <R 0 v.fails> continue to work.
534   */
535  (CUTALL) e.Snt =
536    {
537      v.fails : $r v.earlier-fails (Comp Source) t.fail e =
538        v.earlier-fails (Comp Source) t.fail;
539      <L 0 v.fails>;
540    } :: v.fails,
541    <Comp-Sentence s.tail? (v.fails) () e.Snt>;
542
543  /*
544   * In case of = in the Refal-6 sense (non-transparent hedge for the fails),
545   * $fail(k) should become $error(Fname "Unexpected fail"), so clear the
546   * failures stack and put that value in it.
547   */
548  NOFAIL e.Snt =
549    <Comp-Sentence s.tail? ((FATAL)) (e.last-Re) e.Snt>;
550
551  /*
552   * In case of $fail return last failure catcher.
553   */
554  (FAIL) e.Snt =
555    v.fails : e (e.last-fail),
556    e.last-fail;
557
558  /*
559   * In case of # we should proceed with the rest if the source is computed
560   * to $fail.
561   * We could compile the rest of the sentence and place it in the
562   * failures stack.  But then the compiled sentence would be copied as many
563   * times as there are $fail's to the upper level in the source.  So we
564   * place compiled source in the block and put the break to exit from it in
565   * the stack.
566   * When compiling the source mark it as Notail as usual.
567   * If the source isn't computed to $fail we should proceed with the last
568   * failure catcher.
569   */
570  (NOT (BRANCH e.branch)) e.Snt =
571    <Gener-Label "negation"> :: t.label,
572    v.fails : e (e.last-fail),
573//    <Save-Snt-State>,
574    <Comp-Sentence Notail (((BREAK t.label))) () e.branch> e.last-fail
575      :: e.comp-negation,
576//    <Pop-Snt-State>,
577    (LABEL (t.label) e.comp-negation) <Comp-Sentence s.tail? (v.fails) () e.Snt>;
578
579  /*
580   * In case of $error all fails become $error(Fname "Unexpected fail").  So
581   * place that value in the failures stack and then compile the computation
582   * of the rest of the sentence and the last Re which should be the value of
583   * $error.
584   */
585  (ERROR) e.Snt =
586    <Comp-Sentence Notail ((FATAL)) () e.Snt (Comp Error)>;
587
588  (Comp Error) e.Snt =
589    <Prepare-Res (e.last-Re)> : (e.Re),
590    (ERROR e.Re);
591
592  /*
593   * Protection mark to be used between source and tail.  If there is $error
594   * construction somewhere in the source then the tail shouldn't be
595   * computed, but instead the source value should be used for throwing.
596   */
597  (Comp If-not-error) e.Snt =
598    {
599      e.Snt : e (Comp Error) =
600        <Comp-Sentence s.tail? (v.fails) (e.last-Re) (Comp Error)>;
601      <Comp-Sentence s.tail? (v.fails) (e.last-Re) e.Snt>;
602    };
603
604//  (Comp Fatal) = FATAL;
605
606//  (Comp Retfail) = RETFAIL;
607
608};
609
610
611
612********** Sentence state stack and functions for work with it. **********
613
614$box Snt-State;
615
616/*
617 * Put current state in the stack.
618 */
619Save-Snt-State = <Put &Snt-State <Vars-Copy-State>>;
620
621/*
622 * Set current state to that at the top of the stack.
623 */
624Recall-Snt-State = <Vars-Set-State <R 0 <? &Snt-State>>>;
625
626/*
627 * Pop the top from the stack and set current state to it.
628 */
629Pop-Snt-State =
630  <Recall-Snt-State>,
631  <Store &Snt-State <Middle 0 1 <? &Snt-State>>>;
632
633
634
635********************** Function calls compilation. ***********************
636
637/*
638 * $func Extract-Calls e.Re = (e.last-Re) e.calls;
639 *
640 *
641 *
642 */
643Extract-Calls {
644  (CALL t.name e.arg) e.rest =
645    <Lookup-Func t.name> :: s.linkage s.tag t.pragma (e.Fin) (e.Fout),
646    <Extract-Calls e.arg> :: (e.last-Re) e.calls,
647    <Prepare-Res <Split-Re (e.Fin) e.last-Re>> :: e.splited-Re,
648    <RFP-Extract-Qualifiers t.name> :: t e.prefix,
649    <Gener-Subst-Vars (e.Fout) e.prefix> :: e.Re,
650    <Vars e.Re> :: e.vars,
651    <Map &Set-Var- (Instantiated? True) (e.vars)> : e,
652    {
653      s.tag : FUNC? =   (Failable (CALL t.name (e.splited-Re) (e.vars)));
654      (CALL t.name (e.splited-Re) (e.vars));
655    } :: t.call,
656    <Extract-Calls e.rest> :: (e.rest-Re) e.rest-calls,
657    (e.Re e.rest-Re) e.calls <Vars-Decl Result e.vars> t.call e.rest-calls;
658  (PAREN e.Re) e.rest =
659    <Extract-Calls e.Re> :: (e.last-Re) e.calls,
660    <Extract-Calls e.rest> :: (e.rest-Re) e.rest-calls,
661    ((PAREN e.last-Re) e.rest-Re) e.calls e.rest-calls;
662  t.Rt e.Re =
663    <Extract-Calls e.Re> :: (e.last-Re) e.calls,
664    (t.Rt e.last-Re) e.calls;
665  /*empty*/ = () /*empty*/;
666};
667
668
669Comp-Calls (e.fail) e.calls, e.calls : {
670  (Failable t.call) e.rest =
671    (IF ((NOT t.call)) e.fail) <Comp-Calls (e.fail) e.rest>;
672  t.call e.rest =
673    t.call <Comp-Calls (e.fail) e.rest>;
674  /*empty*/ = /*empty*/;
675};
676
677
678
679********** Preparation of vars and REs for following processing **********
680*********** Compilation of static parts of result expressions ************
681
682$func Static-Expr? s.create? e.Re = static? e.Re;
683
684$func Ref-Func? t = t;
685
686$func Static-Term? t.Rt = static? e.Re;
687
688$func Stub-Name t.name = t.stub-name;
689
690
691/*
692 * Extract static parts from each Re.
693 * Also get the right names for variables generated during the preprocessing
694 * stage, if those are in the expr.
695 */
696Prepare-Res {
697  (e.Re) e.rest = <Static-Expr? Create e.Re> :: s e.Re, (e.Re) <Prepare-Res e.rest>;
698  /*empty*/     = /*empty*/;
699};
700
701/*
702 * Find all the longest static parts in the upper level of Re.  Create STATIC
703 * form in place of each one.
704 * Return a tag pointing whether the whole expression is static and expression
705 * with static parts replaced by STATIC forms.  Dynamic parts are returned
706 * unchanged.
707 */
708Static-Expr? s.create? e.Re =
709  (/*e.static*/) e.Re $iter {
710    e.Re : t.Rt e.rest =
711      <Static-Term? t.Rt> : {
712        Static e.st-Re =
713          (e.static e.st-Re) e.rest;
714        Dynamic t.dyn-Rt =
715          <Static-Expr? Create e.rest> :: s e.rest,
716          (e.static) (Dynamic t.dyn-Rt e.rest);
717      };
718    (e.static);
719  } :: (e.static) e.Re,
720  e.Re : \{
721    /*empty*/, {
722      s.create? : Create =
723        Static <Create-Static e.static>;
724      Static e.static;
725    };
726    (Dynamic e.dynamic) = Dynamic <Create-Static e.static> e.dynamic;
727  };
728
729/*
730 * The same as Static-Expr? but for terms.
731 */
732Static-Term? {
733  symbol       = Static symbol;
734  (PAREN e.Re) = <Static-Expr? Not-Create e.Re> :: static? e.Re, static? (PAREN e.Re);
735  (REF t.name) = Static <Ref-Func? (REF t.name)>;
736  (STATIC t.name) = Static <Get-Static (STATIC t.name)>;
737  t.var        = <Prepare-Vars t.var> : t.prep-var, Dynamic t.prep-var;
738};
739
740Ref-Func? {
741  (REF t.name) =
742    {
743      <Lookup-Func t.name> : {
744        s.linkage s.tag t.pragma ((EVAR)) ((EVAR)) = (s.tag t.name);
745        s.linkage s.tag t.pragma (e.Fin) (e.Fout) =
746          {
747            <Lookup &Stub-Funcs t.name> : t.stub-name e =
748              (FUNC? t.stub-name);
749            <Stub-Name t.name> :: t.stub-name,
750              <Bind &Stub-Funcs (t.name)
751                (t.stub-name s.tag (e.Fin) (e.Fout))>,
752              (FUNC? t.stub-name);
753          };
754      };
755      (REF t.name);
756    };
757  term = term;
758};
759
760Prepare-Vars {
761  (s.var-tag (e.prefix s.n)) e.rest, <Int? s.n> =
762    {
763      <Lookup &Prep-Vars e.prefix s.n>;
764      <Gener-Vars ((s.var-tag)) e.prefix> :: e.var,
765        <Bind &Prep-Vars (e.prefix s.n) (e.var)>,
766        e.var;
767    } :: e.var,
768    e.var <Prepare-Vars e.rest>;
769  t.var e.rest = t.var <Prepare-Vars e.rest>;
770  /*empty*/ = /*empty*/;
771};
772
773/*
774 * Генерируем уникальные внутри модуля имена для функций-заглушек.
775 */
776Stub-Name (e.qualifiers s.name) =
777  <To-Chars s.name> : {
778    e1 '_' s.n, <Int? s.n> = e1 '_' <"+" s.n 1>;
779    e1 = e1 '_' 0;
780  } :: e.name,
781  (/*e.qualifiers*/ <To-Word e.name>) :: t.name,
782  {
783    <Lookup-Func t.name> : e = <Stub-Name t.name>;
784    t.name;
785  };
786
787
788
789***************** Compilation of assignment to variables *****************
790
791$func Comp-Assign-to-Var t.var e.Re (e.assigned-vars) = e.assign (e.used-vars);
792
793Comp-Assign-to-Var t.var e.Re (e.assigned-vars) =
794  {
795    t.var : e.Re = /*empty*/ ();
796    <Vars-Reset t.var>, $fail;
797    <Substitutable-Var? e.Re>, # \{ e.assigned-vars : e t.var e; } =
798      <Gener-Var-Assign t.var e.Re> ();
799    <Get-Var Decl t.var> : s = (ASSIGN <Vars-Print t.var> e.Re) (<Vars e.Re>);
800    <Vars-Decl Expr t.var> : e, (EXPR <Vars-Print t.var> e.Re) (<Vars e.Re>);
801  };
802
803Comp-Assigns e.assigns =
804  e.assigns (/*e.assigned-vars*/) (/*e.comp-assigns*/) $iter {
805    e.assigns : (t.var (e.Re)) e.rest =
806      <Comp-Assign-to-Var t.var e.Re (e.assigned-vars)> :: e.c-as (e.a-vs),
807      e.rest (e.assigned-vars e.a-vs) (e.comp-assigns e.c-as);
808  } :: e.assigns (e.assigned-vars) (e.comp-assigns),
809  e.assigns : /*empty*/ =
810  e.comp-assigns;
811
812
813
814************************** FORMAT compilation. ***************************
815
816$box Aux-Index;
817
818$func Gener-Aux-Var = t.new-aux-var;
819
820Gener-Aux-Var =
821  <? &Aux-Index> : s.n,
822  <Store &Aux-Index <"+" s.n 1>>,
823  (VAR ("aux" s.n));
824
825
826$func Create-Aux-Vars (e.vars) e.splited-Re = e.assigns;
827
828
829Comp-Format (e.last-Re) e.He =
830  <Prepare-Vars <Vars e.He>> :: e.vars,
831  <Prepare-Res <Split-Re (<Format-Exp e.He>) e.last-Re>> :: e.splited-Re,
832  <Store &Aux-Index 1>,
833  <Create-Aux-Vars (e.vars) e.splited-Re> :: e.assigns,
834  <Comp-Assigns e.assigns>;
835
836/*
837 * Итак, e.vars -- все переменные, входящие в форматное выражение.  Каждая
838 * переменная может входить в форматное выражение только один раз, поэтому
839 * повторяющихся среди них нет.
840 * e.splited-Re -- набор результатных выражений.  На каждую переменную из
841 * e.vars по выражению, которое должно быть ей присвоено.
842 *
843 * Если переменная t.var_i используется в выражении e.Re_j, и i /= j, то
844 * переменной t.var_j значение должно быть присвоено раньше, чем перeменной
845 * t.var_i.  Если же, по аналогичным соображениям, t.var_i должна получить
846 * значение раньше t.var_j, необходимо завести вспомогательную переменную.
847 *
848 * Пример:
849 *
850 * t1 (t1 t2) (t1 t3) :: t2 t1 t3
851 *
852 * t3 = (t1 + t3)();
853 * aux_1 = t1;
854 * t1 = (t1 + t2)()
855 * t2 = aux_1;
856 *
857 * В общем случае вспомогательная переменная требуется, если двум переменным
858 * необходимы старые значения друг друга (возможно, не напрямую, а через
859 * промежуточные переменные).
860 *
861 * Вместо того, чтобы искать и анализировать такие циклы, будем действовать по
862 * методу "наибольшей пользы".  А именно:
863 *
864 *   - Для каждой переменной выпишем все другие переменные, которым требуется
865 *     её старое значение, а также отдельно те, старые значения которых
866 *     требуются ей.
867 *
868 *   - Всем переменным, от старых значений которых ничего не зависит, можно
869 *     смело присвоить новые значения.  При этом они исчезают из списков
870 *     зависимостей оставшихся переменных.
871 *
872 *   - Все переменные, новые значения которых ни от чего не зависят, можно
873 *     отложить, чтобы присвоить им значения тогда, когда будет удобно.  Т.е.
874 *     тогда, когда списки зависящих от них переменных опустеют.
875 *
876 *   - Чтобы означить оставшиеся, нужны вспомогательные переменные.  Выберем
877 *     одну из переменных, с максимальным списком тех, от которых она зависит,
878 *     и положим её значение во вспомогательную переменную.  Так как мы сразу
879 *     уменьшили кол-во зависимостей у максимального кол-ва переменных,
880 *     локально мы добились наибольшей пользы, хотя не исключено, что глобально
881 *     такой метод и не даст наименьшего кол-ва вспомогательных переменных.
882 *     Кроме того, мы не пытаемся выбрать наилучшую переменную из нескольких с
883 *     максимальным списком зависимостей.
884 *
885 *   - Повторяем всё это до тех пор, пока у каждой переменной не опустеет
886 *     список зависящих от неё.
887 *
888 *
889 * Для нашего примера:
890 *
891 * t1 (t1 t2) (t1 t3) :: t2 t1 t3
892 *
893 * t1 -- (t2 t3) (t2)
894 * t2 -- (t1)    (t1)
895 * t3 -- ()      (t1)
896 *
897 *
898 * Для каждой переменной var_i найдём все j /= i, такие что в Re_j встречается
899 * var_i -- provide[i], и а также все j /= i, такие что var_j нужна для
900 * подсчёта var_i, т.е. встречается в Re_i.
901 *
902 * Res-vars <- <Map &Vars (Res)>
903 * for var_i in vars
904 *     provide[i] <-
905 *     for vars-Re_j in Res-vars, j /= i
906 *         vars-Re_j : e var_i e = j
907 *     require[i] <- <Res-vars[i] `*` vars[^i]> : e var_j e, j
908 *
909 * Res-vars = map Vars Res
910 * provide, require =
911 *   {   [ j | vars-Re_j <- Res-vars, j /= i, var_i `in` vars-Re_j ]
912 *     , [ j | var_j <- Res-vars[i] `*` vars, i /= j]
913 *     | var_i <- vars
914 *   }
915 *
916 */
917
918$func CAV e.vars (e.assigns) (e.delayed) = e.assigns;
919
920$func Get-Vars e = e;
921Get-Vars (e.Re) = (<Vars e.Re>);
922
923Create-Aux-Vars (e.vars) e.splited-Re =
924  <Zip (<Map &Get-Vars (e.splited-Re)>) (e.vars)> :: e.list,
925  <Box> :: s.box,
926  <Box> :: s.provide-i,
927  <Box> :: s.require-i,
928  {
929    e.vars : e1 t.var-i e2,
930      {
931        e.list : e ((e.vars-Re) t.var-j) e,
932          \{
933            t.var-i : t.var-j = <Put s.require-i <And (e1 e2) e.vars-Re>>;
934            e.vars-Re : e t.var-i e = <Put s.provide-i t.var-j>;
935          },
936          $fail;
937        <L <Length e1> e.splited-Re> :: t.Re-i,
938        <Put s.box (t.var-i t.Re-i (<? s.provide-i>) (<? s.require-i>))>,
939          <Store s.provide-i /*empty*/>,
940          <Store s.require-i /*empty*/>;
941      },
942      $fail;;
943  },
944  <CAV <? s.box> (/*assigns*/) (/*delayed*/)>;
945
946
947/*
948 * Если есть переменная, у которой список provide пуст, её можно посчитать.
949 * Это выражается в том, что она (вместе с присваиваемым значением) добавляется
950 * в список assigns, убирается из списка vars, а также из всех списков provide
951 * и delayed.  В списках require её не было.
952 *
953 * CAV Res vars provide require assigns delayed =
954 *   { i | var_i <- vars, provide_i == [] } ->     // Здесь неверно!  На переменные
955 *                                                    из delayed тоже надо смотреть.
956 *       vars    = vars - var_i
957 *       provide = [ provide_j - i | provide_j <- provide ]
958 *       assigns = assigns++[(var_i, Res[i])]
959 *       delayed = [ (var_j, provide_j - i) | (var_j, provide_j) <- delayed ]
960 *       CAV Res vars provide require assigns delayed
961 */
962
963$func Assign-Empty-Provides e.vars  = e.assigns (e.vars);
964
965Assign-Empty-Provides {
966  e1 (t.var-i t.Re-i (/*empty provide_i*/) (e.require-i)) e2 =
967    <Box> :: s.vars,
968    {
969      e1 e2 : e (t.var-j t.Re-j (e.provide-j) (e.require-j)) e,
970        <Put s.vars (t.var-j t.Re-j (<Sub (e.provide-j) t.var-i>) (e.require-j))>,
971        $fail;;
972    },
973    (t.var-i t.Re-i) <Assign-Empty-Provides <? s.vars>>;
974  e.vars = /*empty*/ (e.vars);
975};
976
977
978/*
979 * Если есть переменная, у которой список require пуст, кладём её в delayed.
980 * Она будет посчитана, когда у неё опустеет список provide, т.е. когда не
981 * останется переменных, у которых она в списке require.
982 */
983$func Delay-Empty-Requires e.vars  = e.delayed (e.vars);
984
985Delay-Empty-Requires {
986  e1 t.var e2, t.var : (t.var-i t.Re-i (e.provide-i) (/*empty require_i*/)) =
987    <Delay-Empty-Requires e2> :: e.delayed (e.vars),
988    t.var e.delayed (e1 e.vars);
989  e.vars = /*empty*/ (e.vars);
990};
991
992
993/*
994 * Выбор переменной (из двух) с более длинным списком требуемых ей значений.
995 */
996$func Max-Require e = e;
997
998Max-Require t.arg1 t.arg2 =
999  t.arg1 : (t.var1 t.Re1 t.provide1 (e.require1)),
1000  t.arg2 : (t.var2 t.Re2 t.provide2 (e.require2)),
1001  {
1002    <"<" (<Length e.require1>) (<Length e.require2>)> = t.arg2;
1003    t.arg1;
1004  };
1005
1006
1007/*
1008 * Подставить вспомогательную переменную вместо исходной во всех результатных выражениях.
1009 * Присваивание к исходной переменной убрать (оно к этому моменту уже выполнено).
1010 * Убрать переменную из списков зависимостей.
1011 */
1012$func Subst-Aux-Var e = e;
1013
1014Subst-Aux-Var t.var t.aux (t.v t.Re (e.provide) (e.require)), {
1015  t.var : t.v = /*empty*/;
1016  (
1017    t.v
1018    <Subst (t.var) ((t.aux)) t.Re>
1019    (<Sub (e.provide) t.var>)
1020    (<Sub (e.require) t.var>)
1021  );
1022};
1023
1024
1025/*
1026 * Извлечь присваивание из всей информации о переменной.
1027 */
1028$func Extract-Assigns e = e;
1029Extract-Assigns (t.var t.Re e) = (t.var t.Re);
1030
1031
1032/*
1033 * Основной цикл обработки присваиваний.
1034 *
1035 * 1) Из всех переменных (в том числе и отложенных), от которых больше ничего
1036 *    не зависит, сделать присваивания.
1037 * 2) Все переменные, которые больше ни от чего не зависят, отложить.
1038 * 3) Если осталось хотя бы две неотложенных переменных, выбирать из них ту,
1039 *    которая зависит от наибольшего числа переменных, подставить везде вместо
1040 *    неё вспомогательную, перейти к пункту 1.
1041 */
1042CAV e.vars (e.assigns) (e.delayed) =
1043  <Assign-Empty-Provides e.vars> :: e.new-assigns (e.vars),
1044  e.assigns e.new-assigns <Assign-Empty-Provides e.delayed> :: e.assigns (e.delayed),
1045  e.delayed <Delay-Empty-Requires e.vars> :: e.delayed (e.vars),
1046  {
1047    e.vars : t t e =
1048      <Foldr1 &Max-Require (e.vars)> : (t.var t.Re e),
1049      <Gener-Aux-Var> :: t.aux,
1050      e.assigns (t.aux (t.var)) (t.var t.Re) :: e.assigns,
1051      <Map &Subst-Aux-Var t.var t.aux (e.vars)> :: e.vars,
1052      <Map &Subst-Aux-Var t.var t.aux (e.delayed)> :: e.delayed,
1053      <CAV e.vars (e.assigns) (e.delayed)>;
1054    e.assigns <Map &Extract-Assigns (e.vars e.delayed)>;
1055  };
1056
1057
1058
1059
1060****************** Компиляция сопоставления с образцом *******************
1061
1062Get-Clash-Sequence (e.last-Re) t.Pattern e.Snt =
1063  (/*e.clashes*/) (RESULT e.last-Re) t.Pattern e.Snt $iter {
1064    e.Snt : (RESULT e.Re) (s.dir e.Pe) e.rest =
1065      /*
1066       * Компилируем все константные выражения и заводим в табличке все
1067       * незаведённые переменные.  У старых переменных очищается память
1068       * на предмет клешей, в которых они раньше использовались.
1069       */
1070      <Prepare-Res (e.Re) (e.Pe)> : (e.R1) (e.P1),
1071      <Map &Set-Var- (Clashes /*empty*/) (<Vars e.R1 e.P1>)> : e,
1072      (e.clashes (e.R1) (s.dir e.P1)) e.rest;
1073  } :: (e.clashes) e.Snt,
1074  # \{
1075    e.Snt : \{
1076      (RESULT e.Re) (LEFT e) e = e.Re;
1077      (RESULT e.Re) (RIGHT e) e = e.Re;
1078    } :: e.Re,
1079      <Without-Calls? e.Re>;
1080  } =
1081  (e.clashes) e.Snt;
1082
1083Without-Calls? e.Re =
1084  e.Re $iter {
1085    e.Re : t.Rt e.rest =
1086      t.Rt : {
1087        (CALL e) = $fail;
1088        (BLOCK e) = $fail;
1089        (PAREN e.Re1) = <Without-Calls? e.Re1>;
1090        t.symbol-or-var = /*empty*/;
1091      },
1092      e.rest;
1093  } :: e.Re,
1094  e.Re : /*empty*/;
1095
1096$func CC s.tail? (v.fails) t.end-cycle e.Snt = e.asail-Snt;
1097
1098Comp-Clashes (e.clashes) s.tail? (v.fails) e.Sentence =
1099  <Init-Clashes e.clashes>,
1100  <CC s.tail? (v.fails) <R 0 v.fails> e.Sentence>;
1101
1102$func CC-Known-Lengths t.fail e.idxs = e.conds;
1103
1104$func CC-Compute-Length t.fail t.end-cycle t.idx = e;
1105
1106$func CC-Unknown-Lengths t.fail e.idxs = e.conds;
1107
1108$func CC-Deref t.fail e.actions = e.actions;
1109
1110$func CC-Eqs t.fail (e.assigns) e.eqs = e.actions;
1111
1112CC s.tail? (v.fails) t.end-cycle e.Snt, {
1113  <Domain &Known-Lengths> : v.clashes =
1114    <CC-Known-Lengths t.end-cycle v.clashes>
1115    <CC s.tail? (v.fails) t.end-cycle e.Snt>;
1116  <Domain &Compute-Length> : (t.clash) e =
1117    <CC-Compute-Length <R 0 v.fails> t.end-cycle t.clash>
1118    <CC s.tail? (v.fails) t.end-cycle e.Snt>;
1119  <Domain &Unknown-Lengths> : e.clashes =
1120    <CC-Unknown-Lengths t.end-cycle e.clashes> :: e.conds,
1121    /*
1122     * Когда мы добрались до сюда, все условия на длины на текущем уровне
1123     * выписаны.  Невыполнение любого из оставшихся условий (на
1124     * соответствие типов, равенство, длины внутри скобок) ведёт не к
1125     * прекращению текущего цикла, а переход к его следующей итерации.
1126     * Поэтому в качестве t.end-cycle везде дальше подставляется текущий
1127     * откат.
1128     */
1129    <Update-Hard-Parts> : {
1130      v.actions =
1131        e.conds <CC-Deref <R 0 v.fails> v.actions>
1132        <CC s.tail? (v.fails) <R 0 v.fails> e.Snt>;
1133      /*empty*/ =
1134        e.conds <CC-Eqs <R 0 v.fails> () <? &Eqs>> :: e.actions,
1135        <Store &Eqs /*empty*/>,
1136        {
1137          <Compose-Source> :: e.assign =
1138            e.actions <CC-Eqs <R 0 v.fails> () e.assign>
1139            <CC s.tail? (v.fails) <R 0 v.fails> e.Snt>;
1140          {
1141            <Get-Cycle> :: s.split (e.left) (e.right) (e.len)
1142                    t.var t.l-var t.r-var =
1143              {
1144                e.left : 0, e.right : 0 = /*empty*/ t.var;
1145                <Gener-Vars ((VAR)) "subexpr_" t.var> : t.sub-var,
1146                  (SUBEXPR t.sub-var t.var (e.left)
1147                    ((INFIX "-" (e.len) (e.left e.right))))
1148                  t.sub-var;
1149              } :: e.subexpr t.var,
1150              {
1151                s.split : RSPLIT =
1152                  t.r-var t.l-var DEC-ITER;
1153                t.l-var t.r-var INC-ITER;
1154              } :: t.l-var t.r-var s.iter-op,
1155              <Gener-Label "continue"> :: t.cont-label,
1156              <Gener-Label "exit"> :: t.break-label,
1157              e.actions e.subexpr
1158              (s.split t.var (<Get-Var Min t.l-var>) t.l-var t.r-var)
1159              (FOR (t.cont-label) (t.break-label) () ((s.iter-op t.var))
1160                (IF ((NOT (CHECK-ITER t.var))) <Concat <R 0 v.fails>>)
1161                <CC s.tail?     (v.fails ((CONTINUE t.cont-label)))
1162                  <R 0 v.fails> e.Snt>
1163                (BREAK t.break-label)
1164              );
1165            e.actions <Comp-Sentence s.tail? (v.fails) () e.Snt>;
1166          };
1167        };
1168    };
1169};
1170
1171CC-Known-Lengths (e.fail) e.idxs, {
1172  e.idxs : (t.idx) e.rest =
1173    <Put &Checked-Lengths t.idx>,
1174    <Lookup &Known-Lengths t.idx> : (e.len-Re) (e.len-Pe),
1175    (IF ((INFIX "!=" (e.len-Re) (e.len-Pe))) e.fail)
1176    <CC-Known-Lengths (e.fail) e.rest>;
1177  <RFP-Clear-Table &Known-Lengths>;
1178};
1179
1180CC-Compute-Length (e.fail) (e.end-cycle) t.idx =
1181  <Lookup &Compute-Length t.idx> : t.var s.mult (e.minuend) (e.subtrahend),
1182  <Get-Var Min t.var> :: e.min,
1183  {
1184    t.var : (Len-Var e) =
1185      <Unbind &Compute-Length t.idx>,
1186      (IF ((INFIX "<" (e.minuend)
1187          ((INFIX "+" (e.subtrahend)
1188            ((INFIX "*" (e.min) (s.mult)))
1189        ))      ))
1190        e.end-cycle
1191      );
1192    <Create-Int-Var ("len") Aux e.minuend> :: t.m-var e.m-assign,
1193      <Create-Int-Var ("len") Aux e.subtrahend> :: t.s-var e.s-assign,
1194      ((INFIX "<" (t.m-var)
1195        ((INFIX "+" (t.s-var)
1196              ((INFIX "*" (e.min) (s.mult)))
1197        ))                      )) :: e.min-cond,
1198      <Get-Var Max t.var> : {
1199        /*empty*/;
1200        e.max =
1201          ((INFIX ">" (t.m-var)
1202            ((INFIX "+" (t.s-var)
1203                  ((INFIX "*" (e.max) (s.mult)))
1204          ))                    ));
1205      } :: e.max-cond,
1206      (INFIX "%" ((INFIX "-" (t.m-var) (t.s-var))) (s.mult)) :: e.div-cond,
1207      <Create-Int-Var ("len_") t.var
1208        (INFIX "/" ((INFIX "-" (t.m-var) (t.s-var))) (s.mult))
1209      > :: t.len-var e.len-assign,
1210      <Set-Var (Length t.len-var) t.var>,
1211      <Unbind &Compute-Length t.idx>,
1212      <Put &Checked-Lengths t.idx>,
1213      <Get-Var Clashes t.var> :: e.clashes,
1214      <Map &Reclassify-Clash (<Sub (e.clashes) <? &Checked-Lengths>>)> : e,
1215      e.m-assign e.s-assign
1216      (IF ((INFIX "||" e.min-cond e.max-cond)) e.end-cycle)
1217      (IF (e.div-cond) e.fail)
1218      e.len-assign;
1219  };
1220
1221$func  Get-Min e = e;
1222
1223$func? Get-Max e = e;
1224
1225CC-Unknown-Lengths (e.fail) e.idxs, {
1226  e.idxs : (t.idx) e.rest =
1227    <Lookup &Unknown-Lengths t.idx> : (e.len-Re) (e.len-Pe) (e.vars-Re) (e.vars-Pe),
1228    {
1229      <Get-Max e.vars-Re> :: e.max =
1230        <Get-Min e.vars-Pe> :: e.min,
1231        ((INFIX "<" (e.len-Re e.max) (e.len-Pe e.min)));
1232      /*empty*/;
1233    } :: e.cond1,
1234    {
1235      <Get-Max e.vars-Pe> :: e.max =
1236        <Get-Min e.vars-Re> :: e.min,
1237        ((INFIX ">" (e.len-Re e.min) (e.len-Pe e.max)));
1238      /*empty*/;
1239    } :: e.cond2,
1240    {
1241      e.cond1 : /*empty*/, e.cond2 : /*empty*/ = /*empty*/;
1242      (IF ((INFIX "||" e.cond1 e.cond2)) e.fail);
1243    } :: e.cond,
1244    e.cond
1245    <CC-Unknown-Lengths (e.fail) e.rest>;
1246  <RFP-Clear-Table &Unknown-Lengths>;
1247};
1248
1249Get-Min
1250{
1251  t.var e.vars = <Get-Var Min t.var> <Get-Min e.vars>;
1252  /*empty*/ = /*empty*/;
1253};
1254
1255Get-Max
1256{
1257  t.var e.vars = <Get-Var Max t.var> : v.max, v.max <Get-Max e.vars>;
1258  /*empty*/ = /*empty*/;
1259};
1260
1261$func Pos (e.Re) s.dir e.pos = e.pos;
1262
1263Pos {
1264  (e.Re) RIGHT e.pos = (INFIX "-" ((LENGTH e.Re)) (1) (e.pos));
1265  (e.Re) LEFT  e.pos = e.pos;
1266};
1267
1268/*
1269 * Информацию о проверках и заведении переменных, необходимых для создания
1270 * клешей из содержимого скобок, кодируем на ASAIL.
1271 */
1272CC-Deref (e.fail) e.actions, e.actions : {
1273  (SYMBOL? e.Re (s.dir e.pos)) e.rest =
1274    (IF ((SYMBOL? e.Re (<Pos (e.Re) s.dir e.pos>))) e.fail)
1275    <CC-Deref (e.fail) e.rest>;
1276  (DEREF t.var e.Re (s.dir e.pos)) e.rest =
1277    (DEREF t.var e.Re (<Pos (e.Re) s.dir e.pos>))
1278    <CC-Deref (e.fail) e.rest>;
1279  /*empty*/ = /*empty*/;
1280};
1281
1282CC-Eqs (e.fail) (e.assigns) e.eqs, {
1283  e.eqs : ((e.Re) (s.dir e.pos) t.Pt (e.len)) e.rest =
1284    {
1285      e.Re : t,
1286        <Get-Known-Length e.Re> : e.len (), // FIXME: здесь надо использовать
1287                          //        калькулятор
1288        s.dir e.pos : \{
1289          LEFT 0;
1290          RIGHT e.len;
1291        } =
1292        e.Re;;
1293    } :: e.Re-term,
1294    {
1295      e.len : 1 = TERM-EQ;      // FIXME: здесь надо использовать
1296                  //        калькулятор
1297      EQ;
1298    } :: s.eq,
1299    <Pos (e.Re) s.dir e.pos> :: e.pos,
1300    {
1301      \{
1302        <Get-Var Instantiated? t.Pt> : True = t.Pt (e.Re);
1303        t.Pt : \{
1304          (REF e);
1305          (STATIC e);
1306        }, {
1307          <Var? e.Re-term> = e.Re-term (t.Pt);
1308          t.Pt (e.Re);
1309        };
1310      } :: el (er),
1311        (IF ((NOT (s.eq el (er) (e.pos)))) e.fail) :: t.cond,
1312        {
1313          /*
1314           * Мы предполагаем, что во всех пришедших e.eqs все e.Re
1315           * уже были определены ранее.
1316           */
1317          e.assigns : $r e1 (s.op t.Pt e.def) e2 =
1318            <CC-Eqs (e.fail) (e1 (s.op t.Pt e.def) t.cond e2) e.rest>;
1319          t.cond <CC-Eqs (e.fail) (e.assigns) e.rest>;
1320        };
1321      <Set-Var (Instantiated? True) t.Pt>,
1322        {
1323          t.Pt : (SVAR e) =
1324            (IF
1325              ((NOT (SYMBOL? e.Re (<Pos (e.Re) s.dir e.pos>))))
1326              e.fail
1327            );;
1328        } :: e.cond,
1329        {
1330          <Get-Var Decl t.Pt> : s =
1331            e.cond <CC-Eqs (e.fail) (e.assigns
1332              (ASSIGN t.Pt (SUBEXPR e.Re (e.pos) (e.len))))
1333              e.rest>;
1334          <Vars-Decl Expr t.Pt> : e,
1335            e.cond <CC-Eqs (e.fail) (e.assigns
1336              (SUBEXPR t.Pt e.Re (e.pos) (e.len))) e.rest>;
1337        };
1338    };
1339  e.assigns e.eqs;
1340};
1341
1342
1343
1344
1345Gener-Label e.QualifiedName =
1346  {
1347    <Lookup &Labels e.QualifiedName> : s.num,
1348      <"+" s.num 1>;
1349    1;
1350  } :: s.num,
1351  <Bind &Labels (e.QualifiedName) (s.num)>,
1352  (e.QualifiedName s.num);
1353
1354Add-To-Label (e.label) e.name = <Gener-Label e.label "_" e.name>;
1355
1356
1357
1358
1359Lookup-Func t.Fname, \{
1360  <Lookup &Fun t.Fname>;
1361  <Lookup &Fun? t.Fname>;
1362} : s.linkage s.tag t.pragma (e.Fin) (e.Fout) =
1363  s.linkage s.tag t.pragma (e.Fin) (e.Fout);
1364
Note: See TracBrowser for help on using the repository browser.