source: to-imperative/trunk/compiler/rfp_compile.rf @ 2474

Last change on this file since 2474 was 2474, checked in by orlov, 14 years ago
  • No variable declarations with DEREF and SUBEXPR in ASAIL.
  • Typo fixed: EXPORTS -> EXPORT in asail_java and asail_jbc.
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 43.2 KB
Line 
1// $Source$
2// $Revision: 2474 $
3// $Date: 2007-02-26 21:51:18 +0000 (Mon, 26 Feb 2007) $
4
5$use "rfpc";
6$use "rfp_helper";
7$use "rfp_check";
8$use "rfp_as2as";
9$use "rfp_format";
10$use "rfp_vars";
11$use "rfp_const";
12$use "rfp_clashes";
13
14$use StdIO;
15$use Table;
16$use Box;
17$use Arithm;
18$use Access;
19$use Compare;
20$use Convert;
21$use Class;
22$use Apply;
23$use Dos;
24$use List;
25
26
27/*
28 * Table for storing object names.
29 */
30$table Objects;
31
32/*
33 * Table for storing parameters of referenced functions.
34 */
35$table Stub-Funcs;
36
37/*
38 * Box for storing function out format
39 */
40$box Out-Format;
41
42/*
43 * Box for storing names for function result variables
44 */
45$box Res-Vars;
46
47/*
48 * Following table is used by Gener-Label function for obtaining unical (for
49 * certain function) label name.
50 * e.Key ::= e.QualifiedName      (parameter given to Gener-Label)
51 * e.Val ::= [Int]          (last index used with such e.QualifiedName)
52 */
53$table Labels;
54
55/*
56 * Table for storing variables used in place of preprocessor-generated ones.
57 */
58$table Prep-Vars;
59
60
61$func Compile (e.targets) e.Items = e.Compiled-Items;
62
63$func Comp-Func-Stubs = e.asail-funcs;
64
65$func Comp-Func s.linkage s.tag t.name e.params-and-body = e.compiled-func;
66
67$func Set-Drops (e.declared-exprs) e.comp-func = (e.declared-exprs) e.result-func;
68
69$func Comp-Sentence e.Sentence = e.asail-sentence;
70
71$func Save-Snt-State = ;
72
73$func Recall-Snt-State = ;
74
75$func Pop-Snt-State = ;
76
77$func Extract-Calls e.Re = (e.last-Re) e.calls;
78
79$func Get-Clash-Sequence (e.last-Re) e.Snt = (e.clashes) e.rest-of-the-Sentence;
80
81$func? Without-Calls? e.Re = ;
82
83$func Comp-Clashes (e.clashes) s.tail? (v.fails) e.Sentence = e.asail-sentence;
84
85$func Gener-Label e.QualifiedName = t.label;
86
87$func Add-To-Label t.label e.name = t.label;
88
89$func Comp-Calls e.Re = e.calls;
90
91$func Prepare-Vars e.vars = e.vars;
92
93$func Prepare-Res e.Reult-exprs = e.Result-exprs;
94
95$func Prepare-Const e.const-expr = e.const-expr;
96
97$func Comp-Assigns e.assignments = e.asail-assignments;
98
99$func Comp-Format (e.last-Re) e.He = e.assignments;
100
101
102
103************ Get AS-Items and targets, and pass it to Compile ************
104
105/*
106 * Ящик для объявлений статических функций, констант и объектов.  Все они
107 * выписываются в самом начале тела модуля.
108 */
109$box Declarations;
110
111$box Trace-Names;
112
113$box Module-Name;
114
115RFP-Compile (e.ModuleName) e.Items =
116  <Store &Module-Name e.ModuleName>,
117  { <Lookup &RFP-Options ITEMS>;; } :: e.targets,
118  <Clear-Table &Stub-Funcs>,
119  <Store &Trace-Names /*empty*/>,
120  <Store &Declarations /*empty*/>,
121  <Init-Consts>,
122  <Compile (e.targets) e.Items> :: e.Items,
123  <Comp-Func-Stubs> :: e.stub-funcs,
124  (MODULE (e.ModuleName) <? &Trace-Names> <? &Declarations> <Comp-Consts>
125    e.Items e.stub-funcs);
126
127
128
129****************** Choose needed items and compile them ******************
130
131Compile (e.targets) e.Items =
132  e.Items (/*e.asail*/) $iter {
133    e.Items : t.item e.rest,
134      {
135        e.targets : v =
136          e.targets : e t.name e,
137          t.item : (t t t t.name e);;
138      },
139      t.item : {
140        (IMPORT s.tag t.pragma t.name e) \?
141          {
142            t.pragma : (PRAGMA e (FILE e.fname) e),
143              s.tag : \{ CONST; FUNC; FUNC?; },
144              e.fname : RFI "org" "refal" "plus" "wrappers" e \! $fail;;
145          };
146        (TRACE t.name) =
147          <Put &Trace-Names (TRACE t.name)>;
148        (EXTERN t.pragma t.name) =
149          <Put &Declarations (EXTERN t.name)>;
150        (s.link s.tag t.pragma t.name (e.in) (e.out) e.body), FUNC FUNC? TFUNC : e s.tag e =
151          {
152            e.body : (BRANCH t.p e.branch) =
153              <Comp-Func s.link s.tag t.name <Del-Pragmas (e.in) (e.out) e.branch>>;
154            <Comp-Func s.link s.tag t.name (<Gener-Vars (e.in) "arg">) (e.out)>;
155          };
156        (s.link CONST t.pragma t.name e.expr) =
157          <Put &Declarations (CONSTEXPR s.link t.name (e.expr) <Prepare-Const e.expr>)>;
158        (s.link s.tag t.pragma t.name) =
159          <Put &Declarations (OBJ s.link s.tag t.name)>;
160      } :: e.item,
161      e.rest (e.asail e.item);
162  } :: e.Items (e.asail),
163  e.Items : /*empty*/ =
164  e.asail;
165
166
167$func Gener-Stub e = e;
168
169/*
170 * For each referenced function generate a stub one with format e = e.
171 */
172Comp-Func-Stubs = <Map &Gener-Stub (<Domain &Stub-Funcs>)>;
173
174Gener-Stub (t.name) =
175  <Lookup &Stub-Funcs t.name> : t.stub-name s.tag (e.Fin) (e.Fout),
176  <Gener-Vars (e.Fin) "stub"> :: e.He,
177  <Comp-Func LOCAL STUB t.stub-name ((EVAR ("arg" 1))) ((EVAR))
178    (LEFT e.He) (CUTALL) (RESULT (CALL t.name e.He))>;
179
180
181
182Comp-Func s.linkage s.tag t.name (e.in) (e.out) e.Sentence =
183  <Clear-Table &Labels>,
184  <Clear-Table &Prep-Vars>,
185  <Init-Vars>,
186  <Vars <Gener-Vars (e.out) "res">> :: e.res-vars,
187  <Vars-Decl Result e.res-vars> : e,
188  <Store &Res-Vars e.res-vars>,
189  <Store &Out-Format <Format-Exp e.out>>,
190  <Prepare-Res (e.in)> : (e.arg),
191  <Vars e.arg> :: e.arg-vars,
192  <Map &Set-Var (Instantiated? True) (e.arg-vars)> : e,
193  s.tag : {
194    FUNC = FUNC (FATAL);
195    FUNC? = FUNC? (RETFAIL);
196    TFUNC = TFUNC (FATAL);
197    STUB =
198      <Prepare-Res (Apply Apply "Unexpected fail")> : (e.message),
199      FUNC? (RETFAIL) ((ERROR e.message));
200  } :: s.tag e.fails,
201  (s.tag s.linkage t.name (<Vars-Print e.arg-vars>) (<Vars-Print e.res-vars>)
202    <Comp-Sentence Tail (e.fails) (e.arg) e.Sentence>
203  ) :: e.comp-func,
204*       <Set-Drops () <Gener-Var-Names e.comp-func>> :: t e.comp-func,
205  <Gener-Var-Names e.comp-func> :: e.comp-func,
206//!     <Post-Comp (e.res-vars) e.comp-func> :: t e.result,
207//!     e.result;
208  e.comp-func;
209//  :: (e.func-decl) e.func-body,
210//  () <Domain &Declarations> $iter {
211//    e.vars : (t.var) e.rest-vars,
212//      (e.var-decls (DECL t.var)) e.rest-vars;
213//  } :: (e.var-decls) e.vars,
214//  e.vars : /*empty*/,
215//  (e.func-decl e.var-decls e.func-body);
216
217Set-Drops (e.declared) e.comp-func =
218  e.comp-func () (e.declared) $iter {
219    e.comp-func : t.first e.rest, {
220      t.first : \{
221        (EXPR t.var e) = (DROP t.var) (t.first) t.var Init;
222        (DEREF t.var e) = (DROP t.var) (t.first) t.var Init;
223        (SUBEXPR t.var e) = (DROP t.var) (t.first) t.var Init;
224        (DECL Expr t.var) = (DROP t.var) () t.var Decl;
225        (DECL "int" t.var) = /*empty*/ () t.var Decl;
226      } :: e.drop (e.constr) t.var s.init,
227        {
228          e.declared : e1 t.var s.old-init e2, s.old-init : {
229            Init, {
230              t.var : (VAR ("const" e)) =
231                e.rest (e.result-func) (e.declared);
232              e.rest (e.result-func e.drop e.constr) (e.declared);
233            };
234            Decl, s.init : {
235              Decl =
236                e.rest (e.result-func) (e.declared);
237              Init =
238                t.first : (s.method t.var e.args),
239                e.rest (e.result-func (ASSIGN t.var (s.method e.args)))
240                (e1 e2 t.var s.init);
241                /*
242                 * FIXME: if s.method is EXPR, it shouldn't be written.
243                 */
244            };
245          };
246          e.rest (e.result-func t.first) (e.declared t.var s.init);
247        };
248      t.first : (LABEL (t.label) e.expr) =
249        <Set-Drops (e.declared) e.expr> :: (e.declared) e.expr,
250        e.rest (e.result-func (LABEL (t.label) e.expr)) (e.declared);
251      t.first : (e.expr) =
252        <Set-Drops (e.declared) e.expr> :: t e.expr,
253        e.rest (e.result-func (e.expr)) (e.declared);
254      t.first : s.symbol =
255        e.rest (e.result-func s.symbol) (e.declared);
256    };
257  } :: e.comp-func (e.result-func) (e.declared),
258  e.comp-func : /*empty*/ =
259  (e.declared) e.result-func;
260
261
262Comp-Sentence s.tail? (v.fails) (e.last-Re) e.Sentence, e.Sentence : {
263
264  /*empty*/ = /*empty*/;
265
266  /*
267   * In case of Re look if we should do a tailcall.  If not, then compile
268   * function calls from the Re and assign results to the out parameters or
269   * use them in compilation of the rest of the sentence.
270   */
271  (RESULT e.Re) e.Snt =
272    {
273      /*
274       * If the Re is the last action in the sentence then we can do
275       * tailcall if one of the following is true:
276       *  - Re is a call of non-failable function;
277       *  - Re is a call of a failable function, current function is
278       *  failable, and the failures stack is empty.
279       * In both cases out format of the called function should coincide
280       * with those of compiled one.
281       * FIXME: really we can do tailcall if all the parameters of
282       * compiled function that won't get their values from the call can
283       * be assigned from other sources.  Some support from runtime is
284       * needed though.
285       */
286      e.Snt : /*empty*/, s.tail? : Tail, e.Re : (CALL t.name e.arg),
287        {
288          <In-Table? &Fun? t.name> =
289            v.fails : (RETFAIL),
290            TAILCALL?;
291          TAILCALL;
292        } :: s.tailcall,
293        <Lookup-Func t.name> :: s.linkage s.tag t.pragma (e.Fin) (e.Fout),
294        <Subformat? (e.Fout) (<? &Out-Format>)> =
295        <Extract-Calls e.arg> :: (e.last-Re) e.calls,
296        <Prepare-Res <Split-Re (e.Fin) e.last-Re>> :: e.splited-Re,
297        <Comp-Calls <R 0 v.fails> e.calls>
298        (s.tailcall t.name (e.splited-Re) (<? &Res-Vars>));
299
300      <Extract-Calls e.Re> :: (e.last-Re) e.calls,
301        <Comp-Calls <R 0 v.fails> e.calls> :: e.comp-calls,
302        {
303          e.Snt : /*empty*/, Tail Tail-in-Trap : e s.tail? e =
304            <Split-Re (<? &Out-Format>) e.last-Re> :: e.splited-Re,
305            <Prepare-Res e.splited-Re> :: e.splited-Re,
306            e.comp-calls <Comp-Assigns <Zip (<? &Res-Vars>) (e.splited-Re)>>;
307
308          e.comp-calls <Comp-Sentence s.tail? (v.fails) (e.last-Re) e.Snt>;
309        };
310    };
311
312  /*
313   * In case of He compile assignments from last Re and then (with new state
314   * of variables) proceed with the rest of the sentence.
315   */
316  (FORMAT e.He) e.Snt =
317    <Comp-Format (e.last-Re) e.He>
318    <Comp-Sentence s.tail? (v.fails) () e.Snt>;
319
320  /*
321   * In case of Pe get from the begining of the sentence a maximum possible
322   * sequence of clashes and compile it.  New values of variables from the
323   * clashes use in the compilation of the rest of the sentence.
324   */
325  (s.dir e.Pattern) e.Snt, s.dir : \{ LEFT; RIGHT; } =
326    <Get-Clash-Sequence (e.last-Re) e.Sentence> :: (e.clashes) e.Sentence,
327    <Comp-Clashes (e.clashes) s.tail? (v.fails) e.Sentence>;
328
329  (s.block) e, BLOCK BLOCK? : e s.block e = <WriteLN! &StdErr "Empty block?">, $fail;
330
331  /*
332   * In case of a block first see if its results are needed for something
333   * after the block and determine whether the block is a source.  Then
334   * compile each branch in turn.
335   */
336  (s.block e.branches) e.Snt,
337    s.block : \{
338      BLOCK = (FATAL);
339      BLOCK?;
340    } :: e.fatal? =
341    /*
342     * If the block initializes an $iter then extract from the $iter the He
343     * for placing it in the end of each branch.
344     * Then look if the block is used by a format expression.
345     * If so, we should declare variables from that expression before
346     * entering any branch -- those should be visible after the block.
347     * The format expression is placed in the end of each branch.
348     * But if a branch computes to $error, the expression shouldn't be
349     * used, so protect it with (Comp If-not-error).
350     * If next after the block is (Comp Error) then block results should be
351     * used as values for $error, so place (Comp Error) in the end of each
352     * branch.
353     * If next after the block is (Comp If-not-error) then our block is in
354     * the end of a branch of an outer block and has next pattern or format
355     * inherited from there.  In that case we should place all the sentence
356     * rest in the end of each branch because the block can be inside the
357     * $error already.
358     */
359    {
360      e.Snt : (ITER t.body t.format t.cond) e.rest =
361        t.format (Comp Iter t.body t.format t.cond) e.rest;
362      e.Snt;
363    } :: e.Snt,
364    e.Snt : {
365      (FORMAT e.format) e.rest =
366        <Prepare-Vars <Vars e.format>> :: e.vars,
367        (e.vars) ((Comp If-not-error) (FORMAT e.format))
368        ((Comp Source)) e.rest;
369      (Comp Error) e.rest =
370        () ((Comp Error)) () /*empty*/;
371      (Comp If-not-error) e.rest =
372        () (e.Snt) () /*empty*/;
373      e = () () () e.Snt;
374    } :: (e.out-vars) (e.next-terms) (e.source?) e.Snt,
375    /*
376     * The block is a source if after it goes format expression
377     * (in that case e.source? isn't empty) or e.Snt isn't empty.
378     * Branches in the block are tail sentences if the current sentence is
379     * tail and the block isn't a source.
380     */
381    {
382      \{ e.source? : v; e.Snt : v; } = ((Comp Source) <R 0 v.fails>) Notail;
383      () s.tail?;
384    } :: (e.source?) s.tail-branch?,
385    /*
386     * In case our block is a source we should mark the position in the
387     * failures stack, so that we can jump to it after CUTALL.  And if our
388     * block isn't failable we should add (FATAL) to the end of the stack.
389     */
390    v.fails e.source? e.fatal? :: v.branch-fails,
391    /*
392     * Before compile the branches mark all out-vars as declared.
393     */
394    <Vars-Decl Expr e.out-vars> :: e.decls,
395    /*
396     * We put all compiled branches in a block, so positive return from a
397     * branch is a break from that block.
398     * Each branch in its turn is placed in its own block, so for a $fail
399     * to the next branch we should just break from that inner block.
400     * Each branch is compiled with the current sentence state and the
401     * state is recalled after that.  When all branches are compiled the
402     * state is popped out from the stack.
403     * If last branch fails then the whole block fails, and return from the
404     * last branch is return from the block.  So the last branch isn't
405     * placed in a block and is processed with the failures stack that was
406     * before entering the block.  Note: this trick helps us find more
407     * tailcalls.  If the call of a failable function is on the last branch
408     * of the block and the failures stack is empty we can do tailcall.
409     * When the last branch is compiled with the block's stack, all we
410     * should do is to check it.
411     */
412    <Gener-Label "block"> :: t.label,
413    <Save-Snt-State>,
414    (e.branches) /*e.comp-branches*/ $iter {
415      e.branches : (BRANCH e.branch) e.rest-br =
416        <Add-To-Label t.label "branch"> :: t.br-label,
417        <Comp-Sentence
418          s.tail-branch?
419          (v.branch-fails ((BREAK t.br-label)))
420          (e.last-Re)
421          e.branch e.next-terms
422        > :: e.comp-br,
423        <Recall-Snt-State>,
424        (e.rest-br) e.comp-branches (LABEL (t.br-label) e.comp-br (BREAK t.label));
425    } :: (e.branches) e.comp-branches,
426    e.branches : (BRANCH e.branch) =
427    <Comp-Sentence
428      s.tail-branch? (v.branch-fails) (e.last-Re) e.branch e.next-terms
429    > :: e.last-branch,
430    <Pop-Snt-State>,
431    <Vars-Reset e.out-vars>,
432    e.decls (LABEL (t.label) e.comp-branches e.last-branch)
433    <Comp-Sentence s.tail? (v.fails) () e.Snt>;
434
435  /*
436   * In case of $iter first of all compile initial assignment to the hard
437   * expression.
438   */
439  (ITER t.body t.format t.cond) e.Snt =
440    <Comp-Sentence s.tail? (v.fails) (e.last-Re)
441      t.format (Comp Iter t.body t.format t.cond) e.Snt
442    >;
443
444  /*
445   * Before compiling $iter condition or body we should forget available info
446   * about all format variables, because that info can be changed during
447   * cycle iterations.
448   * Then compile $iter condition and body both with the current state of the
449   * sentence.
450   * e.Snt can contain (Comp Error) and (protected from errors) pattern or
451   * format which comes from an outer block, so compile it together with the
452   * condition.
453   * If condition fails we should compute the body, so put the compiled
454   * condition in a block and place a break from it to the failures stack.
455   */
456  (Comp Iter (BRANCH e.body) t.format (BRANCH e.condition)) e.Snt =
457    t.format : (FORMAT e.Fe),
458    <Vars-Reset <Prepare-Vars <Vars e.Fe>>>,
459    <Save-Snt-State>,
460    <Gener-Label "iter"> :: t.label,
461    <Gener-Label "exit_iter"> :: t.exit,
462    <Comp-Sentence s.tail? (v.fails ((BREAK t.label))) () e.condition e.Snt>
463      :: e.comp-condition,
464    <Pop-Snt-State>,
465    <Comp-Sentence Notail (v.fails) () e.body t.format> :: e.comp-body,
466    (FOR (/*cont-label*/) (t.exit) () ()
467      (LABEL (t.label) e.comp-condition (BREAK t.exit)) e.comp-body
468    );
469
470  /*
471   * In case of $trap/$with at first compile try-sentence.  All $fails from
472   * it should become errors.
473   * Then recall the state of the sentence and compile catching of an error
474   * with a variable err.
475   * e.Snt can contain (Comp Error) and (protected from errors) pattern or
476   * format which comes from an outer block, so compile it together with both
477   * sentences.
478   */
479  (TRY (BRANCH e.try) e.catch) e.Snt =
480    <Save-Snt-State>,
481    {
482      s.tail? : Tail = Tail-in-Trap;
483      s.tail?;
484    } :: s.tail-in-trap?,
485    <Comp-Sentence s.tail-in-trap? ((FATAL)) () e.try e.Snt> :: e.comp-try,
486    <Pop-Snt-State>,
487    <Gener-Err-Var> :: t.var,
488    <Set-Var (Instantiated? True) t.var>,
489    <Comp-Sentence s.tail? (v.fails) (t.var) e.catch e.Snt> :: e.comp-catch,
490    (TRY e.comp-try) (CATCH-ERROR e.comp-catch);
491
492  /*
493   * In case of \? add Stake to the failures stack.  Add last fail after it
494   * for <R 0 v.fails> continue to work.
495   */
496  (STAKE) e.Snt =
497    <Comp-Sentence s.tail? (v.fails (Comp Stake) <R 0 v.fails>) () e.Snt>;
498
499  /*
500   * In case of \! forget all failure catchers after last \?.
501   * If there is no Stake then we are inside negation or error (we assume the
502   * program is correct).  So the right failure catcher is in the bottom of
503   * the stack.
504   */
505  (CUT) e.Snt =
506    {
507      v.fails : $r v.earlier-fails (Comp Stake) e = v.earlier-fails;
508      <L 0 v.fails>;
509    } :: v.fails,
510    <Comp-Sentence s.tail? (v.fails) () e.Snt>;
511
512  /*
513   * In case of = clear the failures stack up to the closest source.
514   * Don't clear last fail after it for <R 0 v.fails> continue to work.
515   */
516  (CUTALL) e.Snt =
517    {
518      v.fails : $r v.earlier-fails (Comp Source) t.fail e =
519        v.earlier-fails (Comp Source) t.fail;
520      <L 0 v.fails>;
521    } :: v.fails,
522    <Comp-Sentence s.tail? (v.fails) () e.Snt>;
523
524  /*
525   * In case of = in the Refal-6 sense (non-transparent hedge for the fails),
526   * $fail(k) should become $error(Fname "Unexpected fail"), so clear the
527   * failures stack and put that value in it.
528   */
529  NOFAIL e.Snt =
530    <Comp-Sentence s.tail? ((FATAL)) (e.last-Re) e.Snt>;
531
532  /*
533   * In case of $fail return last failure catcher.
534   */
535  (FAIL) e.Snt =
536    v.fails : e (e.last-fail),
537    e.last-fail;
538
539  /*
540   * In case of # we should proceed with the rest if the source is computed
541   * to $fail.
542   * We could compile the rest of the sentence and place it in the
543   * failures stack.  But then the compiled sentence would be copied as many
544   * times as there are $fail's to the upper level in the source.  So we
545   * place compiled source in the block and put the break to exit from it in
546   * the stack.
547   * When compiling the source mark it as Notail as usual.
548   * If the source isn't computed to $fail we should proceed with the last
549   * failure catcher.
550   */
551  (NOT (BRANCH e.branch)) e.Snt =
552    <Gener-Label "negation"> :: t.label,
553    v.fails : e (e.last-fail),
554//    <Save-Snt-State>,
555    <Comp-Sentence Notail (((BREAK t.label))) () e.branch> e.last-fail
556      :: e.comp-negation,
557//    <Pop-Snt-State>,
558    (LABEL (t.label) e.comp-negation) <Comp-Sentence s.tail? (v.fails) () e.Snt>;
559
560  /*
561   * In case of $error all fails become $error(Fname "Unexpected fail").  So
562   * place that value in the failures stack and then compile the computation
563   * of the rest of the sentence and the last Re which should be the value of
564   * $error.
565   */
566  (ERROR) e.Snt =
567    <Comp-Sentence Notail ((FATAL)) () e.Snt (Comp Error)>;
568
569  (Comp Error) e.Snt =
570    <Prepare-Res (e.last-Re)> : (e.Re),
571    (ERROR e.Re);
572
573  /*
574   * Protection mark to be used between source and tail.  If there is $error
575   * construction somewhere in the source then the tail shouldn't be
576   * computed, but instead the source value should be used for throwing.
577   */
578  (Comp If-not-error) e.Snt =
579    {
580      e.Snt : e (Comp Error) =
581        <Comp-Sentence s.tail? (v.fails) (e.last-Re) (Comp Error)>;
582      <Comp-Sentence s.tail? (v.fails) (e.last-Re) e.Snt>;
583    };
584
585//  (Comp Fatal) = FATAL;
586
587//  (Comp Retfail) = RETFAIL;
588
589};
590
591
592
593********** Sentence state stack and functions for work with it. **********
594
595$box Snt-State;
596
597/*
598 * Put current state in the stack.
599 */
600Save-Snt-State = <Put &Snt-State <Vars-Copy-State>>;
601
602/*
603 * Set current state to that at the top of the stack.
604 */
605Recall-Snt-State = <Vars-Set-State <R 0 <? &Snt-State>>>;
606
607/*
608 * Pop the top from the stack and set current state to it.
609 */
610Pop-Snt-State =
611  <Recall-Snt-State>,
612  <Store &Snt-State <Middle 0 1 <? &Snt-State>>>;
613
614
615
616********************** Function calls compilation. ***********************
617
618/*
619 * $func Extract-Calls e.Re = (e.last-Re) e.calls;
620 *
621 *
622 *
623 */
624Extract-Calls {
625  (CALL t.name e.arg) e.rest =
626    <Lookup-Func t.name> :: s.linkage s.tag t.pragma (e.Fin) (e.Fout),
627    <Extract-Calls e.arg> :: (e.last-Re) e.calls,
628    <Prepare-Res <Split-Re (e.Fin) e.last-Re>> :: e.splited-Re,
629    t.name : (e s.prefix),
630    <Gener-Subst-Vars (e.Fout) s.prefix> :: e.Re,
631    <Vars e.Re> :: e.vars,
632    <Map &Set-Var (Instantiated? True) (e.vars)> : e,
633    {
634      s.tag : FUNC? =   (Failable (CALL t.name (e.splited-Re) (e.vars)));
635      (CALL t.name (e.splited-Re) (e.vars));
636    } :: t.call,
637    <Extract-Calls e.rest> :: (e.rest-Re) e.rest-calls,
638    (e.Re e.rest-Re) e.calls <Vars-Decl Result e.vars> t.call e.rest-calls;
639  (PAREN e.Re) e.rest =
640    <Extract-Calls e.Re> :: (e.last-Re) e.calls,
641    <Extract-Calls e.rest> :: (e.rest-Re) e.rest-calls,
642    ((PAREN e.last-Re) e.rest-Re) e.calls e.rest-calls;
643  t.Rt e.Re =
644    <Extract-Calls e.Re> :: (e.last-Re) e.calls,
645    (t.Rt e.last-Re) e.calls;
646  /*empty*/ = () /*empty*/;
647};
648
649
650Comp-Calls (e.fail) e.calls, e.calls : {
651  (Failable t.call) e.rest =
652    (IF (CALL-FAILS t.call) e.fail) <Comp-Calls (e.fail) e.rest>;
653  t.call e.rest =
654    t.call <Comp-Calls (e.fail) e.rest>;
655  /*empty*/ = /*empty*/;
656};
657
658
659
660********** Preparation of vars and REs for following processing **********
661*********** Compilation of static parts of result expressions ************
662
663$func Static-Expr? s.create? e.Re = static? e.Re;
664
665$func Ref-Func? t = t;
666
667$func Static-Term? t.Rt = static? e.Re;
668
669$func Stub-Name t.name = t.stub-name;
670
671
672/*
673 * Extract static parts from each Re.
674 * Also get the right names for variables generated during the preprocessing
675 * stage, if those are in the expr.
676 */
677Prepare-Res {
678  (e.Re) e.rest = <Static-Expr? Create e.Re> :: s e.Re, (e.Re) <Prepare-Res e.rest>;
679  /*empty*/     = /*empty*/;
680};
681
682/*
683 * Find all the longest static parts in the upper level of Re.  Create STATIC
684 * form in place of each one.
685 * Return a tag pointing whether the whole expression is static and expression
686 * with static parts replaced by STATIC forms.  Dynamic parts are returned
687 * unchanged.
688 */
689Static-Expr? s.create? e.Re =
690  (/*e.static*/) e.Re $iter {
691    e.Re : t.Rt e.rest =
692      <Static-Term? t.Rt> : {
693        Static e.st-Re =
694          (e.static e.st-Re) e.rest;
695        Dynamic t.dyn-Rt =
696          <Static-Expr? Create e.rest> :: s e.rest,
697          (e.static) (Dynamic t.dyn-Rt e.rest);
698      };
699    (e.static);
700  } :: (e.static) e.Re,
701  e.Re : \{
702    /*empty*/, {
703      s.create? : Create =
704        Static <Create-Static e.static>;
705      Static e.static;
706    };
707    (Dynamic e.dynamic) = Dynamic <Create-Static e.static> e.dynamic;
708  };
709
710/*
711 * The same as Static-Expr? but for terms.
712 */
713Static-Term? {
714  symbol       = Static symbol;
715  (PAREN e.Re) = <Static-Expr? Not-Create e.Re> :: static? e.Re, static? (PAREN e.Re);
716  (REF t.name) = Static <Ref-Func? (REF t.name)>;
717  (STATIC t.name) = Static <Get-Static (STATIC t.name)>;
718  t.var        = <Prepare-Vars t.var> : t.prep-var, Dynamic t.prep-var;
719};
720
721Ref-Func? {
722  (REF t.name) =
723    {
724      <Lookup-Func t.name> : {
725        s.linkage s.tag t.pragma ((EVAR)) ((EVAR)) = (s.tag t.name);
726        s.linkage s.tag t.pragma (e.Fin) (e.Fout) =
727          {
728            <Lookup &Stub-Funcs t.name> : t.stub-name e =
729              (FUNC? t.stub-name);
730            <Stub-Name t.name> :: t.stub-name,
731              <Bind &Stub-Funcs (t.name)
732                (t.stub-name s.tag (e.Fin) (e.Fout))>,
733              (FUNC? t.stub-name);
734          };
735      };
736      (REF t.name);
737    };
738  term = term;
739};
740
741/*
742 * Обеспечивает, что сгенерированные препроцессорами переменные (с именами,
743 * оканчивающимися на число) не пересекаются с программными переменными (за
744 * счёт того, что таг будет VAR).
745 */
746Prepare-Vars {
747//  (s.var-tag (e.prefix s.n)) e.rest, <Int? s.n> =
748//    {
749//      <Lookup &Prep-Vars (s.var-tag (e.prefix s.n))>;
750//      <Gener-Vars ((s.var-tag)) e.prefix> :: e.var,
751//        <Bind &Prep-Vars ((s.var-tag (e.prefix s.n))) (e.var)>,
752//        e.var;
753//    } :: e.var,
754//    e.var <Prepare-Vars e.rest>;
755  t.var e.rest = t.var <Prepare-Vars e.rest>;
756  /*empty*/ = /*empty*/;
757};
758
759/*
760 * Генерируем уникальные внутри модуля имена для функций-заглушек.
761 */
762Stub-Name (e.qualifiers s.name) =
763  <To-Chars s.name> : {
764    e1 '_' s.n, <Int? s.n> = e1 '_' <"+" s.n 1>;
765    e1 = e1 '_' 0;
766  } :: e.name,
767//  (e.qualifiers <To-Word e.name>) :: t.name,
768  (<? &Module-Name> <To-Word e.name>) :: t.name,
769  {
770    <Lookup-Func t.name> : e = <Stub-Name t.name>;
771    t.name;
772  };
773
774
775Prepare-Const {
776  (PAREN expr) e.rest = (PAREN <Prepare-Const expr>) <Prepare-Const e.rest>;
777  t1 e.rest = <Ref-Func? t1> <Prepare-Const e.rest>;
778  /*empty*/ = /*empty*/;
779};
780
781
782***************** Compilation of assignment to variables *****************
783
784$func Comp-Assign-to-Var t.var e.Re (e.assigned-vars) = e.assign (e.used-vars);
785
786Comp-Assign-to-Var t.var e.Re (e.assigned-vars) =
787  {
788    t.var : e.Re = /*empty*/ ();
789    <Vars-Reset t.var>, $fail;
790    <Substitutable-Var? e.Re>, # \{ e.assigned-vars : e t.var e; } =
791      <Gener-Var-Assign t.var e.Re> ();
792    <Get-Var Decl t.var> : s = (ASSIGN <Vars-Print t.var> e.Re) (<Vars e.Re>);
793    <Vars-Decl Expr t.var> : e, (EXPR <Vars-Print t.var> e.Re) (<Vars e.Re>);
794  };
795
796Comp-Assigns e.assigns =
797  e.assigns (/*e.assigned-vars*/) (/*e.comp-assigns*/) $iter {
798    e.assigns : (t.var (e.Re)) e.rest =
799      <Comp-Assign-to-Var t.var e.Re (e.assigned-vars)> :: e.c-as (e.a-vs),
800      e.rest (e.assigned-vars e.a-vs) (e.comp-assigns e.c-as);
801  } :: e.assigns (e.assigned-vars) (e.comp-assigns),
802  e.assigns : /*empty*/ =
803  e.comp-assigns;
804
805
806
807************************** FORMAT compilation. ***************************
808
809$box Aux-Index;
810
811$func Gener-Aux-Var = t.new-aux-var;
812
813Gener-Aux-Var =
814  <? &Aux-Index> : s.n,
815  <Store &Aux-Index <"+" s.n 1>>,
816  (VAR ("aux" s.n));
817
818
819$func Create-Aux-Vars (e.vars) e.splited-Re = e.assigns;
820
821
822Comp-Format (e.last-Re) e.He =
823  <Prepare-Vars <Vars e.He>> :: e.vars,
824  <Prepare-Res <Split-Re (<Format-Exp e.He>) e.last-Re>> :: e.splited-Re,
825  <Store &Aux-Index 1>,
826  <Create-Aux-Vars (e.vars) e.splited-Re> :: e.assigns,
827  <Comp-Assigns e.assigns>;
828
829/*
830 * Итак, e.vars -- все переменные, входящие в форматное выражение.  Каждая
831 * переменная может входить в форматное выражение только один раз, поэтому
832 * повторяющихся среди них нет.
833 * e.splited-Re -- набор результатных выражений.  На каждую переменную из
834 * e.vars по выражению, которое должно быть ей присвоено.
835 *
836 * Если переменная t.var_i используется в выражении e.Re_j, и i /= j, то
837 * переменной t.var_j значение должно быть присвоено раньше, чем перeменной
838 * t.var_i.  Если же, по аналогичным соображениям, t.var_i должна получить
839 * значение раньше t.var_j, необходимо завести вспомогательную переменную.
840 *
841 * Пример:
842 *
843 * t1 (t1 t2) (t1 t3) :: t2 t1 t3
844 *
845 * t3 = (t1 + t3)();
846 * aux_1 = t1;
847 * t1 = (t1 + t2)()
848 * t2 = aux_1;
849 *
850 * В общем случае вспомогательная переменная требуется, если двум переменным
851 * необходимы старые значения друг друга (возможно, не напрямую, а через
852 * промежуточные переменные).
853 *
854 * Вместо того, чтобы искать и анализировать такие циклы, будем действовать по
855 * методу "наибольшей пользы".  А именно:
856 *
857 *   - Для каждой переменной выпишем все другие переменные, которым требуется
858 *     её старое значение, а также отдельно те, старые значения которых
859 *     требуются ей.
860 *
861 *   - Всем переменным, от старых значений которых ничего не зависит, можно
862 *     смело присвоить новые значения.  При этом они исчезают из списков
863 *     зависимостей оставшихся переменных.
864 *
865 *   - Все переменные, новые значения которых ни от чего не зависят, можно
866 *     отложить, чтобы присвоить им значения тогда, когда будет удобно.  Т.е.
867 *     тогда, когда списки зависящих от них переменных опустеют.
868 *
869 *   - Чтобы означить оставшиеся, нужны вспомогательные переменные.  Выберем
870 *     одну из переменных, с максимальным списком тех, от которых она зависит,
871 *     и положим её значение во вспомогательную переменную.  Так как мы сразу
872 *     уменьшили кол-во зависимостей у максимального кол-ва переменных,
873 *     локально мы добились наибольшей пользы, хотя не исключено, что глобально
874 *     такой метод и не даст наименьшего кол-ва вспомогательных переменных.
875 *     Кроме того, мы не пытаемся выбрать наилучшую переменную из нескольких с
876 *     максимальным списком зависимостей.
877 *
878 *   - Повторяем всё это до тех пор, пока у каждой переменной не опустеет
879 *     список зависящих от неё.
880 *
881 *
882 * Для нашего примера:
883 *
884 * t1 (t1 t2) (t1 t3) :: t2 t1 t3
885 *
886 * t1 -- (t2 t3) (t2)
887 * t2 -- (t1)    (t1)
888 * t3 -- ()      (t1)
889 *
890 *
891 * Для каждой переменной var_i найдём все j /= i, такие что в Re_j встречается
892 * var_i -- provide[i], и а также все j /= i, такие что var_j нужна для
893 * подсчёта var_i, т.е. встречается в Re_i.
894 *
895 * Res-vars <- <Map &Vars (Res)>
896 * for var_i in vars
897 *     provide[i] <-
898 *     for vars-Re_j in Res-vars, j /= i
899 *         vars-Re_j : e var_i e = j
900 *     require[i] <- <Res-vars[i] `*` vars[^i]> : e var_j e, j
901 *
902 * Res-vars = map Vars Res
903 * provide, require =
904 *   {   [ j | vars-Re_j <- Res-vars, j /= i, var_i `in` vars-Re_j ]
905 *     , [ j | var_j <- Res-vars[i] `*` vars, i /= j]
906 *     | var_i <- vars
907 *   }
908 *
909 */
910
911$func CAV e.vars (e.assigns) (e.delayed) = e.assigns;
912
913$func Get-Vars e = e;
914Get-Vars (e.Re) = (<Vars e.Re>);
915
916Create-Aux-Vars (e.vars) e.splited-Re =
917  <Zip (<Map &Get-Vars (e.splited-Re)>) (e.vars)> :: e.list,
918  <Box> :: s.box,
919  <Box> :: s.provide-i,
920  <Box> :: s.require-i,
921  {
922    e.vars : e1 t.var-i e2,
923      {
924        e.list : e ((e.vars-Re) t.var-j) e,
925          \{
926            t.var-i : t.var-j = <Put s.require-i <And (e1 e2) e.vars-Re>>;
927            e.vars-Re : e t.var-i e = <Put s.provide-i t.var-j>;
928          },
929          $fail;
930        <L <Length e1> e.splited-Re> :: t.Re-i,
931        <Put s.box (t.var-i t.Re-i (<? s.provide-i>) (<? s.require-i>))>,
932          <Store s.provide-i /*empty*/>,
933          <Store s.require-i /*empty*/>;
934      },
935      $fail;;
936  },
937  <CAV <? s.box> (/*assigns*/) (/*delayed*/)>;
938
939
940/*
941 * Если есть переменная, у которой список provide пуст, её можно посчитать.
942 * Это выражается в том, что она (вместе с присваиваемым значением) добавляется
943 * в список assigns, убирается из списка vars, а также из всех списков provide
944 * и delayed.  В списках require её не было.
945 *
946 * CAV Res vars provide require assigns delayed =
947 *   { i | var_i <- vars, provide_i == [] } ->     // Здесь неверно!  На переменные
948 *                                                    из delayed тоже надо смотреть.
949 *       vars    = vars - var_i
950 *       provide = [ provide_j - i | provide_j <- provide ]
951 *       assigns = assigns++[(var_i, Res[i])]
952 *       delayed = [ (var_j, provide_j - i) | (var_j, provide_j) <- delayed ]
953 *       CAV Res vars provide require assigns delayed
954 */
955
956$func Assign-Empty-Provides e.vars  = e.assigns (e.vars);
957
958Assign-Empty-Provides {
959  e1 (t.var-i t.Re-i (/*empty provide_i*/) (e.require-i)) e2 =
960    <Box> :: s.vars,
961    {
962      e1 e2 : e (t.var-j t.Re-j (e.provide-j) (e.require-j)) e,
963        <Put s.vars (t.var-j t.Re-j (<Sub (e.provide-j) t.var-i>) (e.require-j))>,
964        $fail;;
965    },
966    (t.var-i t.Re-i) <Assign-Empty-Provides <? s.vars>>;
967  e.vars = /*empty*/ (e.vars);
968};
969
970
971/*
972 * Если есть переменная, у которой список require пуст, кладём её в delayed.
973 * Она будет посчитана, когда у неё опустеет список provide, т.е. когда не
974 * останется переменных, у которых она в списке require.
975 */
976$func Delay-Empty-Requires e.vars  = e.delayed (e.vars);
977
978Delay-Empty-Requires {
979  e1 t.var e2, t.var : (t.var-i t.Re-i (e.provide-i) (/*empty require_i*/)) =
980    <Delay-Empty-Requires e2> :: e.delayed (e.vars),
981    t.var e.delayed (e1 e.vars);
982  e.vars = /*empty*/ (e.vars);
983};
984
985
986/*
987 * Выбор переменной (из двух) с более длинным списком требуемых ей значений.
988 */
989$func Max-Require e = e;
990
991Max-Require t.arg1 t.arg2 =
992  t.arg1 : (t.var1 t.Re1 t.provide1 (e.require1)),
993  t.arg2 : (t.var2 t.Re2 t.provide2 (e.require2)),
994  {
995    <"<" (<Length e.require1>) (<Length e.require2>)> = t.arg2;
996    t.arg1;
997  };
998
999
1000/*
1001 * Подставить вспомогательную переменную вместо исходной во всех результатных выражениях.
1002 * Присваивание к исходной переменной убрать (оно к этому моменту уже выполнено).
1003 * Убрать переменную из списков зависимостей.
1004 */
1005$func Subst-Aux-Var e = e;
1006
1007Subst-Aux-Var t.var t.aux (t.v t.Re (e.provide) (e.require)), {
1008  t.var : t.v = /*empty*/;
1009  (
1010    t.v
1011    <Subst (t.var) ((t.aux)) t.Re>
1012    (<Sub (e.provide) t.var>)
1013    (<Sub (e.require) t.var>)
1014  );
1015};
1016
1017
1018/*
1019 * Извлечь присваивание из всей информации о переменной.
1020 */
1021$func Extract-Assigns e = e;
1022Extract-Assigns (t.var t.Re e) = (t.var t.Re);
1023
1024
1025/*
1026 * Основной цикл обработки присваиваний.
1027 *
1028 * 1) Из всех переменных (в том числе и отложенных), от которых больше ничего
1029 *    не зависит, сделать присваивания.
1030 * 2) Все переменные, которые больше ни от чего не зависят, отложить.
1031 * 3) Если осталось хотя бы две неотложенных переменных, выбирать из них ту,
1032 *    которая зависит от наибольшего числа переменных, подставить везде вместо
1033 *    неё вспомогательную, перейти к пункту 1.
1034 */
1035CAV e.vars (e.assigns) (e.delayed) =
1036  <Assign-Empty-Provides e.vars> :: e.new-assigns (e.vars),
1037  e.assigns e.new-assigns <Assign-Empty-Provides e.delayed> :: e.assigns (e.delayed),
1038  e.delayed <Delay-Empty-Requires e.vars> :: e.delayed (e.vars),
1039  {
1040    e.vars : t t e =
1041      <Foldr1 &Max-Require (e.vars)> : (t.var t.Re e),
1042      <Gener-Aux-Var> :: t.aux,
1043      e.assigns (t.aux (t.var)) (t.var t.Re) :: e.assigns,
1044      <Map &Subst-Aux-Var t.var t.aux (e.vars)> :: e.vars,
1045      <Map &Subst-Aux-Var t.var t.aux (e.delayed)> :: e.delayed,
1046      <CAV e.vars (e.assigns) (e.delayed)>;
1047    e.assigns <Map &Extract-Assigns (e.vars e.delayed)>;
1048  };
1049
1050
1051
1052
1053****************** Компиляция сопоставления с образцом *******************
1054
1055Get-Clash-Sequence (e.last-Re) t.Pattern e.Snt =
1056  (/*e.clashes*/) (RESULT e.last-Re) t.Pattern e.Snt $iter {
1057    e.Snt : (RESULT e.Re) (s.dir e.Pe) e.rest =
1058      /*
1059       * Компилируем все константные выражения и заводим в табличке все
1060       * незаведённые переменные.  У старых переменных очищается память
1061       * на предмет клешей, в которых они раньше использовались.
1062       */
1063      <Prepare-Res (e.Re) (e.Pe)> : (e.R1) (e.P1),
1064      <Map &Set-Var (Clashes /*empty*/) (<Vars e.R1 e.P1>)> : e,
1065      (e.clashes (e.R1) (s.dir e.P1)) e.rest;
1066  } :: (e.clashes) e.Snt,
1067  # \{
1068    e.Snt : \{
1069      (RESULT e.Re) (LEFT e) e = e.Re;
1070      (RESULT e.Re) (RIGHT e) e = e.Re;
1071    } :: e.Re,
1072      <Without-Calls? e.Re>;
1073  } =
1074  (e.clashes) e.Snt;
1075
1076Without-Calls? e.Re =
1077  e.Re $iter {
1078    e.Re : t.Rt e.rest =
1079      t.Rt : {
1080        (CALL e) = $fail;
1081        (BLOCK e) = $fail;
1082        (PAREN e.Re1) = <Without-Calls? e.Re1>;
1083        t.symbol-or-var = /*empty*/;
1084      },
1085      e.rest;
1086  } :: e.Re,
1087  e.Re : /*empty*/;
1088
1089$func CC s.tail? (v.fails) t.end-cycle e.Snt = e.asail-Snt;
1090
1091Comp-Clashes (e.clashes) s.tail? (v.fails) e.Sentence =
1092  <Init-Clashes e.clashes>,
1093  <CC s.tail? (v.fails) <R 0 v.fails> e.Sentence>;
1094
1095$func CC-Known-Lengths t.fail e.idxs = e.conds;
1096
1097$func CC-Compute-Length t.fail t.end-cycle t.idx = e;
1098
1099$func CC-Unknown-Lengths t.fail e.idxs = e.conds;
1100
1101$func CC-Deref t.fail e.actions = e.actions;
1102
1103$func CC-Eqs t.fail (e.assigns) e.eqs = e.actions;
1104
1105CC s.tail? (v.fails) t.end-cycle e.Snt, {
1106  <Domain &Known-Lengths> : v.clashes =
1107    <CC-Known-Lengths t.end-cycle v.clashes>
1108    <CC s.tail? (v.fails) t.end-cycle e.Snt>;
1109  <Domain &Compute-Length> : (t.clash) e =
1110    <CC-Compute-Length <R 0 v.fails> t.end-cycle t.clash>
1111    <CC s.tail? (v.fails) t.end-cycle e.Snt>;
1112  <Domain &Unknown-Lengths> : e.clashes =
1113    <CC-Unknown-Lengths t.end-cycle e.clashes> :: e.conds,
1114    /*
1115     * Когда мы добрались до сюда, все условия на длины на текущем уровне
1116     * выписаны.  Невыполнение любого из оставшихся условий (на
1117     * соответствие типов, равенство, длины внутри скобок) ведёт не к
1118     * прекращению текущего цикла, а переход к его следующей итерации.
1119     * Поэтому в качестве t.end-cycle везде дальше подставляется текущий
1120     * откат.
1121     */
1122    <Update-Hard-Parts> : {
1123      v.actions =
1124        e.conds <CC-Deref <R 0 v.fails> v.actions>
1125        <CC s.tail? (v.fails) <R 0 v.fails> e.Snt>;
1126      /*empty*/ =
1127        e.conds <CC-Eqs <R 0 v.fails> () <? &Eqs>> :: e.actions,
1128        <Store &Eqs /*empty*/>,
1129        {
1130          <Compose-Source> :: e.assign =
1131            e.actions <CC-Eqs <R 0 v.fails> () e.assign>
1132            <CC s.tail? (v.fails) <R 0 v.fails> e.Snt>;
1133          {
1134            <Get-Cycle> :: s.split (e.left) (e.right) (e.len)
1135                    t.var t.l-var t.r-var =
1136              {
1137                e.left : 0, e.right : 0 = /*empty*/ t.var;
1138                <Gener-Vars ((VAR)) "subexpr_" t.var> : t.sub-var,
1139                  (DECL Expr t.sub-var)
1140                  (ASSIGN t.sub-var
1141                    (SUBEXPR t.var (e.left) ((INFIX "-" (e.len) (e.left e.right)))))
1142                  t.sub-var;
1143              } :: e.subexpr t.var,
1144              {
1145                s.split : RSPLIT =
1146                  t.r-var t.l-var DEC-ITER;
1147                t.l-var t.r-var INC-ITER;
1148              } :: t.l-var t.r-var s.iter-op,
1149              <Gener-Label "continue"> :: t.cont-label,
1150              <Gener-Label "exit"> :: t.break-label,
1151              e.actions e.subexpr
1152              (s.split t.var (<Get-Var Min t.l-var>) t.l-var t.r-var)
1153              (FOR (t.cont-label) (t.break-label) () ((s.iter-op t.var))
1154                (IF (ITER-FAILS t.var) <Concat <R 0 v.fails>>)
1155                <CC s.tail?     (v.fails ((CONTINUE t.cont-label)))
1156                  <R 0 v.fails> e.Snt>
1157                (BREAK t.break-label)
1158              );
1159            e.actions <Comp-Sentence s.tail? (v.fails) () e.Snt>;
1160          };
1161        };
1162    };
1163};
1164
1165CC-Known-Lengths (e.fail) e.idxs, {
1166  e.idxs : (t.idx) e.rest =
1167    <Put &Checked-Lengths t.idx>,
1168    <Lookup &Known-Lengths t.idx> : (e.len-Re) (e.len-Pe),
1169    (IF-INT-CMP "!=" (e.len-Re) (e.len-Pe) e.fail)
1170    <CC-Known-Lengths (e.fail) e.rest>;
1171  <Clear-Table &Known-Lengths>;
1172};
1173
1174CC-Compute-Length (e.fail) (e.end-cycle) t.idx =
1175  <Lookup &Compute-Length t.idx> : t.var s.mult (e.minuend) (e.subtrahend),
1176  <Get-Var Min t.var> :: e.min,
1177  {
1178    t.var : (Len-Var e) =
1179      <Unbind &Compute-Length t.idx>,
1180      (IF-INT-CMP "<" (e.minuend)
1181          ((INFIX "+" (e.subtrahend)
1182            ((INFIX "*" (e.min) (s.mult)))
1183          ))
1184        e.end-cycle
1185      );
1186    <Create-Int-Var ("len") Aux e.minuend> :: t.m-var e.m-assign,
1187      <Create-Int-Var ("len") Aux e.subtrahend> :: t.s-var e.s-assign,
1188      (IF-INT-CMP "<" (t.m-var)
1189          ((INFIX "+" (t.s-var)
1190            ((INFIX "*" (e.min) (s.mult)))
1191          ))
1192        e.end-cycle
1193      ) :: e.min-cond,
1194      <Get-Var Max t.var> : {
1195        /*empty*/;
1196        e.max =
1197          (IF-INT-CMP ">" (t.m-var)
1198              ((INFIX "+" (t.s-var)
1199                ((INFIX "*" (e.max) (s.mult)))
1200              ))
1201          e.end-cycle);
1202      } :: e.max-cond,
1203      (INFIX "%" ((INFIX "-" (t.m-var) (t.s-var))) (s.mult)) :: e.div-cond,
1204      <Create-Int-Var ("len_") t.var
1205        (INFIX "/" ((INFIX "-" (t.m-var) (t.s-var))) (s.mult))
1206      > :: t.len-var e.len-assign,
1207      <Set-Var (Length t.len-var) t.var>,
1208      <Unbind &Compute-Length t.idx>,
1209      <Put &Checked-Lengths t.idx>,
1210      <Get-Var Clashes t.var> :: e.clashes,
1211      <Map &Reclassify-Clash (<Sub (e.clashes) <? &Checked-Lengths>>)> : e,
1212      e.m-assign e.s-assign
1213      e.min-cond e.max-cond
1214      (IF-INT-CMP "!=" (e.div-cond) (0) e.fail)
1215      e.len-assign;
1216  };
1217
1218$func  Get-Min e = e;
1219
1220$func? Get-Max e = e;
1221
1222CC-Unknown-Lengths (e.fail) e.idxs, {
1223  e.idxs : (t.idx) e.rest =
1224    <Lookup &Unknown-Lengths t.idx> : (e.len-Re) (e.len-Pe) (e.vars-Re) (e.vars-Pe),
1225    {
1226      <Get-Max e.vars-Re> :: e.max =
1227        <Get-Min e.vars-Pe> :: e.min,
1228        (IF-INT-CMP "<" (e.len-Re e.max) (e.len-Pe e.min) e.fail);
1229      /*empty*/;
1230    } :: e.cond1,
1231    {
1232      <Get-Max e.vars-Pe> :: e.max =
1233        <Get-Min e.vars-Re> :: e.min,
1234        (IF-INT-CMP ">" (e.len-Re e.min) (e.len-Pe e.max) e.fail);
1235      /*empty*/;
1236    } :: e.cond2,
1237    e.cond1 e.cond2
1238    <CC-Unknown-Lengths (e.fail) e.rest>;
1239  <Clear-Table &Unknown-Lengths>;
1240};
1241
1242Get-Min
1243{
1244  t.var e.vars = <Get-Var Min t.var> <Get-Min e.vars>;
1245  /*empty*/ = /*empty*/;
1246};
1247
1248Get-Max
1249{
1250  t.var e.vars = <Get-Var Max t.var> : v.max, v.max <Get-Max e.vars>;
1251  /*empty*/ = /*empty*/;
1252};
1253
1254$func Pos (e.Re) s.dir e.pos = e.pos;
1255
1256Pos {
1257  (e.Re) RIGHT e.pos = (INFIX "-" ((LENGTH e.Re)) (e.pos));
1258  (e.Re) LEFT  e.pos = e.pos;
1259};
1260
1261/*
1262 * Информацию о проверках и заведении переменных, необходимых для создания
1263 * клешей из содержимого скобок, кодируем на ASAIL.
1264 */
1265CC-Deref (e.fail) e.actions, e.actions : {
1266  (SYMBOL? e.Re (s.dir e.pos)) e.rest =
1267    (IF (SYMBOL? e.Re (<Pos (e.Re) s.dir e.pos>)) e.fail)
1268    <CC-Deref (e.fail) e.rest>;
1269  (DEREF t.var e.Re (s.dir e.pos)) e.rest =
1270    (DECL Expr t.var)
1271    (ASSIGN t.var (DEREF e.Re (<Pos (e.Re) s.dir e.pos>)))
1272    <CC-Deref (e.fail) e.rest>;
1273  /*empty*/ = /*empty*/;
1274};
1275
1276CC-Eqs (e.fail) (e.assigns) e.eqs, {
1277  e.eqs : ((e.Re) (s.dir e.pos) t.Pt (e.len)) e.rest =
1278    {
1279      e.Re : t,
1280        <Get-Known-Length e.Re> : e.len (), // FIXME: здесь надо использовать
1281                          //        калькулятор
1282        s.dir e.pos : \{
1283          LEFT 0;
1284          RIGHT e.len;
1285        } =
1286        e.Re;;
1287    } :: e.Re-term,
1288    {
1289      e.len : 1 = TERM-EQ;      // FIXME: здесь надо использовать
1290                  //        калькулятор
1291      EQ;
1292    } :: s.eq,
1293    <Pos (e.Re) s.dir e.pos> :: e.pos,
1294    {
1295      \{
1296        <Get-Var Instantiated? t.Pt> : True = t.Pt (e.Re);
1297        t.Pt : \{
1298          (REF e);
1299          (STATIC e);
1300        }, {
1301          <Var? e.Re-term> = e.Re-term (t.Pt);
1302          t.Pt (e.Re);
1303        };
1304      } :: el (er),
1305        (IF (NOT (s.eq el (er) (e.pos))) e.fail) :: t.cond,
1306        {
1307          /*
1308           * Мы предполагаем, что во всех пришедших e.eqs все e.Re
1309           * уже были определены ранее.
1310           */
1311          e.assigns : $r e1 (s.op t.Pt e.def) e2 =
1312            <CC-Eqs (e.fail) (e1 (s.op t.Pt e.def) t.cond e2) e.rest>;
1313          t.cond <CC-Eqs (e.fail) (e.assigns) e.rest>;
1314        };
1315      <Set-Var (Instantiated? True) t.Pt>,
1316        {
1317          t.Pt : (SVAR e) =
1318            (IF
1319              (NOT (SYMBOL? e.Re (e.pos)))
1320              e.fail
1321            );;
1322        } :: e.cond,
1323        {
1324          <Get-Var Decl t.Pt> : s =
1325            e.cond <CC-Eqs (e.fail) (e.assigns
1326              (ASSIGN t.Pt (SUBEXPR e.Re (e.pos) (e.len))))
1327              e.rest>;
1328          <Vars-Decl Expr t.Pt> : e,
1329            e.cond <CC-Eqs (e.fail) (e.assigns
1330              (EXPR t.Pt (SUBEXPR e.Re (e.pos) (e.len)))) e.rest>;
1331        };
1332    };
1333  e.assigns e.eqs;
1334};
1335
1336
1337
1338
1339Gener-Label e.QualifiedName =
1340  {
1341    <Lookup &Labels e.QualifiedName> : s.num,
1342      <"+" s.num 1>;
1343    1;
1344  } :: s.num,
1345  <Bind &Labels (e.QualifiedName) (s.num)>,
1346  (e.QualifiedName s.num);
1347
1348Add-To-Label (e.label) e.name = <Gener-Label e.label "_" e.name>;
1349
1350
1351
1352
1353Lookup-Func t.Fname, \{
1354  <Lookup &Fun t.Fname>;
1355  <Lookup &Fun? t.Fname>;
1356} : s.linkage s.tag t.pragma (e.Fin) (e.Fout) =
1357  s.linkage s.tag t.pragma (e.Fin) (e.Fout);
1358
Note: See TracBrowser for help on using the repository browser.