source: to-imperative/trunk/compiler/rfp_mangle.rf @ 683

// $Source$
// $Revision: 683 $
// $Date: 2003-04-27 14:32:36 +0000 (Sun, 27 Apr 2003) $

$use Class Convert;

$use "rfp_list";

$use "reserved-c++";  // import $func? Reserved-Word?;

$const Conv-Table =
  ('!'    'e')
  ('?'    'q')
  ('_'    '')
  ('-'    'm')
  ('+'    'p')
  ('<'    'lt')
  ('>'    'gt')
  ('='    'eq')
  ('*'    'a')
  ('/'    's')
  (' '    'sp')
  ('\\'   'bs')
  ('|'    'bar')
  ('~'    'tilde')
  ('@'    'at')
  ('#'    'num')
  ('$'    'dollar')
  ('%'    'percnt')
  ('^'    'circ')
  ('&'    'amp')
  ('('    'lpar')
  (')'    'rpar')
  ('['    'lsqb')
  (']'    'rsqb')
  ('{'    'lcub')
  ('}'    'rcub')
  ('`'    'grave')
  ('\''   'apos')
  ('\"'   'quot')
  (','    'comma')
  ('.'    'period')
  (':'    'colon')
  (';'    'semi');



//$func Qualifier2Cpp s.qualifier = e.cpp-namespace;
$func Qualifier2Cpp e = e;

$func Chars2Cpp e.name = e.cpp-identifier;

//$func A-Char2Cpp s.char = e.char-representation;
$func A-Char2Cpp e = e;

$func Char-To-Unicode s.char = e.unicode;


Rfp2Cpp e.rfp-obj, {
  e.rfp-obj : \{
    (VAR (e.name)) = ('_v_') e.name;
    (EVAR (e.name)) = ('_ve_') e.name;
    (VVAR (e.name)) = ('_vv_') e.name;
    (TVAR (e.name)) = ('_vt_') e.name;
    (SVAR (e.name)) = ('_vs_') e.name;
    (STATIC (e.name)) = ('_c_') e.name;
    (LABEL (e.name)) = () e.name;
  } :: (e.prefix) e.name =
    e.prefix <Chars2Cpp e.name>;
  e.rfp-obj : {
    (OBJ e.names) = e.names;
    (e.names) = e.names;
    e.names = e.names;
  } : e.qualifiers s.name =
    <Map &Qualifier2Cpp (e.qualifiers)> <Chars2Cpp s.name>;
  = /*empty*/;
} :: e.ident,
  {
    <Reserved-Word? e.ident> = '_r_' e.ident;
    e.ident;
  };

Qualifier2Cpp s.qualifier = <Chars2Cpp s.qualifier> '::';

Chars2Cpp e.name = <Map &A-Char2Cpp (<To-Chars e.name>)>;

A-Char2Cpp s.char, {
  <Digit? s.char> = s.char;
  <Letter? s.char>, # \{ s.char : '?'; } = s.char;
  &Conv-Table : e (s.char e.code) e = '_' e.code '_';
  '_' <Char-To-Unicode s.char> '_';
};

Char-To-Unicode {
//  '\a' = '07';
  '\b' = '08';
  '\t' = '09';
  '\n' = '0A';
  '\v' = '0B';
  '\f' = '0C';
  '\r' = '0D';
};


$func? Qualifiers2Rfp e.qualifiers = e.words;

$func? Chars2Rfp e.name = s.word;

$func? Codes2Rfp e.codes = e.chars;


Cpp2Rfp e.ident =
  <To-Chars e.ident> : {
    '_r_' e.name = e.name;
    e.name = e.name;
  } : \{
    '_ve_' e.name = (EVAR (<Chars2Rfp e.name>));
    '_vv_' e.name = (VVAR (<Chars2Rfp e.name>));
    '_vt_' e.name = (TVAR (<Chars2Rfp e.name>));
    '_vs_' e.name = (SVAR (<Chars2Rfp e.name>));
    e.name = <Qualifiers2Rfp e.name>;
  };

Qualifiers2Rfp {
  e.qualifier '::' e.rest = <Chars2Rfp e.qualifier> <Qualifiers2Rfp e.rest>;
  e.name = <Chars2Rfp e.name>;
};

Chars2Rfp e.name = <To-Word <Codes2Rfp e.name>>;

Codes2Rfp {
  '_' e.code '_' e.rest =
    &Conv-Table : e (s.char e.code) e =
    s.char <Codes2Rfp e.rest>;
  s.char e.rest = \{
    <Digit? s.char>;
    <Letter? s.char>, # \{ s.char : '?'; };
  } =
    s.char <Codes2Rfp e.rest>;
  /*empty*/ = /*empty*/;
};