source: to-imperative/trunk/samples/select3.rf @ 760

//$use Dos StdIO;// TIMER;
$use StdIO;

$func  MkArg  eString     = ePrefixes;
$func  Select eSets       = eXs-or-sFail;   * (eXs) or '*'
$func? Sel    (eXs) eSets = (eXs);
$func? InStack e.Xs s.X   = ;               * /*empty*/ | $false;
$func  Stack2Exp e.Xs     = e.ExpXs;


Main =
  /*<PrintLN <Time>>,*/
  <MkArg '1234567890ab'> :: e.Arg,
  <PrintLN e.Arg>,
  <Select e.Arg> :: e.Res,
  <PrintLN e.Res>,
  /*<PrintLN <Time>>*/;

MkArg e.String = * e.Prefixes
  ( ) (e.String) $iter {
    e.Prefix : e.Prefix-- s =
      (e.Prefixes (e.Prefix)) (e.Prefix--) ;
  } :: (e.Prefixes) (e.Prefix),
  e.Prefix : /*empty*/
   = e.Prefixes;

Select e.Sets = * e.Xs-or-sFail -- (eXs') or '*'
  {
    <Sel () e.Sets> :: (e.Xs) = (<Stack2Exp e.Xs>);
    '*';
  };

Sel (e.Xs) e.Sets = * (eXs) | $fail;
  e.Sets : \{
    /*empty*/ = (e.Xs);

    (e.Set) e.Sets--,
      e.Set : e sX e, 
      #<InStack e.Xs s.X>,
      <Sel (s.X (e.Xs)) e.Sets-->;
  };

InStack e.Xs s.X =               * /*empty*/ | $false;
  e.Xs : s.Y (e.Xs--),
  \{
    s.Y : s.X;
    <InStack e.Xs-- s.X>;
  };
 
Stack2Exp e.Xs =                 * e.ExpXs
  e.Xs : {
    /* empty */ = /* empty */;
    s.Y (e.Xs--) = <Stack2Exp e.Xs--> s.Y;
  };