source: to-imperative/trunk/library/Stream/refal/Stream.rf @ 2027

Last change on this file since 2027 was 2027, checked in by orlov, 15 years ago
  • Stream.Get-Line and StdIO.Read-Line! consider a line to be terminated

by any one of a line feed ('\n'), a carriage return ('\r'),
or a carriage return followed immediately by a linefeed.

  • New function Stream.Scanc.
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 3.6 KB
Line 
1// $Id: Stream.rf 2027 2006-07-17 17:40:42Z orlov $
2
3//$module Stream : IStream;
4
5$use Access Apply Box Class Compare Error StdIO;
6
7*** $func Stream s.func e.args = stream;
8
9Stream s.func e.args, {
10  # <Func? s.func> =
11    <Lib-Error (Stream Stream) "Arg 1 is not a Function">, $fail;
12  <Box () (s.func e.args)>;
13};
14
15
16$func? Read-Expr s.box = v.expr;
17
18Read-Expr s.box =
19  <? s.box> : v.expr,
20  <Store s.box /*empty*/>,
21  v.expr;
22
23*** $func Expr-Open expr = stream;
24
25Expr-Open expr =
26  <Box expr> :: s.box,
27  <Stream &Read-Expr s.box>;
28
29
30*** $func File-Open  e.filename = stream;
31*** $func File-Close stream     = ;
32
33File-Open e.filename =
34  <Channel> :: s.channel,
35  <Prim-Open-File s.channel e.filename R>,
36  <Stream &Prim-Read s.channel &Read-Chunk-Size>;
37
38File-Close stream, {
39  <? stream> : (e.buf) (s.func e.args), {
40    e.args : s.ch e.rest, <Channel? s.ch> =
41      <Prim-Close-Channel s.ch>;
42    <Lib-Error (Stream File-Close) "Arg 1 is not a Streamed File"> = $fail;
43  };
44  <Lib-Error (Stream File-Close) "Arg 1 is not a Stream"> = $fail;
45};
46
47
48*** $func StdIStream = stream;
49
50$box StdIStream-Box;
51
52StdIStream, {
53  <? &StdIStream-Box> : stream = stream;
54  <Stream &Prim-Read &StdIn 1> :: stream,
55    <Store &StdIStream-Box stream>,
56    stream;
57};
58
59
60*** $func? Getc   stream      = term;
61
62Getc stream = <Gets stream 1> : term, term;
63
64
65*** $func? Gets   stream s.n  = expr;
66
67Gets stream s.n, {
68  <? stream> : (e.buf) (s.func e.args) =
69    e.buf $iter {
70      e.buf <Apply s.func e.args>;
71      <Store stream (e.buf) (s.func e.args)> = $fail;
72    } :: e.buf,
73    <">=" (<Length e.buf>) (s.n)> =
74    <Store stream (<Middle s.n 0 e.buf>) (s.func e.args)>,
75    <Left 0 s.n e.buf>;
76  <Lib-Error (Stream Gets) "Arg 1 is not a Stream"> = $fail;
77};
78
79
80*** $func  Ungets stream expr = ;
81
82Ungets stream expr, {
83  <? stream> : (e.buf) (s.func e.args) =
84    <Store stream (expr e.buf) (s.func e.args)>;
85  <Lib-Error (Stream Ungets) "Arg 1 is not a Stream"> = $fail;
86};
87
88
89*** $func  Scanc  stream t1   = empty-or-t1;
90
91Scanc stream t1, {
92  <Getc stream> : {
93    t1 = t1;
94    t2 = <Ungets stream t2>;
95  };
96  /*empty*/;
97};
98
99
100*** $func Get-Delim stream t.delim = expr;
101
102Get-Delim stream t.delim, {
103  <? stream> : (e.buf) (s.func e.args) =
104    (/*e.str*/) (e.buf) $iter {
105      e.buf : e1 t.delim e2 =
106        (e.str e1 t.delim) (e2) Stop;
107      (e.str e.buf) (<Apply s.func e.args>);
108      (e.str e.buf) () Stop;
109    } :: (e.str) (e.buf) e.stop?,
110    e.stop? : Stop =
111    <Store stream (e.buf) (s.func e.args)>,
112    e.str;
113  <Lib-Error (Stream Get-Delim) "Arg 1 is not a Stream"> = $fail;
114};
115
116
117*** $func Get-Line stream = expr;
118
119//Get-Line stream = <Get-Delim stream '\n'>;
120
121$func? Not-EOL t1 = ;
122Not-EOL t1 = # t1 : \{ '\n'; '\r'; };
123
124Get-Line stream =
125  <Get-While stream &Not-EOL> <Scanc stream '\r'> <Scanc stream '\n'>;
126
127
128*** $func Get-While stream s.pred = expr;
129
130Get-While stream s.pred, {
131  <? stream> : (e.buf) (s.func e.args) =
132    (/*e.str*/) (e.buf) $iter {
133      e.buf : t1 e2, {
134        <Apply s.pred t1> : e = (e.str t1) (e2);
135        (e.str) (e.buf) Stop;
136      };
137      (e.str) (<Apply s.func e.args>);
138      (e.str) (e.buf) Stop;
139    } :: (e.str) (e.buf) e.stop?,
140    e.stop? : Stop =
141    <Store stream (e.buf) (s.func e.args)>,
142    e.str;
143  <Lib-Error (Stream Get-While) "Arg 1 is not a Stream"> = $fail;
144};
145
146
147*** $func? End-of-Stream? stream = ;
148
149End-of-Stream? stream, {
150  <? stream> : (e.buf) (s.func e.args) =
151    {
152      e.buf $iter
153        <Apply s.func e.args>
154      :: e.buf,
155        e.buf : v =
156        <Store stream (e.buf) (s.func e.args)>,
157        $fail;
158      /*We are at the end of the stream*/;
159    };
160  <Lib-Error (Stream End-of-Stream?) "Arg 1 is not a Stream"> = $fail;
161};
162
Note: See TracBrowser for help on using the repository browser.