source: to-imperative/trunk/java/refal/refal/plus/Stream.rf @ 3953

// $Id: Stream.rf 3953 2008-10-02 14:13:11Z yura $

//$module Stream : IStream;

$use Access Apply Box Class Compare Error StdIO;

//** $func Stream s.func e.args = stream;

Stream s.func e.args, {
  # <IsFunc s.func> =
    <Lib_Error (Stream Stream) "Arg 1 is not a Function">, $fail;
  <Box () (s.func e.args)>;
};


$func? Read_Expr s.box = v.expr;

Read_Expr s.box =
  <Get s.box> : v.expr,
  <Store s.box /*empty*/>,
  v.expr;

//** $func Expr-Open expr = stream;

Expr_Open expr =
  <Box expr> :: s.box,
  <Stream &Read_Expr s.box>;


//** $func File-Open  e.filename = stream;
//** $func File-Close stream     = ;

File_Open e.filename =
  <Channel> :: s.channel,
  <PrimOpenFile s.channel e.filename R>,
  <Stream &PrimRead s.channel &ReadChunkSize>;

File_Close stream, {
  <Get stream> : (e.buf) (s.func e.args), {
    e.args : s.ch e.rest, <IsChannel s.ch> =
      <PrimCloseChannel s.ch>;
    <Lib_Error (Stream "File_Close") "Arg 1 is not a Streamed File"> = $fail;
  };
  <Lib_Error (Stream "File_Close") "Arg 1 is not a Stream"> = $fail;
};


//** $func StdIStream = stream;

$box StdIStream_Box;

StdIStream, {
  <Get &StdIStream_Box> : stream = stream;
  <Stream &PrimRead &StdIn 1> :: stream,
    <Store &StdIStream_Box stream>,
    stream;
};


//** $func? Getc   stream      = term;

Getc stream = <Gets stream 1> : term, term;


//** $func? Gets   stream s.n  = expr;

Gets stream s.n, {
  <Get stream> : (e.buf) (s.func e.args) =
    e.buf $iter {
      e.buf <Apply s.func e.args>;
      <Store stream (e.buf) (s.func e.args)> = $fail;
    } :: e.buf,
    <Ge (<Length e.buf>) (s.n)> =
    <Store stream (<Middle s.n 0 e.buf>) (s.func e.args)>,
    <Left 0 s.n e.buf>;
  <Lib_Error (Stream Gets) "Arg 1 is not a Stream"> = $fail;
};


//** $func  Ungets stream expr = ;

Ungets stream expr, {
  <Get stream> : (e.buf) (s.func e.args) =
    <Store stream (expr e.buf) (s.func e.args)>;
  <Lib_Error (Stream Ungets) "Arg 1 is not a Stream"> = $fail;
};


//** $func  Scanc  stream t1   = empty-or-t1;

Scanc stream t1, {
  <Getc stream> : {
    t1 = t1;
    t2 = <Ungets stream t2>;
  };
  /*empty*/;
};

Scans stream e1, {
  <Gets stream <Length e1>> : {
    e1 = e1;
    e2 = <Ungets stream e2>;
  };
  /*empty*/;
};

//** $func Get-Delim stream t.delim = expr;

Get_Delims stream e.delim, {
  <Scans stream e.delim> : e.delim = e.delim;
  <Getc stream> :: t1 = t1 <Get_Delims stream e.delim>;
  /*empty*/;
};

//** $func Get-Delim stream t.delim = expr;

Get_Delim stream t.delim, {
  <Get stream> : (e.buf) (s.func e.args) =
    (/*e.str*/) (e.buf) $iter {
      e.buf : e1 t.delim e2 =
        (e.str e1 t.delim) (e2) Stop;
      (e.str e.buf) (<Apply s.func e.args>);
      (e.str e.buf) () Stop;
    } :: (e.str) (e.buf) e.Isstop,
    e.Isstop : Stop =
    <Store stream (e.buf) (s.func e.args)>,
    e.str;
  <Lib_Error (Stream "Get_Delim") "Arg 1 is not a Stream"> = $fail;
};


//** $func Get-Line stream = expr;

//Get-Line stream = <Get-Delim stream '\n'>;

$func? Not_EOL t1 = ;
Not_EOL t1 = # t1 : \{ '\n'; '\r'; };

Get_Line stream =
  <Get_While stream &Not_EOL> <Scanc stream '\r'> <Scanc stream '\n'>;


//** $func Get-While stream s.pred = expr;

Get_While stream s.pred, {
  <Get stream> : (e.buf) (s.func e.args) =
    (/*e.str*/) (e.buf) $iter {
      e.buf : t1 e2, {
        <Apply s.pred t1> : e = (e.str t1) (e2);
        (e.str) (e.buf) Stop;
      };
      (e.str) (<Apply s.func e.args>);
      (e.str) (e.buf) Stop;
    } :: (e.str) (e.buf) e.Isstop,
    e.Isstop : Stop =
    <Store stream (e.buf) (s.func e.args)>,
    e.str;
  <Lib_Error (Stream "Get_While") "Arg 1 is not a Stream"> = $fail;
};


//** $func? End-of-Stream? stream = ;

IsEnd_of_Stream stream, {
  <Get stream> : (e.buf) (s.func e.args) =
    {
      e.buf $iter
        <Apply s.func e.args>
      :: e.buf,
        e.buf : v =
        <Store stream (e.buf) (s.func e.args)>,
        $fail;
      /*We are at the end of the stream*/;
    };
  <Lib_Error (Stream "IsEnd_of_Stream") "Arg 1 is not a Stream"> = $fail;
};