source: to-imperative/trunk/java/refal/refal/plus/internal/StdIO.rf @ 3659

// $Id: StdIO.rf 3659 2008-03-31 15:31:21Z yura $

$use Arithm Box Class Compare Convert Error Table;

//X/$use Lexer(Stream FakeStreamIndex);
$use Lexer;
$use Stream;
$use StreamErr;
$use "refal.plus.StdIO";

OpenFile s.channel e.file s.mode, \{
  # <IsChannel s.channel> =
    <Lib_Error (StdIO OpenFile) "Arg 1 is not a Channel">;
  # <IsWord s.mode> =
    <Lib_Error (StdIO OpenFile) "Arg 3 is not a Word">;
  <PrimOpenFile s.channel e.file s.mode>,
    <Bind &Buffers (s.channel) (<Stream &PrimRead s.channel &ReadChunkSize>)>;
};

/*
 * FIXME:
 * Should open &StdIn, &StdOut, and &StdErr like this:
 *   <Bind &Buffers (&StdIn) (<Stream &Prim-Read &StdIn 1>)>;
 */


//FIXME: probably shouldn't close &StdIn, &StdOut, and &StdErr?
CloseChannel s.channel, {
  # <IsChannel s.channel> =
    <Lib_Error (StdIO CloseChannel) "Arg 1 is not a Channel">;
  <PrimCloseChannel s.channel>,
    <Unbind &Buffers s.channel>;
};


IsEof s.channel, {
  <Lookup &Buffers s.channel> : stream =
    <IsEnd_of_Stream stream>;
  <Lib_Error (StdIO IsEof) "Channel is not open">;
};


ReadCharCh s.channel, {
  <Lookup &Buffers s.channel> : stream =
    <Getc stream> : s.char, s.char;
  <Lib_Error (StdIO ReadCharCh) "Channel is not open"> = $fail;
};

ReadChar = <ReadCharCh &StdIn>;


ReadLineCh s.channel, {
  <Lookup &Buffers s.channel> : stream =
    <Get_Line stream> : \{
      e.line '\r\n' = e.line;
      e.line '\n'   = e.line;
      e.line '\r'   = e.line;
      v.line        = v.line;
    };
  <Lib_Error (StdIO ReadLineCh) "Channel is not open"> = $fail;
};

ReadLine = <ReadLineCh &StdIn>;


$func? Read_Main s.fname s.channel = term;

ReadCh s.channel = <Read_Main ReadCh s.channel>;

Read = <Read_Main Read &StdIn>;

Read_Main s.fname s.channel, {
  <Lookup &Buffers s.channel> : stream =
    {
      <IsRead_Term stream>;
      /*empty*/;
    } :: e.result,
    {
      <Errors> : (t.name t.pos (e.message)) e =
        <Lib_Error (StdIO s.fname) e.message>, $fail;;
    },
    e.result : term = term;
  <Lib_Error (StdIO s.fname) "Channel is not open"> = $fail;
};

StaticInit = <Bind &Buffers (&StdIn) (<Stream &PrimRead &StdIn &ReadChunkSize>)>;