source: to-imperative/trunk/compiler/rfp_compile.rf @ 2043

Last change on this file since 2043 was 2043, checked in by orlov, 14 years ago
  • Improved block extraction from result expressions.
  • Use asail2asail when converting to C++.
  • Remove duplicate declarations after cleanup of blocks

(rfp_asail2asail.Remove-Dupl-Decl).

  • Proper generation of debug info for $iter.
  • Fixed pragma-generation when comments are used.
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 43.5 KB
Line 
1// $Source$
2// $Revision: 2043 $
3// $Date: 2006-08-01 17:25:13 +0000 (Tue, 01 Aug 2006) $
4
5$use "rfpc";
6$use "rfp_helper";
7$use "rfp_check";
8$use "rfp_as2as";
9$use "rfp_format";
10$use "rfp_vars";
11$use "rfp_const";
12$use "rfp_clashes";
13
14$use StdIO;
15$use Table;
16$use Box;
17$use Arithm;
18$use Access;
19$use Compare;
20$use Convert;
21$use Class;
22$use Apply;
23$use Dos;
24$use List;
25
26
27/*
28 * Table for storing object names.
29 */
30$table Objects;
31
32/*
33 * Table for storing parameters of referenced functions.
34 */
35$table Stub-Funcs;
36
37/*
38 * Box for storing function out format
39 */
40$box Out-Format;
41
42/*
43 * Box for storing names for function result variables
44 */
45$box Res-Vars;
46
47/*
48 * Following table is used by Gener-Label function for obtaining unical (for
49 * certain function) label name.
50 * e.Key ::= e.QualifiedName      (parameter given to Gener-Label)
51 * e.Val ::= [Int]          (last index used with such e.QualifiedName)
52 */
53$table Labels;
54
55/*
56 * Table for storing variables used in place of preprocessor-generated ones.
57 */
58$table Prep-Vars;
59
60
61$func Compile (e.targets) (e.headers) e.Items = e.Compiled-Items (INTERFACE e.headers);
62
63$func Comp-Func-Stubs = e.asail-funcs;
64
65$func Comp-Func s.tag t.name e.params-and-body = e.compiled-func;
66
67$func Set-Drops (e.declared-exprs) e.comp-func = (e.declared-exprs) e.result-func;
68
69$func Comp-Sentence e.Sentence = e.asail-sentence;
70
71$func Save-Snt-State = ;
72
73$func Recall-Snt-State = ;
74
75$func Pop-Snt-State = ;
76
77$func Extract-Calls e.Re = (e.last-Re) e.calls;
78
79$func Get-Clash-Sequence (e.last-Re) e.Snt = (e.clashes) e.rest-of-the-Sentence;
80
81$func? Without-Calls? e.Re = ;
82
83$func Comp-Clashes (e.clashes) s.tail? (v.fails) e.Sentence = e.asail-sentence;
84
85$func Gener-Label e.QualifiedName = t.label;
86
87$func Add-To-Label t.label e.name = t.label;
88
89$func Comp-Calls e.Re = e.calls;
90
91$func Prepare-Vars e.vars = e.vars;
92
93$func Prepare-Res e.Reult-exprs = e.Result-exprs;
94
95$func Comp-Assigns e.assignments = e.asail-assignments;
96
97$func Comp-Format (e.last-Re) e.He = e.assignments;
98
99
100
101************ Get AS-Items and targets, and pass it to Compile ************
102
103/*
104 * Ящик для объявлений статических функций, констант и объектов.  Все они
105 * выписываются в самом начале тела модуля.
106 */
107$box Declarations;
108
109$box Trace-Names;
110
111$table Includes;
112
113RFP-Compile e.Items =
114  { <Lookup &RFP-Options ITEMS>;; } :: e.targets,
115  <RFP-Clear-Table &Stub-Funcs>,
116  <RFP-Clear-Table &Includes>,
117  <Store &Trace-Names /*empty*/>,
118  <Store &Declarations /*empty*/>,
119  <Init-Consts>,
120  <Compile (e.targets) () e.Items> :: e.Items t.Interface,
121  <Comp-Func-Stubs> :: e.stub-funcs,
122  t.Interface
123  (MODULE <Domain &Includes> <? &Trace-Names> <? &Declarations> <Comp-Consts> e.Items e.stub-funcs);
124
125
126
127****************** Choose needed items and compile them ******************
128
129Compile (e.targets) (e.headers) e.Items, {
130  e.Items : e t.item e.rest,
131    {
132      e.targets : v =
133        e.targets : e t.name e,
134        t.item : (t t t t.name e);;
135    },
136    t.item : {
137      (IMPORT s.tag t.pragma t.name e) =
138        {
139          t.pragma : (PRAGMA e (FILE e.fname) e) =
140            <RFP-Extract-Qualifiers t.name> :: (e.mod-name) e,
141            <Bind &Includes (INPUT (e.mod-name) e.fname) ()>;;
142        },
143        () /*empty*/;
144      (TRACE t.name) =
145        <Put &Trace-Names (TRACE t.name)>,
146        () /*empty*/;
147      (EXTERN t.pragma t.name) =
148        <Put &Declarations (EXTERN t.name)>,
149        () /*empty*/;
150      (s.link s.tag t.pragma t.name (e.in) (e.out) e.body), FUNC FUNC? TFUNC : e s.tag e =
151        {
152          <? &Declarations> : $r e (s t.name) e = /*empty*/;
153          (DECL-FUNC t.name);
154        } :: e.decl,
155        <Put &Declarations e.decl>,
156        {
157          s.link : EXPORT = e.decl;
158           /*empty*/;
159        } :: e.decl,
160        {
161          e.body : (BRANCH t.p e.branch) =
162            <Comp-Func s.tag t.name <Del-Pragmas (e.in) (e.out) e.branch>>;;
163        } :: e.comp-func,
164        (e.decl) e.comp-func;
165      (s.link CONST t.pragma t.name e.expr) =
166        (CONSTEXPR s.link t.name (e.expr) e.expr) :: t.const,
167        <Put &Declarations t.const>,
168        {
169          s.link : EXPORT = ((DECL-OBJ t.name)) /*empty*/;
170          () /*empty*/;
171        };
172      (EXPORT s.tag t.pragma t.name) =
173        <Put &Declarations (OBJ EXPORT s.tag t.name)>,
174        ((DECL-OBJ t.name)) /*empty*/;
175      (LOCAL  s.tag t.pragma t.name) =
176        <Put &Declarations (OBJ LOCAL s.tag t.name)>,
177        () /*empty*/;
178    } :: (e.decl) e.item =
179    e.item <Compile (e.targets) (e.headers e.decl) e.rest>;
180  /*<Comp-Func-Stubs>*/ (INTERFACE e.headers);
181};
182
183
184
185$func Gener-Stub e = e;
186
187/*
188 * For each referenced function generate a stub one with format e = e.
189 */
190Comp-Func-Stubs = <Map &Gener-Stub (<Domain &Stub-Funcs>)>;
191
192Gener-Stub (t.name) =
193  <Lookup &Stub-Funcs t.name> : t.stub-name s.tag (e.Fin) (e.Fout),
194  <Put &Declarations (DECL-FUNC t.stub-name)>,
195  <Gener-Vars (e.Fin) "stub"> :: e.He,
196  <Comp-Func STUB t.stub-name ((EVAR ("arg" 1))) ((EVAR))
197    (LEFT e.He) (CUTALL) (RESULT (CALL t.name e.He))>;
198
199
200
201Comp-Func s.tag t.name (e.in) (e.out) e.Sentence =
202  <RFP-Clear-Table &Labels>,
203  <RFP-Clear-Table &Prep-Vars>,
204  <Init-Vars>,
205  <Vars <Gener-Vars (e.out) "res">> :: e.res-vars,
206  <Vars-Decl Result e.res-vars> : e,
207  <Store &Res-Vars e.res-vars>,
208  <Store &Out-Format <Format-Exp e.out>>,
209  <Prepare-Res (e.in)> : (e.arg),
210  <Vars e.arg> :: e.arg-vars,
211  <Map &Set-Var (Instantiated? True) (e.arg-vars)> : e,
212  s.tag : {
213    FUNC = FUNC (FATAL);
214    FUNC? = FUNC? (RETFAIL);
215    TFUNC = TFUNC (FATAL);
216    STUB =
217      <Prepare-Res (Apply Apply "Unexpected fail")> : (e.message),
218      FUNC? (RETFAIL) ((ERROR e.message));
219  } :: s.tag e.fails,
220  (s.tag t.name (<Vars-Print e.arg-vars>) (<Vars-Print e.res-vars>)
221    <Comp-Sentence Tail (e.fails) (e.arg) e.Sentence>
222  ) :: e.comp-func,
223*       <Set-Drops () <Gener-Var-Names e.comp-func>> :: t e.comp-func,
224  <Gener-Var-Names e.comp-func> :: e.comp-func,
225//!     <Post-Comp (e.res-vars) e.comp-func> :: t e.result,
226//!     e.result;
227  e.comp-func;
228//  :: (e.func-decl) e.func-body,
229//  () <Domain &Declarations> $iter {
230//    e.vars : (t.var) e.rest-vars,
231//      (e.var-decls (DECL t.var)) e.rest-vars;
232//  } :: (e.var-decls) e.vars,
233//  e.vars : /*empty*/,
234//  (e.func-decl e.var-decls e.func-body);
235
236Set-Drops (e.declared) e.comp-func =
237  e.comp-func () (e.declared) $iter {
238    e.comp-func : t.first e.rest, {
239      t.first : \{
240        (EXPR t.var e) = (DROP t.var) (t.first) t.var Init;
241        (DEREF t.var e) = (DROP t.var) (t.first) t.var Init;
242        (SUBEXPR t.var e) = (DROP t.var) (t.first) t.var Init;
243        (DECL Expr t.var) = (DROP t.var) () t.var Decl;
244        (DECL "int" t.var) = /*empty*/ () t.var Decl;
245      } :: e.drop (e.constr) t.var s.init,
246        {
247          e.declared : e1 t.var s.old-init e2, s.old-init : {
248            Init, {
249              t.var : (VAR ("const" e)) =
250                e.rest (e.result-func) (e.declared);
251              e.rest (e.result-func e.drop e.constr) (e.declared);
252            };
253            Decl, s.init : {
254              Decl =
255                e.rest (e.result-func) (e.declared);
256              Init =
257                t.first : (s.method t.var e.args),
258                e.rest (e.result-func (ASSIGN t.var (s.method e.args)))
259                (e1 e2 t.var s.init);
260                /*
261                 * FIXME: if s.method is EXPR, it shouldn't be written.
262                 */
263            };
264          };
265          e.rest (e.result-func t.first) (e.declared t.var s.init);
266        };
267      t.first : (LABEL (t.label) e.expr) =
268        <Set-Drops (e.declared) e.expr> :: (e.declared) e.expr,
269        e.rest (e.result-func (LABEL (t.label) e.expr)) (e.declared);
270      t.first : (e.expr) =
271        <Set-Drops (e.declared) e.expr> :: t e.expr,
272        e.rest (e.result-func (e.expr)) (e.declared);
273      t.first : s.symbol =
274        e.rest (e.result-func s.symbol) (e.declared);
275    };
276  } :: e.comp-func (e.result-func) (e.declared),
277  e.comp-func : /*empty*/ =
278  (e.declared) e.result-func;
279
280
281Comp-Sentence s.tail? (v.fails) (e.last-Re) e.Sentence, e.Sentence : {
282
283  /*empty*/ = /*empty*/;
284
285  /*
286   * In case of Re look if we should do a tailcall.  If not, then compile
287   * function calls from the Re and assign results to the out parameters or
288   * use them in compilation of the rest of the sentence.
289   */
290  (RESULT e.Re) e.Snt =
291    {
292      /*
293       * If the Re is the last action in the sentence then we can do
294       * tailcall if one of the following is true:
295       *  - Re is a call of non-failable function;
296       *  - Re is a call of a failable function, current function is
297       *  failable, and the failures stack is empty.
298       * In both cases out format of the called function should coincide
299       * with those of compiled one.
300       * FIXME: really we can do tailcall if all the parameters of
301       * compiled function that won't get their values from the call can
302       * be assigned from other sources.  Some support from runtime is
303       * needed though.
304       */
305      e.Snt : /*empty*/, s.tail? : Tail, e.Re : (CALL t.name e.arg),
306        {
307          <In-Table? &Fun? t.name> =
308            v.fails : (RETFAIL),
309            TAILCALL?;
310          TAILCALL;
311        } :: s.tailcall,
312        <Lookup-Func t.name> :: s.linkage s.tag t.pragma (e.Fin) (e.Fout),
313        <Subformat? (e.Fout) (<? &Out-Format>)> =
314        <Extract-Calls e.arg> :: (e.last-Re) e.calls,
315        <Prepare-Res <Split-Re (e.Fin) e.last-Re>> :: e.splited-Re,
316        <Comp-Calls <R 0 v.fails> e.calls>
317        (s.tailcall t.name (e.splited-Re) (<? &Res-Vars>));
318
319      <Extract-Calls e.Re> :: (e.last-Re) e.calls,
320        <Comp-Calls <R 0 v.fails> e.calls> :: e.comp-calls,
321        {
322          e.Snt : /*empty*/, Tail Tail-in-Trap : e s.tail? e =
323            <Split-Re (<? &Out-Format>) e.last-Re> :: e.splited-Re,
324            <Prepare-Res e.splited-Re> :: e.splited-Re,
325            e.comp-calls <Comp-Assigns <Zip (<? &Res-Vars>) (e.splited-Re)>>;
326
327          e.comp-calls <Comp-Sentence s.tail? (v.fails) (e.last-Re) e.Snt>;
328        };
329    };
330
331  /*
332   * In case of He compile assignments from last Re and then (with new state
333   * of variables) proceed with the rest of the sentence.
334   */
335  (FORMAT e.He) e.Snt =
336    <Comp-Format (e.last-Re) e.He>
337    <Comp-Sentence s.tail? (v.fails) () e.Snt>;
338
339  /*
340   * In case of Pe get from the begining of the sentence a maximum possible
341   * sequence of clashes and compile it.  New values of variables from the
342   * clashes use in the compilation of the rest of the sentence.
343   */
344  (s.dir e.Pattern) e.Snt, s.dir : \{ LEFT; RIGHT; } =
345    <Get-Clash-Sequence (e.last-Re) e.Sentence> :: (e.clashes) e.Sentence,
346    <Comp-Clashes (e.clashes) s.tail? (v.fails) e.Sentence>;
347
348  (s.block) e, BLOCK BLOCK? : e s.block e = <WriteLN! &StdErr "Empty block?">, $fail;
349
350  /*
351   * In case of a block first see if its results are needed for something
352   * after the block and determine whether the block is a source.  Then
353   * compile each branch in turn.
354   */
355  (s.block e.branches) e.Snt,
356    s.block : \{
357      BLOCK = (FATAL);
358      BLOCK?;
359    } :: e.fatal? =
360    /*
361     * If the block initializes an $iter then extract from the $iter the He
362     * for placing it in the end of each branch.
363     * Then look if the block is used by a format expression.
364     * If so, we should declare variables from that expression before
365     * entering any branch -- those should be visible after the block.
366     * The format expression is placed in the end of each branch.
367     * But if a branch computes to $error, the expression shouldn't be
368     * used, so protect it with (Comp If-not-error).
369     * If next after the block is (Comp Error) then block results should be
370     * used as values for $error, so place (Comp Error) in the end of each
371     * branch.
372     * If next after the block is (Comp If-not-error) then our block is in
373     * the end of a branch of an outer block and has next pattern or format
374     * inherited from there.  In that case we should place all the sentence
375     * rest in the end of each branch because the block can be inside the
376     * $error already.
377     */
378    {
379      e.Snt : (ITER t.body t.format t.cond) e.rest =
380        t.format (Comp Iter t.body t.format t.cond) e.rest;
381      e.Snt;
382    } :: e.Snt,
383    e.Snt : {
384      (FORMAT e.format) e.rest =
385        <Prepare-Vars <Vars e.format>> :: e.vars,
386        (e.vars) ((Comp If-not-error) (FORMAT e.format))
387        ((Comp Source)) e.rest;
388      (Comp Error) e.rest =
389        () ((Comp Error)) () /*empty*/;
390      (Comp If-not-error) e.rest =
391        () (e.Snt) () /*empty*/;
392      e = () () () e.Snt;
393    } :: (e.out-vars) (e.next-terms) (e.source?) e.Snt,
394    /*
395     * The block is a source if after it goes format expression
396     * (in that case e.source? isn't empty) or e.Snt isn't empty.
397     * Branches in the block are tail sentences if the current sentence is
398     * tail and the block isn't a source.
399     */
400    {
401      \{ e.source? : v; e.Snt : v; } = ((Comp Source) <R 0 v.fails>) Notail;
402      () s.tail?;
403    } :: (e.source?) s.tail-branch?,
404    /*
405     * In case our block is a source we should mark the position in the
406     * failures stack, so that we can jump to it after CUTALL.  And if our
407     * block isn't failable we should add (FATAL) to the end of the stack.
408     */
409    v.fails e.source? e.fatal? :: v.branch-fails,
410    /*
411     * Before compile the branches mark all out-vars as declared.
412     */
413    <Vars-Decl Expr e.out-vars> :: e.decls,
414    /*
415     * We put all compiled branches in a block, so positive return from a
416     * branch is a break from that block.
417     * Each branch in its turn is placed in its own block, so for a $fail
418     * to the next branch we should just break from that inner block.
419     * Each branch is compiled with the current sentence state and the
420     * state is recalled after that.  When all branches are compiled the
421     * state is popped out from the stack.
422     * If last branch fails then the whole block fails, and return from the
423     * last branch is return from the block.  So the last branch isn't
424     * placed in a block and is processed with the failures stack that was
425     * before entering the block.  Note: this trick helps us find more
426     * tailcalls.  If the call of a failable function is on the last branch
427     * of the block and the failures stack is empty we can do tailcall.
428     * When the last branch is compiled with the block's stack, all we
429     * should do is to check it.
430     */
431    <Gener-Label "block"> :: t.label,
432    <Save-Snt-State>,
433    (e.branches) /*e.comp-branches*/ $iter {
434      e.branches : (BRANCH e.branch) e.rest-br =
435        <Add-To-Label t.label "branch"> :: t.br-label,
436        <Comp-Sentence
437          s.tail-branch?
438          (v.branch-fails ((BREAK t.br-label)))
439          (e.last-Re)
440          e.branch e.next-terms
441        > :: e.comp-br,
442        <Recall-Snt-State>,
443        (e.rest-br) e.comp-branches (LABEL (t.br-label) e.comp-br (BREAK t.label));
444    } :: (e.branches) e.comp-branches,
445    e.branches : (BRANCH e.branch) =
446    <Comp-Sentence
447      s.tail-branch? (v.branch-fails) (e.last-Re) e.branch e.next-terms
448    > :: e.last-branch,
449    <Pop-Snt-State>,
450    <Vars-Reset e.out-vars>,
451    e.decls (LABEL (t.label) e.comp-branches e.last-branch)
452    <Comp-Sentence s.tail? (v.fails) () e.Snt>;
453
454  /*
455   * In case of $iter first of all compile initial assignment to the hard
456   * expression.
457   */
458  (ITER t.body t.format t.cond) e.Snt =
459    <Comp-Sentence s.tail? (v.fails) (e.last-Re)
460      t.format (Comp Iter t.body t.format t.cond) e.Snt
461    >;
462
463  /*
464   * Before compiling $iter condition or body we should forget available info
465   * about all format variables, because that info can be changed during
466   * cycle iterations.
467   * Then compile $iter condition and body both with the current state of the
468   * sentence.
469   * e.Snt can contain (Comp Error) and (protected from errors) pattern or
470   * format which comes from an outer block, so compile it together with the
471   * condition.
472   * If condition fails we should compute the body, so put the compiled
473   * condition in a block and place a break from it to the failures stack.
474   */
475  (Comp Iter (BRANCH e.body) t.format (BRANCH e.condition)) e.Snt =
476    t.format : (FORMAT e.Fe),
477    <Vars-Reset <Prepare-Vars <Vars e.Fe>>>,
478    <Save-Snt-State>,
479    <Gener-Label "iter"> :: t.label,
480    <Gener-Label "exit_iter"> :: t.exit,
481    <Comp-Sentence s.tail? (v.fails ((BREAK t.label))) () e.condition e.Snt>
482      :: e.comp-condition,
483    <Pop-Snt-State>,
484    <Comp-Sentence Notail (v.fails) () e.body t.format> :: e.comp-body,
485    (FOR (/*cont-label*/) (t.exit) () ()
486      (LABEL (t.label) e.comp-condition (BREAK t.exit)) e.comp-body
487    );
488
489  /*
490   * In case of $trap/$with at first compile try-sentence.  All $fails from
491   * it should become errors.
492   * Then recall the state of the sentence and compile catching of an error
493   * with a variable err.
494   * e.Snt can contain (Comp Error) and (protected from errors) pattern or
495   * format which comes from an outer block, so compile it together with both
496   * sentences.
497   */
498  (TRY (BRANCH e.try) e.catch) e.Snt =
499    <Save-Snt-State>,
500    {
501      s.tail? : Tail = Tail-in-Trap;
502      s.tail?;
503    } :: s.tail-in-trap?,
504    <Comp-Sentence s.tail-in-trap? ((FATAL)) () e.try e.Snt> :: e.comp-try,
505    <Pop-Snt-State>,
506    <Gener-Err-Var> :: t.var,
507    <Set-Var (Instantiated? True) t.var>,
508    <Comp-Sentence s.tail? (v.fails) (t.var) e.catch e.Snt> :: e.comp-catch,
509    (TRY e.comp-try) (CATCH-ERROR e.comp-catch);
510
511  /*
512   * In case of \? add Stake to the failures stack.  Add last fail after it
513   * for <R 0 v.fails> continue to work.
514   */
515  (STAKE) e.Snt =
516    <Comp-Sentence s.tail? (v.fails (Comp Stake) <R 0 v.fails>) () e.Snt>;
517
518  /*
519   * In case of \! forget all failure catchers after last \?.
520   * If there is no Stake then we are inside negation or error (we assume the
521   * program is correct).  So the right failure catcher is in the bottom of
522   * the stack.
523   */
524  (CUT) e.Snt =
525    {
526      v.fails : $r v.earlier-fails (Comp Stake) e = v.earlier-fails;
527      <L 0 v.fails>;
528    } :: v.fails,
529    <Comp-Sentence s.tail? (v.fails) () e.Snt>;
530
531  /*
532   * In case of = clear the failures stack up to the closest source.
533   * Don't clear last fail after it for <R 0 v.fails> continue to work.
534   */
535  (CUTALL) e.Snt =
536    {
537      v.fails : $r v.earlier-fails (Comp Source) t.fail e =
538        v.earlier-fails (Comp Source) t.fail;
539      <L 0 v.fails>;
540    } :: v.fails,
541    <Comp-Sentence s.tail? (v.fails) () e.Snt>;
542
543  /*
544   * In case of = in the Refal-6 sense (non-transparent hedge for the fails),
545   * $fail(k) should become $error(Fname "Unexpected fail"), so clear the
546   * failures stack and put that value in it.
547   */
548  NOFAIL e.Snt =
549    <Comp-Sentence s.tail? ((FATAL)) (e.last-Re) e.Snt>;
550
551  /*
552   * In case of $fail return last failure catcher.
553   */
554  (FAIL) e.Snt =
555    v.fails : e (e.last-fail),
556    e.last-fail;
557
558  /*
559   * In case of # we should proceed with the rest if the source is computed
560   * to $fail.
561   * We could compile the rest of the sentence and place it in the
562   * failures stack.  But then the compiled sentence would be copied as many
563   * times as there are $fail's to the upper level in the source.  So we
564   * place compiled source in the block and put the break to exit from it in
565   * the stack.
566   * When compiling the source mark it as Notail as usual.
567   * If the source isn't computed to $fail we should proceed with the last
568   * failure catcher.
569   */
570  (NOT (BRANCH e.branch)) e.Snt =
571    <Gener-Label "negation"> :: t.label,
572    v.fails : e (e.last-fail),
573//    <Save-Snt-State>,
574    <Comp-Sentence Notail (((BREAK t.label))) () e.branch> e.last-fail
575      :: e.comp-negation,
576//    <Pop-Snt-State>,
577    (LABEL (t.label) e.comp-negation) <Comp-Sentence s.tail? (v.fails) () e.Snt>;
578
579  /*
580   * In case of $error all fails become $error(Fname "Unexpected fail").  So
581   * place that value in the failures stack and then compile the computation
582   * of the rest of the sentence and the last Re which should be the value of
583   * $error.
584   */
585  (ERROR) e.Snt =
586    <Comp-Sentence Notail ((FATAL)) () e.Snt (Comp Error)>;
587
588  (Comp Error) e.Snt =
589    <Prepare-Res (e.last-Re)> : (e.Re),
590    (ERROR e.Re);
591
592  /*
593   * Protection mark to be used between source and tail.  If there is $error
594   * construction somewhere in the source then the tail shouldn't be
595   * computed, but instead the source value should be used for throwing.
596   */
597  (Comp If-not-error) e.Snt =
598    {
599      e.Snt : e (Comp Error) =
600        <Comp-Sentence s.tail? (v.fails) (e.last-Re) (Comp Error)>;
601      <Comp-Sentence s.tail? (v.fails) (e.last-Re) e.Snt>;
602    };
603
604//  (Comp Fatal) = FATAL;
605
606//  (Comp Retfail) = RETFAIL;
607
608};
609
610
611
612********** Sentence state stack and functions for work with it. **********
613
614$box Snt-State;
615
616/*
617 * Put current state in the stack.
618 */
619Save-Snt-State = <Put &Snt-State <Vars-Copy-State>>;
620
621/*
622 * Set current state to that at the top of the stack.
623 */
624Recall-Snt-State = <Vars-Set-State <R 0 <? &Snt-State>>>;
625
626/*
627 * Pop the top from the stack and set current state to it.
628 */
629Pop-Snt-State =
630  <Recall-Snt-State>,
631  <Store &Snt-State <Middle 0 1 <? &Snt-State>>>;
632
633
634
635********************** Function calls compilation. ***********************
636
637/*
638 * $func Extract-Calls e.Re = (e.last-Re) e.calls;
639 *
640 *
641 *
642 */
643Extract-Calls {
644  (CALL t.name e.arg) e.rest =
645    <Lookup-Func t.name> :: s.linkage s.tag t.pragma (e.Fin) (e.Fout),
646    <Extract-Calls e.arg> :: (e.last-Re) e.calls,
647    <Prepare-Res <Split-Re (e.Fin) e.last-Re>> :: e.splited-Re,
648    <RFP-Extract-Qualifiers t.name> :: t e.prefix,
649    <Gener-Subst-Vars (e.Fout) e.prefix> :: e.Re,
650    <Vars e.Re> :: e.vars,
651    <Map &Set-Var (Instantiated? True) (e.vars)> : e,
652    {
653      s.tag : FUNC? =   (Failable (CALL t.name (e.splited-Re) (e.vars)));
654      (CALL t.name (e.splited-Re) (e.vars));
655    } :: t.call,
656    <Extract-Calls e.rest> :: (e.rest-Re) e.rest-calls,
657    (e.Re e.rest-Re) e.calls <Vars-Decl Result e.vars> t.call e.rest-calls;
658  (PAREN e.Re) e.rest =
659    <Extract-Calls e.Re> :: (e.last-Re) e.calls,
660    <Extract-Calls e.rest> :: (e.rest-Re) e.rest-calls,
661    ((PAREN e.last-Re) e.rest-Re) e.calls e.rest-calls;
662  t.Rt e.Re =
663    <Extract-Calls e.Re> :: (e.last-Re) e.calls,
664    (t.Rt e.last-Re) e.calls;
665  /*empty*/ = () /*empty*/;
666};
667
668
669Comp-Calls (e.fail) e.calls, e.calls : {
670  (Failable t.call) e.rest =
671    (IF ((NOT t.call)) e.fail) <Comp-Calls (e.fail) e.rest>;
672  t.call e.rest =
673    t.call <Comp-Calls (e.fail) e.rest>;
674  /*empty*/ = /*empty*/;
675};
676
677
678
679********** Preparation of vars and REs for following processing **********
680*********** Compilation of static parts of result expressions ************
681
682$func Static-Expr? s.create? e.Re = static? e.Re;
683
684$func Ref-Func? t = t;
685
686$func Static-Term? t.Rt = static? e.Re;
687
688$func Stub-Name t.name = t.stub-name;
689
690
691/*
692 * Extract static parts from each Re.
693 * Also get the right names for variables generated during the preprocessing
694 * stage, if those are in the expr.
695 */
696Prepare-Res {
697  (e.Re) e.rest = <Static-Expr? Create e.Re> :: s e.Re, (e.Re) <Prepare-Res e.rest>;
698  /*empty*/     = /*empty*/;
699};
700
701/*
702 * Find all the longest static parts in the upper level of Re.  Create STATIC
703 * form in place of each one.
704 * Return a tag pointing whether the whole expression is static and expression
705 * with static parts replaced by STATIC forms.  Dynamic parts are returned
706 * unchanged.
707 */
708Static-Expr? s.create? e.Re =
709  (/*e.static*/) e.Re $iter {
710    e.Re : t.Rt e.rest =
711      <Static-Term? t.Rt> : {
712        Static e.st-Re =
713          (e.static e.st-Re) e.rest;
714        Dynamic t.dyn-Rt =
715          <Static-Expr? Create e.rest> :: s e.rest,
716          (e.static) (Dynamic t.dyn-Rt e.rest);
717      };
718    (e.static);
719  } :: (e.static) e.Re,
720  e.Re : \{
721    /*empty*/, {
722      s.create? : Create =
723        Static <Create-Static e.static>;
724      Static e.static;
725    };
726    (Dynamic e.dynamic) = Dynamic <Create-Static e.static> e.dynamic;
727  };
728
729/*
730 * The same as Static-Expr? but for terms.
731 */
732Static-Term? {
733  symbol       = Static symbol;
734  (PAREN e.Re) = <Static-Expr? Not-Create e.Re> :: static? e.Re, static? (PAREN e.Re);
735  (REF t.name) = Static <Ref-Func? (REF t.name)>;
736  (STATIC t.name) = Static <Get-Static (STATIC t.name)>;
737  t.var        = <Prepare-Vars t.var> : t.prep-var, Dynamic t.prep-var;
738};
739
740Ref-Func? {
741  (REF t.name) =
742    {
743      <Lookup-Func t.name> : {
744        s.linkage s.tag t.pragma ((EVAR)) ((EVAR)) = (s.tag t.name);
745        s.linkage s.tag t.pragma (e.Fin) (e.Fout) =
746          {
747            <Lookup &Stub-Funcs t.name> : t.stub-name e =
748              (FUNC? t.stub-name);
749            <Stub-Name t.name> :: t.stub-name,
750              <Bind &Stub-Funcs (t.name)
751                (t.stub-name s.tag (e.Fin) (e.Fout))>,
752              (FUNC? t.stub-name);
753          };
754      };
755      (REF t.name);
756    };
757  term = term;
758};
759
760/*
761 * Обеспечивает, что сгенерированные препроцессорами переменные (с именами,
762 * оканчивающимися на число) не пересекаются с программными переменными (за
763 * счёт того, что таг будет VAR).
764 */
765Prepare-Vars {
766  (s.var-tag (e.prefix s.n)) e.rest, <Int? s.n> =
767    {
768      <Lookup &Prep-Vars (s.var-tag (e.prefix s.n))>;
769      <Gener-Vars ((s.var-tag)) e.prefix> :: e.var,
770        <Bind &Prep-Vars ((s.var-tag (e.prefix s.n))) (e.var)>,
771        e.var;
772    } :: e.var,
773    e.var <Prepare-Vars e.rest>;
774  t.var e.rest = t.var <Prepare-Vars e.rest>;
775  /*empty*/ = /*empty*/;
776};
777
778/*
779 * Генерируем уникальные внутри модуля имена для функций-заглушек.
780 */
781Stub-Name (e.qualifiers s.name) =
782  <To-Chars s.name> : {
783    e1 '_' s.n, <Int? s.n> = e1 '_' <"+" s.n 1>;
784    e1 = e1 '_' 0;
785  } :: e.name,
786  (/*e.qualifiers*/ <To-Word e.name>) :: t.name,
787  {
788    <Lookup-Func t.name> : e = <Stub-Name t.name>;
789    t.name;
790  };
791
792
793
794***************** Compilation of assignment to variables *****************
795
796$func Comp-Assign-to-Var t.var e.Re (e.assigned-vars) = e.assign (e.used-vars);
797
798Comp-Assign-to-Var t.var e.Re (e.assigned-vars) =
799  {
800    t.var : e.Re = /*empty*/ ();
801    <Vars-Reset t.var>, $fail;
802    <Substitutable-Var? e.Re>, # \{ e.assigned-vars : e t.var e; } =
803      <Gener-Var-Assign t.var e.Re> ();
804    <Get-Var Decl t.var> : s = (ASSIGN <Vars-Print t.var> e.Re) (<Vars e.Re>);
805    <Vars-Decl Expr t.var> : e, (EXPR <Vars-Print t.var> e.Re) (<Vars e.Re>);
806  };
807
808Comp-Assigns e.assigns =
809  e.assigns (/*e.assigned-vars*/) (/*e.comp-assigns*/) $iter {
810    e.assigns : (t.var (e.Re)) e.rest =
811      <Comp-Assign-to-Var t.var e.Re (e.assigned-vars)> :: e.c-as (e.a-vs),
812      e.rest (e.assigned-vars e.a-vs) (e.comp-assigns e.c-as);
813  } :: e.assigns (e.assigned-vars) (e.comp-assigns),
814  e.assigns : /*empty*/ =
815  e.comp-assigns;
816
817
818
819************************** FORMAT compilation. ***************************
820
821$box Aux-Index;
822
823$func Gener-Aux-Var = t.new-aux-var;
824
825Gener-Aux-Var =
826  <? &Aux-Index> : s.n,
827  <Store &Aux-Index <"+" s.n 1>>,
828  (VAR ("aux" s.n));
829
830
831$func Create-Aux-Vars (e.vars) e.splited-Re = e.assigns;
832
833
834Comp-Format (e.last-Re) e.He =
835  <Prepare-Vars <Vars e.He>> :: e.vars,
836  <Prepare-Res <Split-Re (<Format-Exp e.He>) e.last-Re>> :: e.splited-Re,
837  <Store &Aux-Index 1>,
838  <Create-Aux-Vars (e.vars) e.splited-Re> :: e.assigns,
839  <Comp-Assigns e.assigns>;
840
841/*
842 * Итак, e.vars -- все переменные, входящие в форматное выражение.  Каждая
843 * переменная может входить в форматное выражение только один раз, поэтому
844 * повторяющихся среди них нет.
845 * e.splited-Re -- набор результатных выражений.  На каждую переменную из
846 * e.vars по выражению, которое должно быть ей присвоено.
847 *
848 * Если переменная t.var_i используется в выражении e.Re_j, и i /= j, то
849 * переменной t.var_j значение должно быть присвоено раньше, чем перeменной
850 * t.var_i.  Если же, по аналогичным соображениям, t.var_i должна получить
851 * значение раньше t.var_j, необходимо завести вспомогательную переменную.
852 *
853 * Пример:
854 *
855 * t1 (t1 t2) (t1 t3) :: t2 t1 t3
856 *
857 * t3 = (t1 + t3)();
858 * aux_1 = t1;
859 * t1 = (t1 + t2)()
860 * t2 = aux_1;
861 *
862 * В общем случае вспомогательная переменная требуется, если двум переменным
863 * необходимы старые значения друг друга (возможно, не напрямую, а через
864 * промежуточные переменные).
865 *
866 * Вместо того, чтобы искать и анализировать такие циклы, будем действовать по
867 * методу "наибольшей пользы".  А именно:
868 *
869 *   - Для каждой переменной выпишем все другие переменные, которым требуется
870 *     её старое значение, а также отдельно те, старые значения которых
871 *     требуются ей.
872 *
873 *   - Всем переменным, от старых значений которых ничего не зависит, можно
874 *     смело присвоить новые значения.  При этом они исчезают из списков
875 *     зависимостей оставшихся переменных.
876 *
877 *   - Все переменные, новые значения которых ни от чего не зависят, можно
878 *     отложить, чтобы присвоить им значения тогда, когда будет удобно.  Т.е.
879 *     тогда, когда списки зависящих от них переменных опустеют.
880 *
881 *   - Чтобы означить оставшиеся, нужны вспомогательные переменные.  Выберем
882 *     одну из переменных, с максимальным списком тех, от которых она зависит,
883 *     и положим её значение во вспомогательную переменную.  Так как мы сразу
884 *     уменьшили кол-во зависимостей у максимального кол-ва переменных,
885 *     локально мы добились наибольшей пользы, хотя не исключено, что глобально
886 *     такой метод и не даст наименьшего кол-ва вспомогательных переменных.
887 *     Кроме того, мы не пытаемся выбрать наилучшую переменную из нескольких с
888 *     максимальным списком зависимостей.
889 *
890 *   - Повторяем всё это до тех пор, пока у каждой переменной не опустеет
891 *     список зависящих от неё.
892 *
893 *
894 * Для нашего примера:
895 *
896 * t1 (t1 t2) (t1 t3) :: t2 t1 t3
897 *
898 * t1 -- (t2 t3) (t2)
899 * t2 -- (t1)    (t1)
900 * t3 -- ()      (t1)
901 *
902 *
903 * Для каждой переменной var_i найдём все j /= i, такие что в Re_j встречается
904 * var_i -- provide[i], и а также все j /= i, такие что var_j нужна для
905 * подсчёта var_i, т.е. встречается в Re_i.
906 *
907 * Res-vars <- <Map &Vars (Res)>
908 * for var_i in vars
909 *     provide[i] <-
910 *     for vars-Re_j in Res-vars, j /= i
911 *         vars-Re_j : e var_i e = j
912 *     require[i] <- <Res-vars[i] `*` vars[^i]> : e var_j e, j
913 *
914 * Res-vars = map Vars Res
915 * provide, require =
916 *   {   [ j | vars-Re_j <- Res-vars, j /= i, var_i `in` vars-Re_j ]
917 *     , [ j | var_j <- Res-vars[i] `*` vars, i /= j]
918 *     | var_i <- vars
919 *   }
920 *
921 */
922
923$func CAV e.vars (e.assigns) (e.delayed) = e.assigns;
924
925$func Get-Vars e = e;
926Get-Vars (e.Re) = (<Vars e.Re>);
927
928Create-Aux-Vars (e.vars) e.splited-Re =
929  <Zip (<Map &Get-Vars (e.splited-Re)>) (e.vars)> :: e.list,
930  <Box> :: s.box,
931  <Box> :: s.provide-i,
932  <Box> :: s.require-i,
933  {
934    e.vars : e1 t.var-i e2,
935      {
936        e.list : e ((e.vars-Re) t.var-j) e,
937          \{
938            t.var-i : t.var-j = <Put s.require-i <And (e1 e2) e.vars-Re>>;
939            e.vars-Re : e t.var-i e = <Put s.provide-i t.var-j>;
940          },
941          $fail;
942        <L <Length e1> e.splited-Re> :: t.Re-i,
943        <Put s.box (t.var-i t.Re-i (<? s.provide-i>) (<? s.require-i>))>,
944          <Store s.provide-i /*empty*/>,
945          <Store s.require-i /*empty*/>;
946      },
947      $fail;;
948  },
949  <CAV <? s.box> (/*assigns*/) (/*delayed*/)>;
950
951
952/*
953 * Если есть переменная, у которой список provide пуст, её можно посчитать.
954 * Это выражается в том, что она (вместе с присваиваемым значением) добавляется
955 * в список assigns, убирается из списка vars, а также из всех списков provide
956 * и delayed.  В списках require её не было.
957 *
958 * CAV Res vars provide require assigns delayed =
959 *   { i | var_i <- vars, provide_i == [] } ->     // Здесь неверно!  На переменные
960 *                                                    из delayed тоже надо смотреть.
961 *       vars    = vars - var_i
962 *       provide = [ provide_j - i | provide_j <- provide ]
963 *       assigns = assigns++[(var_i, Res[i])]
964 *       delayed = [ (var_j, provide_j - i) | (var_j, provide_j) <- delayed ]
965 *       CAV Res vars provide require assigns delayed
966 */
967
968$func Assign-Empty-Provides e.vars  = e.assigns (e.vars);
969
970Assign-Empty-Provides {
971  e1 (t.var-i t.Re-i (/*empty provide_i*/) (e.require-i)) e2 =
972    <Box> :: s.vars,
973    {
974      e1 e2 : e (t.var-j t.Re-j (e.provide-j) (e.require-j)) e,
975        <Put s.vars (t.var-j t.Re-j (<Sub (e.provide-j) t.var-i>) (e.require-j))>,
976        $fail;;
977    },
978    (t.var-i t.Re-i) <Assign-Empty-Provides <? s.vars>>;
979  e.vars = /*empty*/ (e.vars);
980};
981
982
983/*
984 * Если есть переменная, у которой список require пуст, кладём её в delayed.
985 * Она будет посчитана, когда у неё опустеет список provide, т.е. когда не
986 * останется переменных, у которых она в списке require.
987 */
988$func Delay-Empty-Requires e.vars  = e.delayed (e.vars);
989
990Delay-Empty-Requires {
991  e1 t.var e2, t.var : (t.var-i t.Re-i (e.provide-i) (/*empty require_i*/)) =
992    <Delay-Empty-Requires e2> :: e.delayed (e.vars),
993    t.var e.delayed (e1 e.vars);
994  e.vars = /*empty*/ (e.vars);
995};
996
997
998/*
999 * Выбор переменной (из двух) с более длинным списком требуемых ей значений.
1000 */
1001$func Max-Require e = e;
1002
1003Max-Require t.arg1 t.arg2 =
1004  t.arg1 : (t.var1 t.Re1 t.provide1 (e.require1)),
1005  t.arg2 : (t.var2 t.Re2 t.provide2 (e.require2)),
1006  {
1007    <"<" (<Length e.require1>) (<Length e.require2>)> = t.arg2;
1008    t.arg1;
1009  };
1010
1011
1012/*
1013 * Подставить вспомогательную переменную вместо исходной во всех результатных выражениях.
1014 * Присваивание к исходной переменной убрать (оно к этому моменту уже выполнено).
1015 * Убрать переменную из списков зависимостей.
1016 */
1017$func Subst-Aux-Var e = e;
1018
1019Subst-Aux-Var t.var t.aux (t.v t.Re (e.provide) (e.require)), {
1020  t.var : t.v = /*empty*/;
1021  (
1022    t.v
1023    <Subst (t.var) ((t.aux)) t.Re>
1024    (<Sub (e.provide) t.var>)
1025    (<Sub (e.require) t.var>)
1026  );
1027};
1028
1029
1030/*
1031 * Извлечь присваивание из всей информации о переменной.
1032 */
1033$func Extract-Assigns e = e;
1034Extract-Assigns (t.var t.Re e) = (t.var t.Re);
1035
1036
1037/*
1038 * Основной цикл обработки присваиваний.
1039 *
1040 * 1) Из всех переменных (в том числе и отложенных), от которых больше ничего
1041 *    не зависит, сделать присваивания.
1042 * 2) Все переменные, которые больше ни от чего не зависят, отложить.
1043 * 3) Если осталось хотя бы две неотложенных переменных, выбирать из них ту,
1044 *    которая зависит от наибольшего числа переменных, подставить везде вместо
1045 *    неё вспомогательную, перейти к пункту 1.
1046 */
1047CAV e.vars (e.assigns) (e.delayed) =
1048  <Assign-Empty-Provides e.vars> :: e.new-assigns (e.vars),
1049  e.assigns e.new-assigns <Assign-Empty-Provides e.delayed> :: e.assigns (e.delayed),
1050  e.delayed <Delay-Empty-Requires e.vars> :: e.delayed (e.vars),
1051  {
1052    e.vars : t t e =
1053      <Foldr1 &Max-Require (e.vars)> : (t.var t.Re e),
1054      <Gener-Aux-Var> :: t.aux,
1055      e.assigns (t.aux (t.var)) (t.var t.Re) :: e.assigns,
1056      <Map &Subst-Aux-Var t.var t.aux (e.vars)> :: e.vars,
1057      <Map &Subst-Aux-Var t.var t.aux (e.delayed)> :: e.delayed,
1058      <CAV e.vars (e.assigns) (e.delayed)>;
1059    e.assigns <Map &Extract-Assigns (e.vars e.delayed)>;
1060  };
1061
1062
1063
1064
1065****************** Компиляция сопоставления с образцом *******************
1066
1067Get-Clash-Sequence (e.last-Re) t.Pattern e.Snt =
1068  (/*e.clashes*/) (RESULT e.last-Re) t.Pattern e.Snt $iter {
1069    e.Snt : (RESULT e.Re) (s.dir e.Pe) e.rest =
1070      /*
1071       * Компилируем все константные выражения и заводим в табличке все
1072       * незаведённые переменные.  У старых переменных очищается память
1073       * на предмет клешей, в которых они раньше использовались.
1074       */
1075      <Prepare-Res (e.Re) (e.Pe)> : (e.R1) (e.P1),
1076      <Map &Set-Var (Clashes /*empty*/) (<Vars e.R1 e.P1>)> : e,
1077      (e.clashes (e.R1) (s.dir e.P1)) e.rest;
1078  } :: (e.clashes) e.Snt,
1079  # \{
1080    e.Snt : \{
1081      (RESULT e.Re) (LEFT e) e = e.Re;
1082      (RESULT e.Re) (RIGHT e) e = e.Re;
1083    } :: e.Re,
1084      <Without-Calls? e.Re>;
1085  } =
1086  (e.clashes) e.Snt;
1087
1088Without-Calls? e.Re =
1089  e.Re $iter {
1090    e.Re : t.Rt e.rest =
1091      t.Rt : {
1092        (CALL e) = $fail;
1093        (BLOCK e) = $fail;
1094        (PAREN e.Re1) = <Without-Calls? e.Re1>;
1095        t.symbol-or-var = /*empty*/;
1096      },
1097      e.rest;
1098  } :: e.Re,
1099  e.Re : /*empty*/;
1100
1101$func CC s.tail? (v.fails) t.end-cycle e.Snt = e.asail-Snt;
1102
1103Comp-Clashes (e.clashes) s.tail? (v.fails) e.Sentence =
1104  <Init-Clashes e.clashes>,
1105  <CC s.tail? (v.fails) <R 0 v.fails> e.Sentence>;
1106
1107$func CC-Known-Lengths t.fail e.idxs = e.conds;
1108
1109$func CC-Compute-Length t.fail t.end-cycle t.idx = e;
1110
1111$func CC-Unknown-Lengths t.fail e.idxs = e.conds;
1112
1113$func CC-Deref t.fail e.actions = e.actions;
1114
1115$func CC-Eqs t.fail (e.assigns) e.eqs = e.actions;
1116
1117CC s.tail? (v.fails) t.end-cycle e.Snt, {
1118  <Domain &Known-Lengths> : v.clashes =
1119    <CC-Known-Lengths t.end-cycle v.clashes>
1120    <CC s.tail? (v.fails) t.end-cycle e.Snt>;
1121  <Domain &Compute-Length> : (t.clash) e =
1122    <CC-Compute-Length <R 0 v.fails> t.end-cycle t.clash>
1123    <CC s.tail? (v.fails) t.end-cycle e.Snt>;
1124  <Domain &Unknown-Lengths> : e.clashes =
1125    <CC-Unknown-Lengths t.end-cycle e.clashes> :: e.conds,
1126    /*
1127     * Когда мы добрались до сюда, все условия на длины на текущем уровне
1128     * выписаны.  Невыполнение любого из оставшихся условий (на
1129     * соответствие типов, равенство, длины внутри скобок) ведёт не к
1130     * прекращению текущего цикла, а переход к его следующей итерации.
1131     * Поэтому в качестве t.end-cycle везде дальше подставляется текущий
1132     * откат.
1133     */
1134    <Update-Hard-Parts> : {
1135      v.actions =
1136        e.conds <CC-Deref <R 0 v.fails> v.actions>
1137        <CC s.tail? (v.fails) <R 0 v.fails> e.Snt>;
1138      /*empty*/ =
1139        e.conds <CC-Eqs <R 0 v.fails> () <? &Eqs>> :: e.actions,
1140        <Store &Eqs /*empty*/>,
1141        {
1142          <Compose-Source> :: e.assign =
1143            e.actions <CC-Eqs <R 0 v.fails> () e.assign>
1144            <CC s.tail? (v.fails) <R 0 v.fails> e.Snt>;
1145          {
1146            <Get-Cycle> :: s.split (e.left) (e.right) (e.len)
1147                    t.var t.l-var t.r-var =
1148              {
1149                e.left : 0, e.right : 0 = /*empty*/ t.var;
1150                <Gener-Vars ((VAR)) "subexpr_" t.var> : t.sub-var,
1151                  (SUBEXPR t.sub-var t.var (e.left)
1152                    ((INFIX "-" (e.len) (e.left e.right))))
1153                  t.sub-var;
1154              } :: e.subexpr t.var,
1155              {
1156                s.split : RSPLIT =
1157                  t.r-var t.l-var DEC-ITER;
1158                t.l-var t.r-var INC-ITER;
1159              } :: t.l-var t.r-var s.iter-op,
1160              <Gener-Label "continue"> :: t.cont-label,
1161              <Gener-Label "exit"> :: t.break-label,
1162              e.actions e.subexpr
1163              (s.split t.var (<Get-Var Min t.l-var>) t.l-var t.r-var)
1164              (FOR (t.cont-label) (t.break-label) () ((s.iter-op t.var))
1165                (IF ((NOT (CHECK-ITER t.var))) <Concat <R 0 v.fails>>)
1166                <CC s.tail?     (v.fails ((CONTINUE t.cont-label)))
1167                  <R 0 v.fails> e.Snt>
1168                (BREAK t.break-label)
1169              );
1170            e.actions <Comp-Sentence s.tail? (v.fails) () e.Snt>;
1171          };
1172        };
1173    };
1174};
1175
1176CC-Known-Lengths (e.fail) e.idxs, {
1177  e.idxs : (t.idx) e.rest =
1178    <Put &Checked-Lengths t.idx>,
1179    <Lookup &Known-Lengths t.idx> : (e.len-Re) (e.len-Pe),
1180    (IF ((INFIX "!=" (e.len-Re) (e.len-Pe))) e.fail)
1181    <CC-Known-Lengths (e.fail) e.rest>;
1182  <RFP-Clear-Table &Known-Lengths>;
1183};
1184
1185CC-Compute-Length (e.fail) (e.end-cycle) t.idx =
1186  <Lookup &Compute-Length t.idx> : t.var s.mult (e.minuend) (e.subtrahend),
1187  <Get-Var Min t.var> :: e.min,
1188  {
1189    t.var : (Len-Var e) =
1190      <Unbind &Compute-Length t.idx>,
1191      (IF ((INFIX "<" (e.minuend)
1192          ((INFIX "+" (e.subtrahend)
1193            ((INFIX "*" (e.min) (s.mult)))
1194        ))      ))
1195        e.end-cycle
1196      );
1197    <Create-Int-Var ("len") Aux e.minuend> :: t.m-var e.m-assign,
1198      <Create-Int-Var ("len") Aux e.subtrahend> :: t.s-var e.s-assign,
1199      ((INFIX "<" (t.m-var)
1200        ((INFIX "+" (t.s-var)
1201              ((INFIX "*" (e.min) (s.mult)))
1202        ))                      )) :: e.min-cond,
1203      <Get-Var Max t.var> : {
1204        /*empty*/;
1205        e.max =
1206          ((INFIX ">" (t.m-var)
1207            ((INFIX "+" (t.s-var)
1208                  ((INFIX "*" (e.max) (s.mult)))
1209          ))                    ));
1210      } :: e.max-cond,
1211      (INFIX "%" ((INFIX "-" (t.m-var) (t.s-var))) (s.mult)) :: e.div-cond,
1212      <Create-Int-Var ("len_") t.var
1213        (INFIX "/" ((INFIX "-" (t.m-var) (t.s-var))) (s.mult))
1214      > :: t.len-var e.len-assign,
1215      <Set-Var (Length t.len-var) t.var>,
1216      <Unbind &Compute-Length t.idx>,
1217      <Put &Checked-Lengths t.idx>,
1218      <Get-Var Clashes t.var> :: e.clashes,
1219      <Map &Reclassify-Clash (<Sub (e.clashes) <? &Checked-Lengths>>)> : e,
1220      e.m-assign e.s-assign
1221      (IF ((INFIX "||" e.min-cond e.max-cond)) e.end-cycle)
1222      (IF (e.div-cond) e.fail)
1223      e.len-assign;
1224  };
1225
1226$func  Get-Min e = e;
1227
1228$func? Get-Max e = e;
1229
1230CC-Unknown-Lengths (e.fail) e.idxs, {
1231  e.idxs : (t.idx) e.rest =
1232    <Lookup &Unknown-Lengths t.idx> : (e.len-Re) (e.len-Pe) (e.vars-Re) (e.vars-Pe),
1233    {
1234      <Get-Max e.vars-Re> :: e.max =
1235        <Get-Min e.vars-Pe> :: e.min,
1236        ((INFIX "<" (e.len-Re e.max) (e.len-Pe e.min)));
1237      /*empty*/;
1238    } :: e.cond1,
1239    {
1240      <Get-Max e.vars-Pe> :: e.max =
1241        <Get-Min e.vars-Re> :: e.min,
1242        ((INFIX ">" (e.len-Re e.min) (e.len-Pe e.max)));
1243      /*empty*/;
1244    } :: e.cond2,
1245    {
1246      e.cond1 : /*empty*/, e.cond2 : /*empty*/ = /*empty*/;
1247      (IF ((INFIX "||" e.cond1 e.cond2)) e.fail);
1248    } :: e.cond,
1249    e.cond
1250    <CC-Unknown-Lengths (e.fail) e.rest>;
1251  <RFP-Clear-Table &Unknown-Lengths>;
1252};
1253
1254Get-Min
1255{
1256  t.var e.vars = <Get-Var Min t.var> <Get-Min e.vars>;
1257  /*empty*/ = /*empty*/;
1258};
1259
1260Get-Max
1261{
1262  t.var e.vars = <Get-Var Max t.var> : v.max, v.max <Get-Max e.vars>;
1263  /*empty*/ = /*empty*/;
1264};
1265
1266$func Pos (e.Re) s.dir e.pos = e.pos;
1267
1268Pos {
1269  (e.Re) RIGHT e.pos = (INFIX "-" ((LENGTH e.Re)) (1) (e.pos));
1270  (e.Re) LEFT  e.pos = e.pos;
1271};
1272
1273/*
1274 * Информацию о проверках и заведении переменных, необходимых для создания
1275 * клешей из содержимого скобок, кодируем на ASAIL.
1276 */
1277CC-Deref (e.fail) e.actions, e.actions : {
1278  (SYMBOL? e.Re (s.dir e.pos)) e.rest =
1279    (IF ((SYMBOL? e.Re (<Pos (e.Re) s.dir e.pos>))) e.fail)
1280    <CC-Deref (e.fail) e.rest>;
1281  (DEREF t.var e.Re (s.dir e.pos)) e.rest =
1282    (DEREF t.var e.Re (<Pos (e.Re) s.dir e.pos>))
1283    <CC-Deref (e.fail) e.rest>;
1284  /*empty*/ = /*empty*/;
1285};
1286
1287CC-Eqs (e.fail) (e.assigns) e.eqs, {
1288  e.eqs : ((e.Re) (s.dir e.pos) t.Pt (e.len)) e.rest =
1289    {
1290      e.Re : t,
1291        <Get-Known-Length e.Re> : e.len (), // FIXME: здесь надо использовать
1292                          //        калькулятор
1293        s.dir e.pos : \{
1294          LEFT 0;
1295          RIGHT e.len;
1296        } =
1297        e.Re;;
1298    } :: e.Re-term,
1299    {
1300      e.len : 1 = TERM-EQ;      // FIXME: здесь надо использовать
1301                  //        калькулятор
1302      EQ;
1303    } :: s.eq,
1304    <Pos (e.Re) s.dir e.pos> :: e.pos,
1305    {
1306      \{
1307        <Get-Var Instantiated? t.Pt> : True = t.Pt (e.Re);
1308        t.Pt : \{
1309          (REF e);
1310          (STATIC e);
1311        }, {
1312          <Var? e.Re-term> = e.Re-term (t.Pt);
1313          t.Pt (e.Re);
1314        };
1315      } :: el (er),
1316        (IF ((NOT (s.eq el (er) (e.pos)))) e.fail) :: t.cond,
1317        {
1318          /*
1319           * Мы предполагаем, что во всех пришедших e.eqs все e.Re
1320           * уже были определены ранее.
1321           */
1322          e.assigns : $r e1 (s.op t.Pt e.def) e2 =
1323            <CC-Eqs (e.fail) (e1 (s.op t.Pt e.def) t.cond e2) e.rest>;
1324          t.cond <CC-Eqs (e.fail) (e.assigns) e.rest>;
1325        };
1326      <Set-Var (Instantiated? True) t.Pt>,
1327        {
1328          t.Pt : (SVAR e) =
1329            (IF
1330              ((NOT (SYMBOL? e.Re (<Pos (e.Re) s.dir e.pos>))))
1331              e.fail
1332            );;
1333        } :: e.cond,
1334        {
1335          <Get-Var Decl t.Pt> : s =
1336            e.cond <CC-Eqs (e.fail) (e.assigns
1337              (ASSIGN t.Pt (SUBEXPR e.Re (e.pos) (e.len))))
1338              e.rest>;
1339          <Vars-Decl Expr t.Pt> : e,
1340            e.cond <CC-Eqs (e.fail) (e.assigns
1341              (SUBEXPR t.Pt e.Re (e.pos) (e.len))) e.rest>;
1342        };
1343    };
1344  e.assigns e.eqs;
1345};
1346
1347
1348
1349
1350Gener-Label e.QualifiedName =
1351  {
1352    <Lookup &Labels e.QualifiedName> : s.num,
1353      <"+" s.num 1>;
1354    1;
1355  } :: s.num,
1356  <Bind &Labels (e.QualifiedName) (s.num)>,
1357  (e.QualifiedName s.num);
1358
1359Add-To-Label (e.label) e.name = <Gener-Label e.label "_" e.name>;
1360
1361
1362
1363
1364Lookup-Func t.Fname, \{
1365  <Lookup &Fun t.Fname>;
1366  <Lookup &Fun? t.Fname>;
1367} : s.linkage s.tag t.pragma (e.Fin) (e.Fout) =
1368  s.linkage s.tag t.pragma (e.Fin) (e.Fout);
1369
Note: See TracBrowser for help on using the repository browser.